lib/NDWeb/Controller/Forum.pm

   1 package NDWeb::Controller::Forum;
   2
   3 use strict;
   4 use warnings;
   5 use parent 'Catalyst::Controller';
   6
   7 use NDWeb::Include;
   8
   9 =head1 NAME
  10
  11 NDWeb::Controller::Forum - Catalyst Controller
  12
  13 =head1 DESCRIPTION
  14
  15 Catalyst Controller.
  16
  17 =head1 METHODS
  18
  19 =cut
  20
  21 =head2 index
  22
  23 =cut
  24
  25 sub index :Path :Args(0) {
  26         my ( $self, $c ) = @_;
  27         my $dbh = $c->model;
  28
  29         my $boards = $dbh->prepare(q{
  30 SELECT fcid,category,fb.fbid,fb.board
  31         ,SUM((SELECT count(*) FROM forum_posts WHERE ftid = ft.ftid
  32                 AND COALESCE(time > ftv.time,TRUE))) AS unread
  33         ,date_trunc('seconds',max(ft.mtime)::timestamp ) AS last_post
  34 FROM forum_categories fc
  35         JOIN forum_boards fb USING (fcid)
  36         LEFT OUTER JOIN forum_threads ft USING (fbid)
  37         LEFT OUTER JOIN (SELECT * FROM forum_thread_visits WHERE uid = $1)
  38                 ftv USING (ftid)
  39 WHERE fbid IN (SELECT fbid FROM forum_access
  40                 WHERE gid IN (SELECT groups($1)))
  41         OR ftid IN (SELECT ftid FROM forum_priv_access
  42                 WHERE uid = $1)
  43 GROUP BY fcid,category,fb.fbid, fb.board
  44 ORDER BY fcid,fb.fbid
  45                 });
  46                 $boards->execute($c->stash->{UID});
  47
  48         my @categories;
  49         my $category = {fcid => 0};
  50         while (my $board = $boards->fetchrow_hashref){
  51                 if ($category->{fcid} != $board->{fcid}){
  52                         $category = {fcid => $board->{fcid}, category => $board->{category}};
  53                         push @categories,$category;
  54                 }
  55                 push @{$category->{boards}},$board;
  56         }
  57         $c->stash(categories => \@categories);
  58 }
  59
  60 sub allUnread : Local {
  61         my ( $self, $c ) = @_;
  62         my $dbh = $c->model;
  63
  64         my $threads = $dbh->prepare(q{
  65 SELECT fcid,category,fbid,board,ft.ftid,u.username,ft.subject,ft.sticky
  66         ,(SELECT count(*) FROM forum_posts WHERE ftid = ft.ftid
  67                 AND COALESCE(time > ftv.time,TRUE)) AS unread
  68         ,ft.posts,date_trunc('seconds',ft.mtime::timestamp) as last_post
  69         ,ft.ctime::DATE as posting_date
  70 FROM forum_categories fc
  71         JOIN forum_boards fb USING (fcid)
  72         JOIN forum_threads ft USING (fbid)
  73         JOIN users u ON u.uid = ft.uid
  74         LEFT OUTER JOIN (SELECT * FROM forum_thread_visits WHERE uid = $1)
  75                 ftv ON ftv.ftid = ft.ftid
  76 WHERE COALESCE(ft.mtime > ftv.time,TRUE)
  77         AND ft.ftid IN (SELECT ftid FROM forum_posts WHERE ftid = ft.ftid)
  78         AND ((fbid > 0 AND
  79                         fb.fbid IN (SELECT fbid FROM forum_access WHERE gid IN (SELECT groups($1))))
  80                 OR ft.ftid IN (SELECT ftid FROM forum_priv_access WHERE uid = $1))
  81 ORDER BY fcid,fbid,sticky DESC,last_post DESC
  82                 });
  83
  84         $threads->execute($c->stash->{UID});
  85         my @categories;
  86         my $category = {fcid => 0};
  87         my $board = {fbid => 0};
  88         while (my $thread = $threads->fetchrow_hashref){
  89                 if ($category->{fcid} != $thread->{fcid}){
  90                         $category = {fcid => $thread->{fcid}, category => $thread->{category}};
  91                         push @categories,$category;
  92                 }
  93                 if ($board->{fbid} != $thread->{fbid}){
  94                         $board = {fbid => $thread->{fbid}, board => $thread->{board}};
  95                         push @{$category->{boards}},$board;
  96                 }
  97                 delete $thread->{fcid};
  98                 delete $thread->{fbid};
  99                 delete $thread->{category};
 100                 delete $thread->{board};
 101                 push @{$board->{threads}},$thread;
 102         }
 103         $c->stash(categories => \@categories);
 104         $c->stash(time => $dbh->selectrow_array('SELECT now()::timestamp',undef));
 105 }
 106
 107
 108 sub search : Local {
 109         my ( $self, $c ) = @_;
 110
 111         my $dbh = $c->model;
 112
 113         my @queries;
 114         if ($c->req->param('search')){
 115                 push @queries,'('.$c->req->param('search').')';
 116         }
 117         my %cat = (body => 'D', topic => 'A', author => 'B');
 118         for ('body','topic','author'){
 119                 if ($c->req->param($_)){
 120                         my @words = split /\W+/,$c->req->param($_);
 121                         my $op = $c->req->param('all'.$_) ? '&' : '|';
 122                         my $cat = $cat{$_};
 123                         my $query = join " $op ", map {"$_:$cat"} @words;
 124                         push @queries,"($query)";
 125                 }
 126         }
 127         my $search = join ' & ', @queries;
 128
 129         if ($search){
 130                 my $posts = $dbh->prepare(q{SELECT fp.ftid,u.username,ft.subject
 131                         ,ts_headline(fp.message,to_tsquery($2)) AS headline
 132                         ,ts_rank_cd(fp.textsearch, to_tsquery($2),32) AS rank
 133                         FROM forum_boards fb
 134                                 JOIN forum_threads ft USING (fbid)
 135                                 JOIN forum_posts fp USING (ftid)
 136                                 JOIN users u ON fp.uid = u.uid
 137                         WHERE (fb.fbid IN (SELECT fbid FROM forum_access
 138                                                 WHERE gid IN (SELECT groups($1)))
 139                                         OR ft.ftid IN (SELECT ftid FROM forum_priv_access WHERE uid = $1)
 140                                 ) AND fp.textsearch @@@ to_tsquery($2)
 141                         ORDER BY rank DESC
 142                 });
 143                 eval {
 144                         $posts->execute($c->stash->{UID},$search);
 145                         my @posts;
 146                         while (my $post = $posts->fetchrow_hashref){
 147                                 push @posts,$post;
 148                         }
 149                         $c->stash(searchresults => \@posts);
 150                 };
 151                 if ($@){
 152                         $c->stash( searcherror => $dbh->errstr);
 153                 }
 154         }
 155
 156 }
 157
 158
 159 sub board : Local {
 160         my ( $self, $c, $board ) = @_;
 161         my $dbh = $c->model;
 162
 163         $c->stash(time => $dbh->selectrow_array('SELECT now()::timestamp',undef));
 164
 165         $c->forward('findBoard');
 166         $board = $c->stash->{board};
 167         if ( !defined $board->{fbid}){
 168                 $c->detach('/default');
 169         }
 170
 171         my $threads = $dbh->prepare(q{
 172 SELECT ft.ftid,u.username,ft.subject,ft.posts, ft.sticky
 173         ,(SELECT count(*) FROM forum_posts WHERE ftid = ft.ftid
 174                 AND COALESCE(time > ftv.time,TRUE)) AS unread
 175         ,ft.ctime::DATE as posting_date
 176         ,date_trunc('seconds',ft.mtime::timestamp) as last_post
 177 FROM forum_threads ft
 178         JOIN users u USING(uid)
 179         LEFT OUTER JOIN (SELECT * FROM forum_thread_visits WHERE uid = $2)
 180                 ftv ON ftv.ftid = ft.ftid
 181 WHERE ft.posts > 0 AND ft.fbid = $1 AND (
 182                 ft.fbid IN (SELECT fbid FROM forum_access WHERE gid IN (SELECT groups($2)))
 183                 OR ft.ftid IN (SELECT ftid FROM forum_priv_access WHERE uid = $2)
 184         )
 185 GROUP BY ft.ftid, ft.subject,ft.sticky,u.username,ft.ctime,ft.mtime,ft.posts,ftv.time
 186 ORDER BY sticky DESC,last_post DESC
 187         });
 188         $threads->execute($board->{fbid},$c->stash->{UID});
 189         my @threads;
 190         while (my $thread = $threads->fetchrow_hashref){
 191                 push @threads,$thread;
 192         }
 193
 194         if ( !(defined $board->{post}) && @threads == 0){
 195                 $c->acl_access_denied('test',$c->action,'No access to board')
 196         }
 197         $c->stash(threads => \@threads);
 198
 199         $c->stash(title => "$board->{board} ($board->{category})");
 200
 201         $c->forward('listModeratorBoards', [$board->{fbid}]) if $board->{moderate};
 202
 203 }
 204
 205 sub thread : Local {
 206         my ( $self, $c, $thread ) = @_;
 207         my $dbh = $c->model;
 208
 209         $c->forward('findThread');
 210         $thread = $c->stash->{thread};
 211         unless ($thread){
 212                 $c->stash(template => 'default.tt2');
 213                 $c->res->status(404);
 214                 return;
 215         }
 216         my $query = $dbh->prepare(q{SELECT uid,username FROM users u
 217                 JOIN forum_priv_access fta USING (uid) WHERE fta.ftid = $1});
 218         $query->execute($thread->{ftid});
 219         $c->stash(access => $query->fetchall_arrayref({}) );
 220         $c->stash(title => $thread->{subject}
 221                 . " ($thread->{category} - $thread->{board})");
 222         $c->forward('findPosts');
 223         $c->forward('markThreadAsRead') if $c->user_exists;
 224         if ($c->stash->{thread}->{moderate}) {
 225                 $c->forward('findUsers');
 226                 $c->forward('listModeratorBoards', [$c->stash->{thread}->{fbid}]);
 227         }
 228 }
 229
 230 sub findPosts :Private {
 231         my ( $self, $c, $thread ) = @_;
 232         my $dbh = $c->model;
 233
 234         my $posts = $dbh->prepare(q{
 235                 SELECT u.uid,u.username,date_trunc('seconds',fp.time::timestamp) AS time
 236                         ,fp.message,COALESCE(fp.time > ftv.time,TRUE) AS unread
 237                 FROM forum_threads ft
 238                         JOIN forum_posts fp USING (ftid)
 239                         JOIN users u ON u.uid = fp.uid
 240                         LEFT OUTER JOIN
 241                                 (SELECT * FROM forum_thread_visits WHERE uid = $2) ftv ON ftv.ftid = ft.ftid
 242                 WHERE ft.ftid = $1
 243                 ORDER BY fp.time ASC
 244                 });
 245         $posts->execute($thread,$c->stash->{UID});
 246
 247         my @posts;
 248         while (my $post = $posts->fetchrow_hashref){
 249                 $post->{message} = parseMarkup($post->{message});
 250                 push @posts,$post;
 251         }
 252
 253         $c->stash(posts => \@posts);
 254 }
 255
 256
 257 sub markBoardAsRead : Local {
 258         my ( $self, $c, $board, $time ) = @_;
 259         my $dbh = $c->model;
 260
 261         $c->forward('findBoard');
 262         $board = $c->stash->{board};
 263
 264         my $threads = $dbh->prepare(q{SELECT ft.ftid,ft.subject
 265                         ,count(NULLIF(COALESCE(fp.time > ftv.time,TRUE),FALSE)) AS unread
 266                         ,count(fp.fpid) AS posts, max(fp.time)::timestamp as last_post
 267                         FROM forum_threads ft
 268                                 JOIN forum_posts fp USING (ftid)
 269                                 LEFT OUTER JOIN (SELECT * FROM forum_thread_visits WHERE uid = $2) ftv ON ftv.ftid = ft.ftid
 270                         WHERE ft.fbid = $1 AND fp.time <= $3
 271                         GROUP BY ft.ftid, ft.subject
 272                         HAVING count(NULLIF(COALESCE(fp.time > ftv.time,TRUE),FALSE)) >= 1
 273                 });
 274         $threads->execute($board->{fbid},$c->user->id,$time);
 275         $dbh->begin_work;
 276         while (my $thread = $threads->fetchrow_hashref){
 277                 $c->forward('markThreadAsRead',[$thread->{ftid}]);
 278         }
 279         $dbh->commit;
 280         $c->forward('/redirect');
 281 }
 282
 283 sub markThreadAsRead : Private {
 284         my ( $self, $c, $thread ) = @_;
 285         my $dbh = $c->model;
 286
 287         my $rows = $dbh->do(q{UPDATE forum_thread_visits SET time = now()
 288                 WHERE uid =     $1 AND ftid = $2
 289                 },undef,$c->user->id,$thread);
 290         if ($rows == 0){
 291                 $dbh->do(q{INSERT INTO forum_thread_visits (uid,ftid)
 292                         VALUES ($1,$2)}
 293                         ,undef,$c->user->id,$thread);
 294         }
 295 }
 296
 297 sub moveThreads : Local {
 298         my ( $self, $c, $board ) = @_;
 299         my $dbh = $c->model;
 300
 301         $c->forward('findBoard',[$c->req->param('board')]);
 302         my $toboard = $c->stash->{board};
 303         unless ($toboard->{moderate}){
 304                 $c->acl_access_denied('test',$c->action,'No moderator access for target board.')
 305         }
 306
 307         $c->forward('findBoard');
 308         $board = $c->stash->{board};
 309         unless ($board->{moderate}){
 310                 $c->acl_access_denied('test',$c->action,'No moderator access for source board.')
 311         }
 312
 313         my $log = "Moved these threads:\n\n";
 314         $dbh->begin_work;
 315         my $moveThread = $dbh->prepare(q{UPDATE forum_threads SET fbid = $1 WHERE ftid = $2 AND fbid = $3});
 316         for my $param ($c->req->param){
 317                 if ($param =~ /t:(\d+)/){
 318                         $moveThread->execute($toboard->{fbid},$1,$board->{fbid});
 319                         if ($moveThread->rows > 0){
 320                                 $log .= "$1\n";
 321                         }
 322                 }
 323         }
 324
 325         $log .= "\nFrom board: $board->{board} ($board->{fbid})";
 326         $log .= "\nTo board: $toboard->{board} ($toboard->{fbid})";
 327         $dbh->do(q{INSERT INTO forum_posts (ftid,uid,message)
 328                 VALUES((SELECT ftid FROM users WHERE uid = $1),$1,$2)
 329                 }, undef, $c->user->id, $log);
 330         $dbh->commit;
 331
 332         $c->res->redirect($c->uri_for('board',$board->{fbid}));
 333 }
 334
 335 sub newThread : Local {
 336         my ( $self, $c, $board ) = @_;
 337
 338         $c->forward('findBoard');
 339         $board = $c->stash->{board};
 340
 341         unless ($c->stash->{board}->{post}){
 342                 $c->acl_access_denied('test',$c->action,'No post access to board.')
 343         }
 344
 345         $c->forward('insertThread');
 346         $c->forward('addPost',[$c->stash->{thread}]);
 347 }
 348
 349 sub insertThread : Private {
 350         my ( $self, $c, $board ) = @_;
 351         my $dbh = $c->model;
 352
 353         my $insert = $dbh->prepare(q{INSERT INTO forum_threads (ftid,fbid,subject,uid)
 354                 VALUES(DEFAULT,$1,$2,$3) RETURNING (ftid);
 355                 });
 356         $insert->execute($board,html_escape($c->req->param('subject')),$c->stash->{UID});
 357         $c->stash(thread => $insert->fetchrow);
 358         $insert->finish;
 359 }
 360
 361 sub addPost : Local {
 362         my ( $self, $c, $thread ) = @_;
 363         my $dbh = $c->model;
 364
 365         if ($c->req->param('cmd') eq 'Submit'){
 366                 $c->forward('findThread');
 367                 unless ($c->stash->{thread}->{post}){
 368                         $c->acl_access_denied('test',$c->action,'No post access to board.')
 369                 }
 370                 $c->forward('insertPost');
 371                 $c->res->redirect($c->uri_for('thread',$thread));
 372         }elsif ($c->req->param('cmd') eq 'Preview'){
 373                 $c->forward('thread');
 374                 $c->forward('previewPost');
 375                 $c->stash(template => 'forum/thread.tt2');
 376         }
 377 }
 378
 379 sub setSticky : Local {
 380         my ( $self, $c, $thread, $sticky ) = @_;
 381         my $dbh = $c->model;
 382
 383         $c->forward('findThread');
 384         unless ($c->stash->{thread}->{moderate}){
 385                 $c->acl_access_denied('test',$c->action,'No moderator access to board.')
 386         }
 387
 388         $dbh->do(q{UPDATE forum_threads SET sticky = $2 WHERE ftid = $1}
 389                 , undef,$thread, $sticky);
 390         $c->res->redirect($c->uri_for('thread',$thread));
 391 }
 392
 393 sub postthreadaccess : Local {
 394         my ( $self, $c, $thread) = @_;
 395         my $dbh = $c->model;
 396
 397         $c->forward('findThread');
 398         $dbh->begin_work;
 399         unless ($c->stash->{thread}->{moderate}){
 400                 $c->acl_access_denied('test',$c->action,'No moderator access to board.')
 401         }
 402         if ($c->req->param('access')){
 403                 $c->req->parameters->{access} = [$c->req->parameters->{access}]
 404                         unless ref $c->req->parameters->{access} eq 'ARRAY';
 405                 my $query = $dbh->prepare(q{DELETE From forum_priv_access
 406                         WHERE ftid = $1 AND uid = ANY ($2)});
 407                 $query->execute($thread,$c->req->parameters->{access});
 408                 $dbh->do(q{INSERT INTO forum_posts (ftid,uid,message)
 409                         VALUES((SELECT ftid FROM users WHERE uid = $1),$1,$2)
 410                         }, undef, $c->user->id
 411                         ,"Removed access on thread $thread for : @{$c->req->parameters->{access}}");
 412         }
 413         if ($c->req->param('uid')){
 414                 $c->forward('addaccess');
 415         }
 416         $dbh->commit;
 417         $c->res->redirect($c->uri_for('thread',$thread));
 418 }
 419
 420 sub removeownthreadaccess : Local {
 421         my ( $self, $c, $thread) = @_;
 422         my $dbh = $c->model;
 423         $dbh->do(q{DELETE FROM forum_priv_access WHERE uid = $1 AND ftid = $2}
 424                 ,undef,$c->user->id,$thread);
 425         $c->res->redirect($c->uri_for('allUnread'));
 426 }
 427
 428 sub privmsg : Local {
 429         my ( $self, $c, $uid ) = @_;
 430
 431         $uid ||= 0;
 432         $c->stash(uid => $uid);
 433
 434         $c->forward('findUsers');
 435 }
 436
 437 sub postprivmsg : Local {
 438         my ( $self, $c ) = @_;
 439         my $dbh = $c->model;
 440
 441         $dbh->begin_work;
 442         $c->forward('insertThread',[-1999]);
 443
 444         $c->req->parameters->{uid} = [$c->req->parameters->{uid}]
 445                 unless ref $c->req->parameters->{uid} eq 'ARRAY';
 446         push @{$c->req->parameters->{uid}}, $c->user->id;
 447         $c->forward('addaccess',[$c->stash->{thread}]);
 448
 449         $c->forward('addPost',[$c->stash->{thread}]);
 450         $dbh->commit;
 451 }
 452
 453 sub addaccess : Private {
 454         my ( $self, $c, $thread) = @_;
 455         my $dbh = $c->model;
 456
 457         $c->req->parameters->{uid} = [$c->req->parameters->{uid}]
 458                 unless ref $c->req->parameters->{uid} eq 'ARRAY';
 459         my $query = $dbh->prepare(q{INSERT INTO forum_priv_access (ftid,uid)
 460                 (SELECT $1,uid FROM users u WHERE uid = ANY ($2) AND NOT uid
 461                         IN (SELECT uid FROM forum_priv_access WHERE ftid = $1))});
 462         $query->execute($thread,$c->req->parameters->{uid});
 463         $dbh->do(q{INSERT INTO forum_posts (ftid,uid,message)
 464                 VALUES((SELECT ftid FROM users WHERE uid = $1),$1,$2)
 465                 }, undef, $c->user->id
 466                 ,"Gave access on thread $thread to : @{$c->req->parameters->{uid}}");
 467 }
 468
 469 sub findUsers : Private {
 470         my ( $self, $c ) = @_;
 471         my $dbh = $c->model;
 472
 473         my $query = $dbh->prepare(q{SELECT uid,username FROM users
 474                 WHERE uid > 0 AND uid IN (SELECT uid FROM groupmembers)
 475                 ORDER BY username});
 476         $query->execute;
 477
 478         $c->stash(users => $query->fetchall_arrayref({}) );
 479 }
 480
 481 sub findThread : Private {
 482         my ( $self, $c, $thread ) = @_;
 483         my $dbh = $c->model;
 484         my $findThread = $dbh->prepare(q{SELECT ft.ftid,ft.subject
 485                 ,COALESCE(bool_or(fa.post),true) AS post, bool_or(fa.moderate) AS moderate
 486                 ,ft.fbid,fb.board,fb.fcid,ft.sticky,fc.category
 487                 FROM forum_boards fb
 488                         NATURAL JOIN forum_threads ft
 489                         NATURAL JOIN forum_categories fc
 490                         LEFT OUTER JOIN (SELECT fa.* FROM forum_access fa
 491                                 JOIN (SELECT groups($2) AS gid) g USING (gid)
 492                         ) fa USING (fbid)
 493                 WHERE ft.ftid = $1 AND (fa.post IS NOT NULL
 494                         OR ft.ftid IN (SELECT ftid FROM forum_priv_access WHERE uid = $2))
 495                 GROUP BY ft.ftid,ft.subject,ft.fbid,fb.board,fb.fcid,ft.sticky,fc.category
 496         });
 497         $thread = $dbh->selectrow_hashref($findThread,undef,$thread,$c->stash->{UID});
 498         $c->stash(thread => $thread);
 499 }
 500
 501 sub findBoard : Private {
 502         my ( $self, $c, $board ) = @_;
 503         my $dbh = $c->model;
 504
 505         my $boards = $dbh->prepare(q{SELECT fb.fbid,fb.board, bool_or(fa.post) AS post, bool_or(fa.moderate) AS moderate,fb.fcid, fc.category
 506                         FROM forum_boards fb
 507                                 NATURAL JOIN forum_categories fc
 508                                 LEFT OUTER JOIN (SELECT * FROM forum_access
 509                                         WHERE fbid = $1 AND gid IN (SELECT groups($2))
 510                                 ) fa USING (fbid)
 511                         WHERE fb.fbid = $1
 512                         GROUP BY fb.fbid,fb.board,fb.fcid,fc.category
 513                 });
 514         $board = $dbh->selectrow_hashref($boards,undef,$board,$c->stash->{UID});
 515
 516         $c->stash(board => $board);
 517 }
 518
 519 sub previewPost : Private {
 520         my ( $self, $c) = @_;
 521         push @{$c->stash->{posts}}, {
 522                 unread => 1,
 523                 username => 'PREVIEW',
 524                 message => parseMarkup(html_escape $c->req->param('message')),
 525         };
 526         $c->stash(previewMessage => html_escape $c->req->param('message'));
 527 }
 528
 529 sub insertPost : Private {
 530         my ( $self, $c, $thread ) = @_;
 531         my $dbh = $c->model;
 532
 533         my $insert = $dbh->prepare(q{INSERT INTO forum_posts (ftid,message,uid)
 534                 VALUES($1,$2,$3)});
 535         $insert->execute($thread,html_escape($c->req->param('message')),$c->stash->{UID});
 536 }
 537
 538 sub listModeratorBoards : Private {
 539         my ( $self, $c, $fbid ) = @_;
 540         my $dbh = $c->model;
 541
 542         my $categories = $dbh->prepare(q{SELECT fcid,category FROM forum_categories ORDER BY fcid});
 543         my $boards = $dbh->prepare(q{SELECT fb.fbid,fb.board, bool_or(fa.post) AS post
 544                 FROM forum_boards fb NATURAL JOIN forum_access fa
 545                 WHERE fb.fcid = $1
 546                         AND gid IN (SELECT groups($2))
 547                         AND moderate
 548                 GROUP BY fb.fbid,fb.board
 549                 ORDER BY fb.fbid
 550                 });
 551         $categories->execute;
 552         my @categories;
 553         while (my $category = $categories->fetchrow_hashref){
 554                 $boards->execute($category->{fcid},$c->stash->{UID});
 555
 556                 my @boards;
 557                 while (my $b = $boards->fetchrow_hashref){
 558                         next if ($b->{fbid} == $fbid);
 559                         push @boards,$b;
 560                 }
 561                 $category->{boards} = \@boards;
 562                 push @categories,$category if @boards;
 563         }
 564         $c->stash(categories => \@categories);
 565 }
 566
 567 =head1 AUTHOR
 568
 569 Michael Andreen (harv@ruin.nu)
 570
 571 =head1 LICENSE
 572
 573 GPL 2.0, or later.
 574
 575 =cut
 576
 577 1;