#**************************************************************************
#   Copyright (C) 2006 by Michael Andreen <harvATruinDOTnu>               *
#                                                                         *
#   This program is free software; you can redistribute it and/or modify  *
#   it under the terms of the GNU General Public License as published by  *
#   the Free Software Foundation; either version 2 of the License, or     *
#   (at your option) any later version.                                   *
#                                                                         *
#   This program is distributed in the hope that it will be useful,       *
#   but WITHOUT ANY WARRANTY; without even the implied warranty of        *
#   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the         *
#   GNU General Public License for more details.                          *
#                                                                         *
#   You should have received a copy of the GNU General Public License     *
#   along with this program; if not, write to the                         *
#   Free Software Foundation, Inc.,                                       *
#   51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.         *
#**************************************************************************/
package NDIRC::PA;
use strict;
use warnings;
use ND::DB;
use ND::Include;
use NDIRC::Access;
use NDIRC::Misc;
use POSIX;
require Exporter;

our @ISA = qw/Exporter/;

our @EXPORT = qw/shipEff shipStop parseValue prettyValue calcXp findCovOpper/;

sub shipEff {
	my ($msg,$command) = @_;
	my ($amount,$ship,$value,$target);
	my $eff = 1;
	$eff = 0 if $command =~ /stop/;
	if(defined $msg && $msg =~ /^(-?\d+(?:\.\d+)?[hkMG]?) (\w+)(?: (\w+))?/){
		$ship = "\%$2\%";
		$target = ($3 || '%');
		my $am = $1;
		if ($command =~ /^v.+$/){
			$value = parseValue($am);
			$value *= -1.5 if $value < 0;
			my $feud = '';
		}else{
			$amount = parseValue($am);
		}
	}else{
		$ND::server->command("notice $ND::nick syntax: $command amount ship [race|class] | Amount can use SI prefixes like k and M. Race or class is an optional argument, using the short form (i.e. cath or Fi)");
		return;
	}
	my $feud = '';

	my $s= $ND::DBH->selectrow_hashref(q{
		SELECT name,t1,t2,t3,"type",damage
			,metal+crystal+eonium AS cost
			,init,"class",guns,race,eres,armor
		FROM ship_stats WHERE name ILIKE ?
		}, undef, $ship);
	if ($s){
		if (defined $value){
			$amount = int(($value*100/$s->{cost}));
			$feud = '(FEUD: '.prettyValue(int($amount/0.86)).') ';
		}
		$value = prettyValue(($amount*$s->{cost}/100));
		my $name = shipColor($s->{name},$s->{type});
		my $text = prettyValue($amount)." $name ($s->{init}:$value) :";
		for my $tn ('t1','t2','t3'){
			next if ($eff && not defined $s->{$tn});
			$text .= " $ND::B${ND::C}03" . ($eff ? $s->{$tn} : $tn) . "$ND::O: ";
			my $st = q{
				SELECT name,"class","type",armor
					,metal+crystal+eonium AS cost
					,init,t1,t2,t3,eres,race
					,damage,guns
				FROM ship_stats 
				};
			if ($eff){
				$st = $ND::DBH->prepare($st . q{
				WHERE "class" = $1
					AND ("class" ILIKE $2 OR race ILIKE $2)
				});
				$st->execute($s->{$tn},$target);
			}else{
				$st = $ND::DBH->prepare($st . qq{
				WHERE $tn = \$1
					AND ("class" ILIKE \$2 OR race ILIKE \$2)
				});
				$st->execute($s->{class},$target);
			}
			while (my $t = $st->fetchrow_hashref()){
				my $number = calcEff($s,$t,$amount,$eff);
				if ($eff){
					$number *= 0.60 if $tn eq 't2';
					$number *= 0.30 if $tn eq 't3';
				}else{
					$number /= 0.60 if $tn eq 't2';
					$number /= 0.30 if $tn eq 't3';
				}
				$number = int($number);
				$value = prettyValue($number*$t->{cost}/100);
				my $name = shipColor($t->{name},$t->{type});
				$text .= " $ND::B$number$ND::O $name ($t->{init}:$value),";
			}
			chop $text;
		}
		$ND::server->command("notice $ND::nick $text");
	}
}

sub calcEff {
	my ($s,$t,$amount,$eff) = @_;

	my $number = 0;
	if ($eff){
		$number = $s->{type} eq 'Emp' ?
			($amount*$s->{guns}*(100-$t->{eres})/100)
			: ($amount*$s->{damage}/$t->{armor});
	}else{
		$number = $t->{type} eq 'Emp' ?
			($amount*100/(100 - $s->{eres})/$t->{guns})
			: ($amount*$s->{armor}/$t->{damage});
	}

	for my $tn ('t1','t2','t3'){
		my ($s1,$t1) = $eff ? ($s,$t) : ($t,$s);
		next unless (defined $t1->{$tn});
		next unless ($t1->{$tn} eq $s1->{class});

		if($t1->{init} <= $s1->{init}){
			$t->{init} = "${ND::C}04$t->{init}$ND::O";
		}else{
			$t->{init} = "${ND::C}12$t->{init}$ND::O";
		}
	}
	return $number;
}

sub shipColor {
	my ($string,$type) = @_;
	my $c = 04;
	$c = 12 if $type eq 'Emp';
	$c = 13 if $type eq 'Steal';
	return "$ND::C$c$string$ND::O";
}

sub calcXp {
	my ($msg) = @_;

	my ($x,$y,$z,$roids,$cap);
	if(defined $msg && $msg =~ /^(\d+)\D+(\d+)\D+(\d+)(?:[^\.\d]+(\d+))?(?:[^\.\d]+(\d*\.\d+))?$/){
		$x = $1;
		$y = $2;
		$z = $3;
		$roids = $4;
		$cap = $5;
	}else{
		$ND::server->command("notice $ND::nick syntax: .xp X:Y:Z [roids] [cap] | if roids < 10 then it's taken as the wave, cap is a floating point number, defaults to 0.25");
		return;
	}

	my ($avalue,$ascore) = $ND::DBH->selectrow_array(q{
		SELECT value,score FROM current_planet_stats WHERE 
			id = (SELECT planet FROM users WHERE hostmask ILIKE ?);
		}, undef, $ND::address);
	my ($tvalue,$tscore,$tsize) = $ND::DBH->selectrow_array(q{
		SELECT value,score,size FROM current_planet_stats WHERE 
		x = ? AND y = ? and z = ?;
		}, undef, $x,$y,$z);
	$cap = 0.25 unless $cap;
	unless($roids){
		$roids = int($tsize*$cap);
	}elsif ($roids < 10){
		$tsize = ceil($tsize*.75**($roids-1));
		$roids = int($cap*$tsize);
	}
	$tsize -= $roids;
	unless (defined $avalue && defined $ascore){
		$ND::server->command("notice $ND::nick You don't have a planet specified");
		return;
	}
	unless (defined $tvalue && defined $tscore){
		$ND::server->command("notice $ND::nick Doesn't seem to be a planet at $x:$y:$z");
		return;
	}
	my $xp = pa_xp($roids,$ascore,$avalue,$tscore,$tvalue);
	my $score = 60 * $xp;
	my $value = $roids*200;
	my $totscore = prettyValue($score + $value);
	$ND::server->command("notice $ND::nick You will gain $ND::B$xp$ND::B XP, $ND::B$score$ND::B score, if you steal $roids roids ($ND::B$value$ND::B value), from $ND::B$x:$y:$z$ND::B, who will have $ND::B$tsize$ND::B roids left, total score gain will be: $ND::B$totscore$ND::B in total,");
}

sub findCovOpper {
	my ($stolen, $command) = @_;

	my $tick = $ND::tick;
	my $agents;

	if (defined $stolen && $stolen =~ /(\d+) (\d+) (\d+)/){
		$tick = $1;
		$agents = $2;
		$stolen = $3;
	}elsif (defined $stolen && $stolen =~ /(\d+) (\d+)/){
		$agents = $1;
		$stolen = $2;
	}else{
		$ND::server->command("notice $ND::nick syntax: .$command [tick] agents stolen | tick can be omitted if you're doing this the same tick you got cov opped, if you have different amount of your resources stolen, specify the highest amount. Only works if less than 10% of your resources and < 10,000*agents were stolen");
		return;
	}

	my ($value,$score) = $ND::DBH->selectrow_array(q{
		SELECT value,score FROM planet_stats WHERE 
			id = (SELECT planet FROM users WHERE hostmask ILIKE ?) AND tick = ?;
		}, undef, $ND::address,$tick);
	unless ($value){
		$ND::server->command("notice $ND::nick No value found for tick $tick, can't find your cov opper.");
		return;
	}
	my $attackers = $ND::DBH->prepare(q{
		SELECT coords(p.x,p.y,p.z), ruler, planet FROM current_planet_stats p JOIN planet_stats ps using (id) WHERE 
		ps.tick = $1 AND (2000.0*$2*$3/ps.value)::int = $4 ;
		});
	$attackers->execute($tick,$agents,$value,$stolen);
	if ($attackers->rows == 0){
		$ND::server->command("notice $ND::nick No cov opper found, did you specify the right tick, and was the stolen amount not capped?");
		return;
	}
	my $coords = '';
	while (my $attacker = $attackers->fetchrow_hashref){
		$coords .= " ($attacker->{coords} : $attacker->{ruler} OF $attacker->{planet})";
	}
	$ND::server->command("notice $ND::nick The planet that cov opped you is one of: $coords");
}

1;
