#**************************************************************************
#   Copyright (C) 2009 by Michael Andreen <harvATruinDOTnu>               *
#                                                                         *
#   This program is free software; you can redistribute it and/or modify  *
#   it under the terms of the GNU General Public License as published by  *
#   the Free Software Foundation; either version 2 of the License, or     *
#   (at your option) any later version.                                   *
#                                                                         *
#   This program is distributed in the hope that it will be useful,       *
#   but WITHOUT ANY WARRANTY; without even the implied warranty of        *
#   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the         *
#   GNU General Public License for more details.                          *
#                                                                         *
#   You should have received a copy of the GNU General Public License     *
#   along with this program; if not, write to the                         *
#   Free Software Foundation, Inc.,                                       *
#   51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.         *
#**************************************************************************/

use strict;
use warnings;
use feature ':5.10';

use MooseX::Declare;
use NDIRC::Dispatcher;

use Tie::File;
use File::Temp ();

tie my @FILE, 'Tie::File', "quote.txt";
tie my @OLDFILE, 'Tie::File',"oldquotes.txt" or die "test";

command quote => {
	help => q(syntax .quote [number] | if number isn't given, then a random quote is used),
	alias => q(lastquote),
}, class extends NDIRC::Command {
	method execute($c,$msg) {
		my ($n) = $msg =~ /(\d+)/;

		$n = $n-1 if defined $n;
		$n //= int(rand($#FILE));
		$n = $#FILE if $self->name eq 'lastquote';

		my $text = $FILE[$n];
		$text =~ s/(.*?)[\r\n]*$/$1/;
		$n++;
		my $num = $#FILE+1;
		$c->reply("Quote <b>$n</b> of <b>$num</b>: $text");
	}
};

command addquote => {
	help => q(syntax .addquote quote),
}, class extends NDIRC::Command {
	method execute($c,$quote) {

		die 'ARGS' unless $quote;

		push @FILE, $quote;
		my $num = $#FILE+1;
		$c->reply("Quote <b>$num</b> added");
	}
};

command findquote => {
	help => q(syntax .findquote pattern | findqre lets you use a regex pattern),
	alias => q(findqre),
}, class extends NDIRC::Command {
	my $file;
	method execute($c,$pattern) {
		die 'ARGS' unless $pattern;

		my $matcher;
		if ($self->name eq 'findqre'){
			if (defined (eval 'm/$pattern/ix')){
				$matcher = 'm/$pattern/ix';
			}else {
				$c->reply("bad regexp");
				return;
			}
		}else{
			$matcher = '(index uc($_), uc($pattern)) != -1';
		}
		$file = new File::Temp( SUFFIX => '.txt' );
		my $n = 1;
		my $match = 0;
		for (@FILE){
			chomp;
			if (eval $matcher){
				$match = 1;
				print $file "$n: $_\n";
			}
			$n++;
		}
		if ($match){
			$file->flush;
			$c->command(dcc => $c->nick => SEND => $file);
		}else{
			$c->reply("No quotes matching <b>$pattern.</b>");
		}
	}
};

command delquote => {
	help => q(syntax: .delquote number),
	acl => q(irc_delquote),
}, class extends NDIRC::Command {
	method execute($c,$msg) {
		my ($n) = $msg =~ /(\d+)/ or die 'ARGS';
		$n = $n-1;
		if (exists $FILE[$n]){
			my ($uid,$username) = $c->model->selectrow_array(q{
SELECT uid,username FROM users where uid = ?
				},undef,$c->uid);

			my $text = $FILE[$n];
			push @OLDFILE,"Removed by $username ($uid): $text";
			splice @FILE,$n,1;
			$n++;
			my $num = $#FILE+1;
			$c->reply("Quote <b>$n</b> {$text} removed, number of quotes now: <b>$num</b>");
		}else{
			$c->reply("No such quote.");
		}
	}
};

1;
