#**************************************************************************
#   Copyright (C) 2006 by Michael Andreen <harvATruinDOTnu>               *
#                                                                         *
#   This program is free software; you can redistribute it and/or modify  *
#   it under the terms of the GNU General Public License as published by  *
#   the Free Software Foundation; either version 2 of the License, or     *
#   (at your option) any later version.                                   *
#                                                                         *
#   This program is distributed in the hope that it will be useful,       *
#   but WITHOUT ANY WARRANTY; without even the implied warranty of        *
#   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the         *
#   GNU General Public License for more details.                          *
#                                                                         *
#   You should have received a copy of the GNU General Public License     *
#   along with this program; if not, write to the                         *
#   Free Software Foundation, Inc.,                                       *
#   51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.         *
#**************************************************************************/
package NDIRC::Delling;

use strict;
use warnings;
use feature ':5.10';

use POE::Session;
use NDIRC::Misc;
use ND::DB;

sub irc_public {
	my ($sender, $heap, $who, $where, $msg) = @_[SENDER, HEAP, ARG0 .. ARG2];
	my ($nick,$username,$address) = ( split /[!@]/, $who );
	my $channel = $where->[0];

	my $irc = $sender->get_heap();

	#$irc->yield(privmsg => $channel, "Authed? " . $irc->is_nick_authed($nick));
	my $dbh = DB();
	my $seen = $dbh->prepare_cached(q{UPDATE users SET laston = NOW() WHERE hostmask = ?});
	$seen->execute($address);

	if ($msg =~ /^(\S+): (.+)$/ && $heap->{disp}->has_command('anon',$channel)){
		my $_ = $1;
		my $text = $2;
		unless ($irc->is_channel_member($channel,$1) || /(Constructing|Researching)/){
			$msg = ".anon $_ $text";
		}

	}
	if (parseCommand($msg,$irc,$nick,$address,$channel,$heap->{disp},$dbh)){
		#Command parsed and run successfully
	}
}


sub irc_msg {
	my ($sender, $heap, $who, $where, $msg) = @_[SENDER, HEAP, ARG0 .. ARG2];
	my ($nick,$username,$address) = ( split /[!@]/, $who );
	my $irc = $sender->get_heap();

	my $dbh = DB();
	my $seen = $dbh->prepare_cached(q{UPDATE users SET laston = NOW() WHERE hostmask = ?});
	$seen->execute($address);

	if (parseCommand($msg,$irc,$nick,$address,'pm',$heap->{disp},$dbh)){
		#Command parsed and run successfully
	}else{
		$irc->yield(notice => $nick, "unknown command");
	}
}

sub irc_join {
	my ($sender, $heap, $who, $channel) = @_[SENDER, HEAP, ARG0 .. ARG1];
	my ($nick,$username,$address) = ( split /[!@]/, $who );
	my $irc = $sender->get_heap();

	my $dbh = DB();
	my $seen = $dbh->prepare_cached(q{UPDATE users SET laston = NOW() WHERE hostmask = ?});
	$seen->execute($address);

	if($heap->{disp}->has_command('voice',$channel)){
		my $flags = $dbh->prepare_cached(q{
SELECT DISTINCT flag
FROM users u
	JOIN groupmembers g USING (uid)
	JOIN channel_group_flags gf USING (gid)
WHERE u.hostmask = $1 AND channel = $2 AND flag IN ('o','v');
		});
		$flags->execute($address, $channel);
		my $mode = '';
		my @who;
		while (my ($flag) = $flags->fetchrow()){
			$mode .= $flag;
			push @who, $nick;
		}
		say "$mode - @who";
		$irc->yield(mode => $channel, $mode, @who) if $mode;
	}
}

sub refresh {
	my ($kernel,$heap) = @_[KERNEL,HEAP];
	$kernel->delay( refresh => 60 );
	print 'Time: ' . time() . ' Lag: ' . $heap->{connector}->lag() . "\n";

	my $dbh = DB();
	my $scans = $dbh->prepare(q{SELECT s.scan_id
			,array_agg(sr.nick) AS nick
			,array_agg(sr.id) AS id
		FROM scan_requests sr
			JOIN scans s USING (pid,type)
		WHERE sr.time > NOW() - '30 min'::INTERVAL
			AND s.tick >= sr.tick AND NOT sr.sent
		GROUP BY scan_id
		});
	my $sentscan = $dbh->prepare(q{UPDATE scan_requests
		SET sent = TRUE WHERE id = ANY($1)
		});
	$scans->execute;
	while (my $scan = $scans->fetchrow_hashref){
		$heap->{irc}->yield(notice => $scan->{nick}, "http://game.planetarion.com/showscan.pl?scan_id=$scan->{scan_id}");
		$sentscan->execute($scan->{id});
	}
	return;
}

1;
