#**************************************************************************
#   Copyright (C) 2006 by Michael Andreen <harvATruinDOTnu>               *
#                                                                         *
#   This program is free software; you can redistribute it and/or modify  *
#   it under the terms of the GNU General Public License as published by  *
#   the Free Software Foundation; either version 2 of the License, or     *
#   (at your option) any later version.                                   *
#                                                                         *
#   This program is distributed in the hope that it will be useful,       *
#   but WITHOUT ANY WARRANTY; without even the implied warranty of        *
#   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the         *
#   GNU General Public License for more details.                          *
#                                                                         *
#   You should have received a copy of the GNU General Public License     *
#   along with this program; if not, write to the                         *
#   Free Software Foundation, Inc.,                                       *
#   51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.         *
#**************************************************************************/
package NDIRC::Scans;
use strict;
use warnings;
use ND::DB;
use NDIRC::Access;
require Exporter;

our @ISA = qw/Exporter/;

our @EXPORT = qw/addScan addScanGroup sendScan reqScan scanReqs/;

sub addScan {
	my ($id,$verbose, $quiet) = @_;
	if (1){
		unless ($ND::DBH->selectrow_array(q{SELECT scan_id FROM scans WHERE NOT groupscan AND scan_id = ? AND tick >= tick() - 168},undef,$id)){
			my @user = $ND::DBH->selectrow_array(q{SELECT uid,username, scan_points, tick() 
				FROM users WHERE hostmask ILIKE ? },undef,$ND::address);
			if ($ND::DBH->do(q{INSERT INTO scans (scan_id,tick,uid) VALUES (?,tick(),COALESCE(?,-1))},
					undef,$id,$user[0]) == 1){
				if (@user){
					$ND::DBH->do('UPDATE users SET scan_points = scan_points + 1 WHERE uid = ? ',undef,$user[0]);
					$user[2] += 1;
					if ($quiet){
						$ND::server->command("msg $ND::target Added scan, points now $user[2]");
					}
					else{
						$ND::server->command("msg $ND::target Added scan, at tick $user[3]. $user[1] points now $user[2]");
					}
				}elsif ($verbose){
					$ND::server->command("msg $ND::target Added scan, but unknown user, no points");
				}
			}
		}elsif ($verbose){
			$ND::server->command("msg $ND::target a scan with that id has already been added within the last 48 ticks");
		}
	}
}
sub addScanGroup {
	my ($id,$verbose) = @_;
	if (1){
		unless ($ND::DBH->selectrow_array("SELECT scan_id FROM scans WHERE groupscan AND  scan_id = ? AND tick >= tick() - 168",undef,$id)){
			my @user = $ND::DBH->selectrow_array(q{SELECT uid,username, scan_points, tick() 
				FROM users WHERE hostmask ILIKE ? },undef,$ND::address);
			if ($ND::DBH->do(q{INSERT INTO scans (scan_id,tick,groupscan,uid) VALUES (?,tick(),true,COALESCE(?,-1))},
					undef,$id,$user[0]) == 1){
				if (@user){
					$ND::server->command("msg $ND::target Added scan group, at tick $user[3]. Points will be added after parsing");
				}elsif ($verbose){
					$ND::server->command("msg $ND::target Added scan, but unknown user, no points");
				}
			}
		}elsif ($verbose){
			$ND::server->command("msg $ND::target a scan with that id has already been added within the last 48 ticks");
		}
	}
}

sub sendScan {
	my ($msg, $command) = @_;
	my ($target,$mess);
	if (defined $msg && $msg =~ /^(\S+) (.*)$/){
		$target = $1;
		$mess = $2;
	}else{
		$ND::server->command("notice $ND::nick syntax: $command nick message");
		return;
	}
	if (scanner()){
		$ND::server->command("msg $target ".chr(2).$mess.chr(3)."4 (reply with /msg $ND::scanchan)");
		$ND::server->command("msg $ND::target ${ND::C}3$target << $mess");
	}
}

our %scanid = (p => 1, s => 2, t => 3, u => 4, n => 5, j => 7, a => 8);

our @scantypes = ('Planet','Surface Analysis', 'Technology Analysis'
	,'Unit', 'News', 'Incoming', 'Jumpgate', 'Advanced Unit');

sub reqScan {
	my ($msg, $command) = @_;

	my ($x, $y, $z, $type, $typeid);
	if (defined $msg && $msg =~ /^([pstunja]) (\d+)\D+(\d+)\D+(\d+) (\S.*)/){
		$typeid = $scanid{$1};
		$type = $scantypes[$typeid-1];
		($x,$y,$z) = ($2,$3,$4);
		$msg = $5;
	}else{
		$ND::server->command("notice $ND::nick syntax: $command type X:Y:Z message"
			. " | type is the first character in the scan name, like p for planet scan, message is a message to scanners, message is a message to scanners, like plz or thanks like plz or thanks");
		return;
	}

	if (my $user = member){

		my $planet = $ND::DBH->selectrow_array(q{SELECT planetid($1,$2,$3,$4)}
			,undef,$x,$y,$z,$ND::tick);

		my $query = $ND::DBH->prepare(q{SELECT scan_id
			FROM scans
			WHERE planet = $1 AND type = $2 AND tick >= $3});
		$query->execute($planet,$type,$ND::tick);

		if (my $scan = $query->fetchrow_hashref){
			$ND::server->command("notice $ND::nick scan already exist: "
				. "http://game.planetarion.com/showscan.pl?scan_id=$scan->{scan_id}");
		}else{
			my $req = $ND::DBH->prepare(q{SELECT * FROM scan_requests
				WHERE uid = $1 AND planet = $2
					AND type = $3 AND NOT sent
			});
			$req->execute($user->{uid},$planet,$type);

			my $id;
			if(my $scan = $req->fetchrow_hashref){
				$req = $ND::DBH->prepare(q{UPDATE scan_requests
					SET nick = $1, tick = tick(), time = NOW()
					WHERE id = $2});
				$req->execute($ND::nick,$scan->{id});
				$id = $scan->{id};
			}else{
				$req = $ND::DBH->prepare(q{INSERT INTO scan_requests
					(uid,nick,planet,type) VALUES($1,$2,$3,$4)
					RETURNING (id)});
				$req->execute($user->{uid},$ND::nick,$planet,$type);
				$id = $req->fetchrow;
			}

			if ($id){
				$ND::server->command("msg $ND::scanchan "
					. "$ND::B$id$ND::O http://game.planetarion.com/waves.pl?id=$typeid&x=$x&y=$y&z=$z"
					. " ($x:$y:$z $type) | <$ND::nick> $msg"
				);
				$ND::server->command("notice $ND::nick sent request ($x:$y:$z $type)");
			}else{
				$ND::server->command("notice $ND::nick something went wrong..");
			}

		}
	}
}

our %scantypes;
{
	my $i = 1;
	%scantypes = map {$_ => $i++} @scantypes;
}

sub scanReqs {
	my ($msg, $command) = @_;

	if (scanner()){

		my $reqs = $ND::DBH->prepare(q{SELECT min(sr.id) AS id, x,y,z,type
			FROM scan_requests sr
				JOIN current_planet_stats p ON p.id = sr.planet
			WHERE sr.time > NOW() - '30 min'::INTERVAL
				AND NOT EXISTS (SELECT scan_id FROM scans
					WHERE planet = sr.planet
						AND type = sr.type
						AND tick >= sr.tick
				)
			GROUP BY x,y,z,type
			ORDER BY id
			});
		$reqs->execute;
		my $text = '';
		while (my $req = $reqs->fetchrow_hashref){
			$text .= "$ND::B$req->{id}$ND::O http://game.planetarion.com/waves.pl?id=$scantypes{$req->{type}}&x=$req->{x}&y=$req->{y}&z=$req->{z} "
		}

		$text = 'No unhandled reqests.' unless $text;
		$ND::server->command("notice $ND::nick $text");
	}
}

1;
