#**************************************************************************
#   Copyright (C) 2009 by Michael Andreen <harvATruinDOTnu>               *
#                                                                         *
#   This program is free software; you can redistribute it and/or modify  *
#   it under the terms of the GNU General Public License as published by  *
#   the Free Software Foundation; either version 2 of the License, or     *
#   (at your option) any later version.                                   *
#                                                                         *
#   This program is distributed in the hope that it will be useful,       *
#   but WITHOUT ANY WARRANTY; without even the implied warranty of        *
#   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the         *
#   GNU General Public License for more details.                          *
#                                                                         *
#   You should have received a copy of the GNU General Public License     *
#   along with this program; if not, write to the                         *
#   Free Software Foundation, Inc.,                                       *
#   51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.         *
#**************************************************************************/

package NDIRC::Commands::Quotes;

use strict;
use warnings;
use feature ':5.10';

use Moose;
use MooseX::MethodAttributes;

use Tie::File;
use File::Temp ();

tie my @FILE, 'Tie::File', "quote.txt";
tie my @OLDFILE, 'Tie::File',"oldquotes.txt" or die "test";

sub quote
	: Help(syntax .quote [number] | if number isn't given, then a random quote is used)
	: Alias(lastquote)
{
	my ($self,$c,$msg) = @_;
	my ($n) = $msg =~ /(\d+)/;

	$n = $n-1 if defined $n;
	$n //= int(rand($#FILE));
	$n = $#FILE if $self->name eq 'lastquote';

	my $text = $FILE[$n];
	$text =~ s/(.*?)[\r\n]*$/$1/;
	$n++;
	my $num = $#FILE+1;
	$c->reply("Quote <b>$n</b> of <b>$num</b>: $text");
}

sub addquote
	: Help(syntax .addquote quote)
{
	my ($self,$c,$quote) = @_;

	die 'ARGS' unless $quote;

	push @FILE, $quote;
	my $num = $#FILE+1;
	$c->reply("Quote <b>$num</b> added");
}

sub findquote
	: Help(syntax .findquote pattern | findqre lets you use a regex pattern)
	: Alias(findqre)
{
	my ($self,$c,$pattern) = @_;
	die 'ARGS' unless $pattern;
	my $matcher;
	if ($self->name eq 'findqre'){
		if (defined (eval 'm/$pattern/ix')){
			$matcher = 'm/$pattern/ix';
		}else {
			$c->reply("bad regexp");
			return;
		}
	}else{
		$matcher = '(index uc($_), uc($pattern)) != -1';
	}
	my $file = new File::Temp( SUFFIX => '.txt' );
	my $n = 1;
	my $match = 0;
	for (@FILE){
		chomp;
		if (eval $matcher){
			$match = 1;
			print $file "$n: $_\n";
		}
		$n++;
	}
	if ($match){
		close $file;
		$c->message("dcc send ".$c->nick, $file);
	}else{
		$c->reply("No quotes matching <b>$pattern.</b>");
	}
}

sub delquote
	: Help(syntax: .delquote number)
	: ACL(irc_delquote)
{
	my ($self,$c,$msg) = @_;
	my ($n) = $msg =~ /(\d+)/ or die 'ARGS';
	$n = $n-1;
	if (exists $FILE[$n]){
		my ($uid,$username) = $c->model->selectrow_array(q{
SELECT uid,username FROM users where hostmask ILIKE ?
			},undef,$c->host);

		my $text = $FILE[$n];
		push @OLDFILE,"Removed by $username ($uid): $text";
		splice @FILE,$n,1;
		$n++;
		my $num = $#FILE+1;
		$c->reply("Quote <b>$n</b> {$text} removed, number of quotes now: <b>$num</b>");
	}else{
		$c->reply("No such quote.");
	}
}

1;
