#**************************************************************************
#   Copyright (C) 2009 by Michael Andreen <harvATruinDOTnu>               *
#                                                                         *
#   This program is free software; you can redistribute it and/or modify  *
#   it under the terms of the GNU General Public License as published by  *
#   the Free Software Foundation; either version 2 of the License, or     *
#   (at your option) any later version.                                   *
#                                                                         *
#   This program is distributed in the hope that it will be useful,       *
#   but WITHOUT ANY WARRANTY; without even the implied warranty of        *
#   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the         *
#   GNU General Public License for more details.                          *
#                                                                         *
#   You should have received a copy of the GNU General Public License     *
#   along with this program; if not, write to the                         *
#   Free Software Foundation, Inc.,                                       *
#   51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.         *
#**************************************************************************/

package NDIRC::Context;
use strict;
use warnings;
use feature ':5.10';

use Moose;
use namespace::autoclean;

use Set::Object ();

has channel => (
	is => 'ro',
	isa => 'Str',
	required => 1
);

has roles => (
	is => 'ro',
	isa => 'Object',
	lazy_build => 1
);

has uid => (
	is => 'ro',
	isa => 'Int',
	lazy_build => 1
);

has disp => (
	is => 'ro',
	isa => 'Object',
	required => 1
);

has model => (
	is => 'ro',
	isa => 'Object',
	required => 1
);

sub assert_user_roles {
	my ($self,@roles) = @_;
	return 1 unless @roles;

	my $need = Set::Object->new(@roles);

	if ($self->roles->superset($need)){
		return 1;
	}

	die "Access denied";
}

sub check_user_roles {
	my ($self,@roles) = @_;

	local $@;
	eval { $self->assert_user_roles(@roles) };
}

sub reply {
}

sub message {
}

sub intel_log {
	my ($c,$planet, $message) = @_;
	my $log = $c->model->prepare_cached(q{
INSERT INTO forum_posts (ftid,uid,message) VALUES(
	(SELECT ftid FROM planets WHERE pid = $3),$1,$2)
		});
	$log->execute($c->uid,$message,$planet);
}

sub def_log {
	my ($c,$call, $message) = @_;
	my $log = $c->model->prepare(q{
INSERT INTO forum_posts (ftid,uid,message) VALUES(
	(SELECT ftid FROM calls WHERE call = $3),$1,$2)
		});
	$log->execute($c->uid,$message,$call);
}

sub _build_roles {
	my ($self) = @_;

	my $query = $self->model->prepare(q{
SELECT role FROM group_roles
WHERE gid IN (SELECT gid FROM groupmembers JOIN users USING (uid)
	WHERE uid = $1)
		});
	$query->execute($self->uid);

	my @roles;
	while (my $group = $query->fetchrow_hashref){
		push @roles,$group->{role};
	}
	return Set::Object->new(@roles);
}

sub _build_uid {
	my ($self) = @_;

	return -4;
}

sub valuecolor {
	shift @_;
	my $s = $_;
	return $s;
}

__PACKAGE__->meta->make_immutable;
1;
