Usermgm.pm

   1 #**************************************************************************
   2 #   Copyright (C) 2006 by Michael Andreen <harvATruinDOTnu>               *
   3 #                                                                         *
   4 #   This program is free software; you can redistribute it and/or modify  *
   5 #   it under the terms of the GNU General Public License as published by  *
   6 #   the Free Software Foundation; either version 2 of the License, or     *
   7 #   (at your option) any later version.                                   *
   8 #                                                                         *
   9 #   This program is distributed in the hope that it will be useful,       *
  10 #   but WITHOUT ANY WARRANTY; without even the implied warranty of        *
  11 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the         *
  12 #   GNU General Public License for more details.                          *
  13 #                                                                         *
  14 #   You should have received a copy of the GNU General Public License     *
  15 #   along with this program; if not, write to the                         *
  16 #   Free Software Foundation, Inc.,                                       *
  17 #   51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.         *
  18 #**************************************************************************/
  19 package NDIRC::Usermgm;
  20 use strict;
  21 use warnings;
  22 use ND::DB;
  23 use NDIRC::Access;
  24 require Exporter;
  25
  26 our @ISA = qw/Exporter/;
  27
  28 our @EXPORT = qw/laston addPoints setHost setPNick getShips getFleet/;
  29
  30 sub laston {
  31         my ($msg, $command) = @_;
  32
  33         if (officer() || ia()){
  34                 my ($flag,$min);
  35                 my $f;
  36                 if(defined $msg && $msg =~ /^(\w)(?: (\d+)(?:\|(\d+)\|(\d+))?)?$/){
  37                         $flag = $1;
  38                         $min = $2;
  39                         my $forum = $3;
  40                         my $claim = $4;
  41                         $min = 0 unless defined $min;
  42                         $f = $ND::DBH->prepare(q{SELECT username, last
  43                                 ,COALESCE(lastforum::text,'?') AS lastforum
  44                                 ,COALESCE(lastclaim::text,'?') AS lastclaim
  45                                 FROM (SELECT username
  46                                         ,date_part('day',now() - laston)::int AS last
  47                                         ,date_part('day',now() - (SELECT max(time) FROM forum_thread_visits WHERE uid = u.uid)) AS lastforum
  48                                         ,date_part('day',now() - (SELECT max(timestamp) FROM raid_claims WHERE uid = u.uid)) AS lastclaim
  49                                         FROM users u
  50                                                 NATURAL JOIN groupmembers
  51                                                 NATURAL JOIN groups
  52                                         WHERE flag = $1
  53                                 ) a
  54                                 WHERE COALESCE(last >= $2,TRUE) AND COALESCE(lastforum >= $3,TRUE) AND COALESCE(lastclaim >= $4,TRUE)
  55                                 ORDER BY last DESC, lastforum DESC, lastclaim DESC
  56                                 });
  57                         $f->execute($flag,$min,$forum,$claim);
  58                 }elsif(defined $msg && $msg =~ /^(\S+)$/){
  59                         $f = $ND::DBH->prepare(q{SELECT username
  60                                 ,date_part('day',now() - laston)::int AS last
  61                                 ,COALESCE(date_part('day',now() - (SELECT max(time) FROM forum_thread_visits WHERE uid = u.uid))::text,'?')
  62                                         AS lastforum
  63                                 ,COALESCE(date_part('day',now() - (SELECT max(timestamp) FROM raid_claims WHERE uid = u.uid))::text,'?') AS lastclaim
  64                                 FROM users u
  65                                 WHERE username ILIKE $1 ORDER BY lower(username)
  66                                 });
  67                         $f->execute($1);
  68                 }else{
  69                         $ND::server->command("notice $ND::nick syntax: .$command <flag [days]|nick> | lists users and the number of days since they were last seen (irc|forum|claim). If days is specified it will only list users with at least that amount of idle time.");
  70                         return;
  71                 }
  72
  73                 my $text;
  74                 my $i = 0;
  75                 while (my $user = $f->fetchrow_hashref){
  76                         $user->{last} = '?' unless defined $user->{last};
  77                         $text .= "$user->{username}($user->{last}|$user->{lastforum}|$user->{lastclaim}) ";
  78                         $i++;
  79                 }
  80                 $ND::server->command("msg $ND::target $ND::B$i$ND::B Users(days)".(defined $flag ?  " with flag $ND::B$flag$ND::B" : "").": $text");
  81         }else{
  82                 $ND::server->command("msg $ND::target Only officers are allowed to check that");
  83         }
  84 }
  85
  86
  87 sub getShips {
  88         my ($ship,$command) = @_;
  89
  90         unless (defined $ship){
  91                 $ND::server->command("notice $ND::nick Usage: .$command ship | % can be used as wildcard, e.g. beet%");
  92                 return;
  93         }
  94         if (officer() || dc()){
  95                 my $f = $ND::DBH->prepare(qq{SELECT username,SUM(fs.amount) AS amount
  96                         FROM users u
  97                                 JOIN (SELECT DISTINCT ON (planet) planet,fid FROM fleets
  98                                         WHERE mission = 'Full fleet' AND name <> 'Unit'
  99                                         ORDER BY planet,tick DESC,fid DESC) f  USING (planet)
 100                                 JOIN fleet_ships fs USING (fid)
 101                         WHERE ship ILIKE ? AND uid IN (SELECT uid FROM groupmembers WHERE gid = 2)
 102                         GROUP BY username ORDER BY amount DESC
 103                         });
 104                 if ($command eq 'shipshome'){
 105                         $f = $ND::DBH->prepare(q{
 106 SELECT username,SUM(amount) AS amount
 107 FROM available_ships
 108 WHERE ship ILIKE ? AND uid IN (SELECT uid FROM groupmembers WHERE gid = 2)
 109 GROUP BY username ORDER BY amount DESC
 110                         });
 111                 }
 112                 $f->execute($ship);
 113                 my $text;
 114                 my $i = 0;
 115                 my $total = 0;
 116                 while (my $user = $f->fetchrow_hashref){
 117                         $user->{last} = '?' unless defined $user->{last};
 118                         $text .= "$user->{username}: $user->{amount} ";
 119                         $i++;
 120                         $total += $user->{amount};
 121                 }
 122                 if ($text){
 123                         $ND::server->command("notice $ND::nick $ND::B$i$ND::B Users with $ND::B$total $ship$ND::B: $text");
 124                 }else{
 125                         $ND::server->command("msg $ND::target $ND::B$i$ND::B Couldn't find any user with $ND::B$ship$ND::B:");
 126                 }
 127         }
 128 }
 129
 130 sub getFleet {
 131         my ($nick,$command) = @_;
 132
 133         unless (defined $nick){
 134                 $ND::server->command("notice $ND::nick Usage: $command nick | % can be used as wildcard, e.g. barr%");
 135                 return;
 136         }
 137         if (officer() || dc()){
 138                 my $f = $ND::DBH->prepare(q{SELECT fs.ship, fs.amount, username
 139                         FROM fleet_ships fs
 140                                 JOIN (SELECT fid,username
 141                                         FROM fleets f
 142                                                 JOIN users u USING (planet)
 143                                         WHERE mission = 'Full fleet' AND name <> 'Unit'
 144                                                 AND username ILIKE $1
 145                                         ORDER BY planet,tick DESC,fid DESC
 146                                         LIMIT 1
 147                                 ) f  USING (fid)
 148                         ORDER BY num
 149                 });
 150                 $f->execute($nick);
 151                 my $text;
 152                 my $username;
 153                 while (my $ship = $f->fetchrow_hashref){
 154                         unless (defined $username) {
 155                                 $username = $ship->{username};
 156                                 $text = "$ND::B$username$ND::O has: "
 157                         }
 158                         $text .= "$ship->{ship} $ship->{amount} ";
 159                 }
 160                 if ($text){
 161                         $ND::server->command("notice $ND::nick $text");
 162                 }else{
 163                         $ND::server->command("notice $ND::nick Couldn't find any fleet for $nick");
 164                 }
 165         }
 166 }
 167
 168 sub addPoints {
 169         my ($msg, $t) = @_;
 170
 171         my ($nick, $points);
 172         if(defined $msg && $msg =~ /^(\S+)(?: (-?(\d+)?(\.\d+)?))?$/){
 173                 $nick = $1;
 174                 $points = $2;
 175         }else{
 176                 $ND::server->command("notice $ND::nick syntax: .$t nick [points] | % can be used for wildcards \%arro\% will match barrow, if the number of points isn't specified, then 1 will be assumed.");
 177                 return;
 178         }
 179         if (   ($t eq "d" && dc())
 180                 || ($t eq "a" && bc())
 181                 || ($t eq "h" && officer())
 182                 || ($t eq "s" && scanner())){
 183                 $points = 1 unless $points;
 184                 if ($points*$points > 400){
 185                         $ND::server->command("msg $ND::target Values between -20 and 20 please");
 186                         return;
 187                 }
 188                 my $f = $ND::DBH->prepare("SELECT uid,username FROM users WHERE username ILIKE ?");
 189                 $f->execute($nick);
 190                 my @row = $f->fetchrow();
 191                 if ($f->rows == 1){
 192                         my $type = "defense";
 193                         $type = "attack" if $t eq "a";
 194                         $type = "humor" if $t eq "h";
 195                         $type = "scan" if $t eq "s";
 196                         my ($fleets) = $ND::DBH->selectrow_array('SELECT count(*) FROM raids r JOIN raid_targets rt ON r.id = rt.raid JOIN raid_claims rc ON rt.id = rc.target WHERE not launched AND uid = ? AND tick + 24 > tick();',undef,$row[0]);
 197                         if ($t eq 'a' && $fleets > 0 && $points > 0){
 198                                 $ND::server->command("msg $ND::target $row[1] has $fleets claimed waves the last 24 ticks that aren't marked as launched, so no points.");
 199                                 return;
 200                         }
 201                         $type .= "_points";
 202                         $ND::DBH->do("UPDATE users SET $type = $type + ? WHERE uid = ?",undef,$points,$row[0]);
 203                         $ND::server->command("msg $ND::target $row[1] has been given $points $type");
 204                 }elsif ($f->rows == 0){
 205                         $ND::server->command("msg $ND::target No hit, maybe spelling mistake, or add % as wildcard");
 206                 }else{
 207                         $ND::server->command("msg $ND::target More than 1 user matched, please refine the search");
 208                 }
 209                 $f->finish;
 210
 211         }else{
 212                 $ND::server->command("msg $ND::target You don't have access for that");
 213         }
 214 }
 215
 216 sub setHost {
 217         my ($msg, $command) = @_;
 218
 219         my ($nick, $host);
 220         if(defined $msg && $msg =~ /^(\S+) (\S+)$/){
 221                 $nick = $1;
 222                 $host = $2;
 223         }else{
 224                 $ND::server->command("notice $ND::nick syntax: .sethost nick host | % can be used for wildcards \%arro% will match barrow");
 225                 return;
 226         }
 227         if (hc()){
 228                 my $f = $ND::DBH->prepare("SELECT uid,username FROM users WHERE username ILIKE ?");
 229                 $f->execute($nick);
 230                 my ($uid,$nick) = $f->fetchrow();
 231                 if ($f->rows == 1){
 232                         my ($username,$hostname) = $ND::DBH->selectrow_array("SELECT username, hostmask FROM users WHERE hostmask ILIKE ? AND NOT (username ILIKE ?)",undef,$host,$nick);
 233                         if ((not defined $username) && $ND::DBH->do("UPDATE users SET hostmask = ? WHERE uid = ?",undef,$host,$uid) > 0){
 234                                 $ND::server->command("msg $ND::target Updated $ND::B$nick${ND::B}'s host to: $ND::B$host$ND::B");
 235                         }elsif(defined $username){
 236                                 $ND::server->command("msg $ND::target $ND::B$username$ND::B already exists with host: $ND::B$hostname$ND::B.");
 237                         }else{
 238                                 $ND::server->command("msg $ND::target Couldn't update $ND::B$username${ND::B}'s host");
 239                         }
 240                 }elsif ($f->rows == 0){
 241                         $ND::server->command("msg $ND::target No hit, maybe spelling mistake, or add % as wildcard");
 242                 }else{
 243                         $ND::server->command("msg $ND::target More than 1 user matched, please refine the search");
 244                 }
 245                 $f->finish;
 246         }
 247 }
 248
 249 sub setPNick {
 250         my ($msg, $command) = @_;
 251
 252         my ($nick, $pnick);
 253         if(defined $msg && $msg =~ /^(\S+) ([^.\s]+)$/){
 254                 $nick = $1;
 255                 $pnick = $2;
 256         }else{
 257                 $ND::server->command("notice $ND::nick syntax: .$command nick pnick | % can be used for wildcards \%arro% will match barrow");
 258                 return;
 259         }
 260         if (hc()){
 261                 my $f = $ND::DBH->prepare("SELECT uid,username FROM users WHERE username ILIKE ?");
 262                 $f->execute($nick);
 263                 my ($uid,$nick) = $f->fetchrow();
 264                 if ($f->rows == 1){
 265                         my ($username,$p_nick) = $ND::DBH->selectrow_array("SELECT username, pnick FROM users WHERE pnick ILIKE ? AND NOT (username ILIKE ?)",undef,$pnick,$nick);
 266                         my $hostname = "$pnick.users.netgamers.org";
 267                         if ((not defined $username) && $ND::DBH->do("UPDATE users SET pnick = ?, hostmask = ? WHERE uid = ?",undef,$pnick,$hostname,$uid) > 0){
 268                                 $ND::server->command("msg $ND::target Updated $ND::B$nick${ND::B}'s pnick to: $ND::B$pnick$ND::B and hostname to $ND::B$hostname$ND::B");
 269                         }elsif(defined $username){
 270                                 $ND::server->command("msg $ND::target $ND::B$username$ND::B already exists with pnick $ND::B$p_nick$ND::B.");
 271                         }else{
 272                                 $ND::server->command("msg $ND::target Couldn't update $ND::B$username${ND::B}'s host");
 273                         }
 274                 }elsif ($f->rows == 0){
 275                         $ND::server->command("msg $ND::target No hit, maybe spelling mistake, or add % as wildcard");
 276                 }else{
 277                         $ND::server->command("msg $ND::target More than 1 user matched, please refine the search");
 278                 }
 279                 $f->finish;
 280         }
 281 }
 282
 283 1;