#**************************************************************************
#   Copyright (C) 2009 by Michael Andreen <harvATruinDOTnu>               *
#                                                                         *
#   This program is free software; you can redistribute it and/or modify  *
#   it under the terms of the GNU General Public License as published by  *
#   the Free Software Foundation; either version 2 of the License, or     *
#   (at your option) any later version.                                   *
#                                                                         *
#   This program is distributed in the hope that it will be useful,       *
#   but WITHOUT ANY WARRANTY; without even the implied warranty of        *
#   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the         *
#   GNU General Public License for more details.                          *
#                                                                         *
#   You should have received a copy of the GNU General Public License     *
#   along with this program; if not, write to the                         *
#   Free Software Foundation, Inc.,                                       *
#   51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.         *
#**************************************************************************/
package NDIRC::Bot;

use strict;
use warnings;
use feature ':5.10';

use Moose;

use POE::Component::IRC::Common qw/irc_to_utf8/;
use POE::Session;
use POE::Component::IRC::Plugin::Logger;
use POE::Component::IRC::Plugin::BotTraffic;
use POE::Component::IRC::Plugin::Connector;
use POE::Component::IRC::Plugin::AutoJoin;
use POE::Component::IRC::Plugin::NickReclaim;

use Mojo::Discord;
use Mojo::IOLoop;

use NDIRC::Dispatcher;
use NDIRC::IrcContext;

use IO::File;

has disp => (
	is => 'rw',
	isa => 'Object',
	lazy_build => 1
);

has discord => (
	is => 'rw',
	isa => 'Object'
);

has discord_name => (
	is => 'rw',
	isa => 'Str'
);

has discord_id => (
	is => 'rw',
	isa => 'Str'
);

has discord_channels => (
	is => 'rw',
	isa => 'HashRef',
	default => sub { {} }
);

# We registered for all events, this will produce some debug info.
sub _default {
	my ($event, $args) = @_[ARG0 .. $#_];
	my @output = ( "$event: " );

	for my $arg (@$args) {
		if ( ref $arg eq 'ARRAY' ) {
			push( @output, '[' . join(', ', @$arg ) . ']' );
		}
		else {
			push ( @output, "'$arg'" );
		}
	}
	print join ' ', @output, "\n";
	return 0;
}

sub _start {
	my ($self,$kernel,$heap,$session) = @_[OBJECT,KERNEL,HEAP,SESSION];

	# retrieve our component's object from the heap where we stashed it
	my $irc = $heap->{irc};
	$kernel->sig( DIE => 'sig_DIE' );
	$kernel->sig( USR1 => 'sig_usr1' );
	$kernel->sig( USR2 => 'sig_usr2' );
	$kernel->sig( INT => 'signal_handler' );

	$irc->plugin_add( 'NickReclaim', POE::Component::IRC::Plugin::NickReclaim->new() );
	$irc->plugin_add( 'AutoJoin', POE::Component::IRC::Plugin::NickReclaim->new() );
	$irc->plugin_add( 'BotTraffic', POE::Component::IRC::Plugin::BotTraffic->new() );
	$irc->plugin_add('Logger', POE::Component::IRC::Plugin::Logger->new(
		Path    => 'irclogs',
		DCC     => 0,
		Private => 1,
		Public  => 1,
		Sort_by_date => 1,
		Strip_color => 1,
		Strip_formatting => 1,
		Notices => 1,
	));

	$heap->{connector} = POE::Component::IRC::Plugin::Connector->new(
		servers => [['irc.netgamers.org'], ['underworld.no.eu.netgamers.org']
			,['firefly.no.eu.netgamers.org'], ['underworld.ca.us.netgamers.org'] ]
	);
	$irc->plugin_add( 'Connector' => $heap->{connector} );

	$irc->yield( register => 'all' );
	$irc->yield( connect => { server => 'irc.netgamers.org' } );

	$kernel->delay( refresh => 60 );

	if (my $f =  new IO::File 'discord'){
		my $user = <$f>;
		chomp $user;
		my $token = <$f>;
		chomp $token;

		$self->discord(Mojo::Discord->new(
				'token'     => $token,
				'name'      => $user,
				'url'       => 'https://nd.ruin.nu',
				'version'   => '1.0',
				'callbacks' => {
					'READY'          => sub { $self->discord_ready(@_) },
					'MESSAGE_CREATE' => sub { $self->discord_message_create(@_) },
					'GUILD_CREATE' => sub { $self->discord_guild_create(@_) },
					'CHANNEL_CREATE' => sub { $self->discord_channel_create(@_) },
				},
				'reconnect' => 1,
				'verbose'   => 1,
			));
		$self->discord->init();
	}
	return;
}

sub auth {
	my $heap = $_[HEAP];

	if (my $f =  new IO::File 'auth'){
		my $user = <$f>;
		chomp $user;
		my $pass = <$f>;
		chomp $pass;
		$heap->{irc}->yield(qbot_auth => $user => $pass);
	}
}

sub sig_usr1 {
	my ($kernel,$heap) = @_[KERNEL,HEAP];

	$kernel->yield( 'refresh' );
}

sub clear_constraint {
	my $tc = shift;

	while (1) {
		if (ref $tc eq 'MooseX::Meta::TypeConstraint::Structured'){
			for my $t (@{$tc->{type_constraints}}){
				clear_constraint($t);
			}

		}
		if (ref $tc eq 'Moose::Meta::TypeConstraint::Parameterized'){
			clear_constraint($tc->{type_parameter});
		}
		last if ref $tc eq 'HASH';
		last if ref $tc eq '';
		if (defined $tc->{_type_constraint}){
			$tc = $tc->{_type_constraint};
		}elsif(defined $tc->{__type_constraint}){
			$tc = $tc->{__type_constraint};
		}else{
			last;
		}
	}
}

sub clear_metains {
	my $ins = shift;

	for my $a (@{$ins->{attributes}}){
		for my $m (@{$a->{associated_methods}}){
			$m->{body} = undef;
		}
		clear_constraint($a->{isa});
	}
}

sub clear_cycles {
	my $c = shift;

	for my $m (values %{$c->meta->{methods}}){
		clear_constraint($m->{type_constraint});

		my $ps = $m->{parsed_signature};
		for my $p (@{$ps->{_positional_params}->{params}}){
			clear_metains($p->{__MOP__}->{_meta_instance});
		}

		$m->{body} = undef;
	}
	clear_metains($c->meta->{_meta_instance});
}


sub sig_usr2 {
	my $self = shift @_;

	for my $c (values %{$self->disp->commands}){
		clear_cycles($c);
	}

	$self->disp($self->_build_disp);
}

sub _build_disp {
	my ($self) = @_;
	my $disp = new NDIRC::Dispatcher;

	if (my $commands = new IO::File 'commands'){
		my @commands = split /\W+/, do{local $/; <$commands>};
		say "Loading commands from: @commands";
		$disp->load(@commands);
	}

	my $channels = new IO::File 'channels' or die $!;;
	while (<$channels>){
		my ($chan, @types) = split /\s+/;
		say "$chan - @types";
		if ($chan =~ /^(.*):(.*)$/){
			$chan = $1;
			$disp->set_target($2,$chan);
		}
		$disp->add_channel($chan,\@types);
	}

	return $disp;
}

sub sig_DIE {
	my( $kernel,$sig, $ex ) = @_[ KERNEL,ARG0, ARG1 ];
	say "DIED!!!!!!!!!!!!!!";
	# $sig is 'DIE'
	# $ex is the exception hash
	warn "$$: error in event: $ex->{error_str}";
	$kernel->sig_handled();

	# Send the signal to session that sent the original event.
	#if( $ex->{source_session} ne $_[SESSION] ) {
	#$kernel->signal( $ex->{source_session}, 'DIE', $sig, $ex );
	#}
}

sub signal_handler {
	my ($kernel, $signal_name, $heap) = @_[KERNEL, ARG0, HEAP];
	print "First session caught SIG$signal_name\n";

	given($signal_name){
		when ('INT') {
			exit unless $heap->{irc}->connected;
			$heap->{INT} = 1;
			$heap->{irc}->yield(quit => 'Bye!');
			$kernel->sig_handled();
		}
	}
	#$kernel->sig_handled();
}

sub irc_disconnected {
	my ($sender,$heap) = @_[SENDER,HEAP];

	exit if $heap->{INT};
}

sub irc_001 {
	my ($self,$sender,$kernel) = @_[OBJECT,SENDER,KERNEL];

	# Since this is an irc_* event, we can get the component's object by
	# accessing the heap of the sender. Then we register and connect to the
	# specified server.
	my $irc = $sender->get_heap();

	print "Connected to ", $irc->server_name(), "\n";

	$kernel->yield( 'auth' );
	$irc->yield( mode => $irc->nick_name, '+ix');

	# we join our channels
	$irc->yield( join => $_ ) for grep /^#/, keys %{$self->disp->channels};
	return;
}

sub irc_invite {
	my ($self,$sender, $who, $channel) = @_[OBJECT,SENDER, ARG0 .. ARG1];
	my $irc = $sender->get_heap();

	$irc->yield( join => $_ ) for grep /^$channel$/i, keys %{$self->disp->channels}
}

sub irc_public {
	$_[ARG2] = irc_to_utf8 $_[ARG2];
}

sub irc_msg {
	$_[ARG2] = irc_to_utf8 $_[ARG2];
}

sub  refresh {
}

sub irc_join {
}

sub discord_ready {
	my $self = shift;
	my $hash = shift;
	$self->discord_id($hash->{user}{id});
	$self->discord_name($hash->{user}{username});

	say localtime(time) . " - Connected to Discord. $self->{discord_id}";
}

sub discord_message_create {
}

sub discord_guild_create {
	my $self = shift;
	my $hash = shift;

	for my $chan (@{$hash->{channels}}) {
		say localtime(time) . " - $chan->{id} - $chan->{name}";
		$self->discord_channels->{$chan->{id}} = $chan;
	}
}

sub discord_channel_create {
	my $self = shift;
	my $chan = shift;

	for my $key (keys %{$chan}) {
		say localtime(time) . " - $key - $chan->{$key}";
	}
	$self->discord_channels->{$chan->{id}} = $chan;
}

sub parseCommand {
	my ($self, $msg, $server, $nick, $address, $channel, $model) = @_;

	return if $channel !~ /^#/ && $msg =~ /^~/;
	$msg = ".$msg"  if $channel !~ /^#/ && $msg =~ /^[^.!]/;

	my ($p,$command,$args) = ($msg =~ /^([.!~])(\S+)(?: (.+))?/);

	if ($msg =~ m{https?://[\w.]+/.+?scan(_id|_grp)?=(\w+)}){
		if (!$command || $command =~ m{^https?://}){
			($p,$command,$args) = ('.','addscan',$msg);
		}elsif($command ne 'addscan'){
			$self->parseCommand (".addscan $msg", $server, $nick, $address, $channel, $model)
		}
	}

	return 0 unless $self->disp->has_command($command,$channel);

	my $reply_string;
	given ($p){
		when ('!'){
			$reply_string = "privmsg $nick";
		}
		when ('~'){
			$reply_string = "privmsg $channel";
		}
		default {
			$reply_string = "notice $nick";
		}
	}

	$address =~ s/.*@(.*)/$1/;
	my $c = NDIRC::IrcContext->new({
			host => $address,
			nick => $nick,
			channel => $channel,
			disp => $self->disp,
			model => $model,
			server => $server,
			reply_string => $reply_string,
		});

	return $self->disp->run_command($c,$command,$args);
}

1;
