#!/usr/bin/perl
q{
/***************************************************************************
 *   Copyright (C) 2006 by Michael Andreen <harvATruinDOTnu>               *
 *                                                                         *
 *   This program is free software; you can redistribute it and/or modify  *
 *   it under the terms of the GNU General Public License as published by  *
 *   the Free Software Foundation; either version 2 of the License, or     *
 *   (at your option) any later version.                                   *
 *                                                                         *
 *   This program is distributed in the hope that it will be useful,       *
 *   but WITHOUT ANY WARRANTY; without even the implied warranty of        *
 *   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the         *
 *   GNU General Public License for more details.                          *
 *                                                                         *
 *   You should have received a copy of the GNU General Public License     *
 *   along with this program; if not, write to the                         *
 *   Free Software Foundation, Inc.,                                       *
 *   51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.         *
 ***************************************************************************/
};

use strict;
use warnings;
use local::lib;
use DBI;
use DBD::Pg qw(:pg_types);
use CGI qw/:standard/;
use Data::Dumper;

use Email::Simple;
use Encode;
use MIME::QuotedPrint;

use FindBin;
use lib "$FindBin::Bin/../lib";
use ND::DB;

my $dbh = ND::DB::DB();

my @text = <>;
my $text = join '',@text;

$text =~ /ndreport\+(.+?)\@ruin\.nu/;

my $user = $1;

my $email = Email::Simple->new($text);

my $body =  decode('ISO-8859-1', $email->body);

unless ($body =~ /Report of events in tick (\d+)/) {
	exit 0;
}

my $tick = $1;

my $c = $dbh->prepare(q{
SELECT coords(x,y,z), uid, pid
FROM users u
	LEFT JOIN current_planet_stats p USING (pid)
WHERE username = $1
	AND uid IN (SELECT uid FROM groupmembers WHERE gid = 'M')
});
my ($coords, $uid, $pid) = $dbh->selectrow_array($c, undef, $user);

$coords //= '(no coords entered)';

my $attacker = $dbh->prepare(q{
SELECT pid, race FROM current_planet_stats WHERE x = $1 AND y = $2 AND z = $3
});

my $report = $dbh->prepare(q{INSERT INTO irc_requests (channel,uid,message) VALUES('def',$1,$2)});


my $message = "Tick **$tick**: *$user* $coords has incs\n";

my $add_inc = $dbh->prepare(q{INSERT INTO incomings (call,pid,eta,amount,fleet) VALUES($1,$2,$3,$4,$5)});

my $find_call = $dbh->prepare(q{
SELECT call, count(*) AS count
FROM calls
	JOIN incomings i USING (call)
WHERE uid = $1 AND landing_tick = $2
GROUP BY call
});
my $add_call = $dbh->prepare(q{
INSERT INTO calls
	(uid,landing_tick,info)
	VALUES($1,$2,'')
RETURNING call
});

my $fleetcatch = $dbh->prepare(q{
SELECT count(*) FROM launch_confirmations WHERE uid = $1 AND back = $2
});


my %incs;
while($body =~ /jumpgate from (.+?), located at (\d+):(\d+):(\d+).+?our system in tick (\d+) and appears to have (\d+)/sg){
	my ($fleet, $x,$y,$z,$landing_tick, $amount) = ($1,$2,$3,$4,$5,$6);

	my $eta = $landing_tick - $tick;

	my ($pid, $race) = $dbh->selectrow_array($attacker,undef, $x,$y,$z);

	push @{$incs{$landing_tick}}, {x => $x, y => $y, z => $z, eta => $eta, amount => $amount, race => $race, fleet => $fleet, pid => $pid};
}

for my $landing_tick (sort keys %incs) {
	$message .= "\n> Landing tick: *$landing_tick*";
	my $call;
	if ($uid) {
		my ($returning) = $dbh->selectrow_array($fleetcatch, undef, $uid, $landing_tick);
		if ($returning > 0) {
			$message .= "\n**THIS IS A POSSIBLE FLEETCATCH!**"
		}
		if (my $c = $dbh->selectrow_hashref($find_call, undef, $uid, $landing_tick)) {
			$call = $c->{call};
			$message .= "\n__Previously an addtional **$c->{count}** fleets landing on this tick__"
		}
		else
		{
			($call) = $dbh->selectrow_array($add_call, undef, $uid, $landing_tick);
		}
	}
	$message .= "\n```";
	for my $i (@{$incs{$landing_tick}}) {
		if ($uid)
		{
			$add_inc->execute($call, $i->{pid}, $i->{eta}, $i->{amount}, $i->{fleet});
		}
		$message .= "\n$i->{x}:$i->{y}:$i->{z} $i->{race} $i->{eta} $i->{amount} $i->{fleet} "
	}
	$message .= "```";
}


#print $message;

$report->execute(-5,$message);

$dbh->disconnect;

system 'killall','-USR1', 'ndbot.pl';
