lib/NDWeb/Controller/Members.pm

   1 package NDWeb::Controller::Members;
   2
   3 use strict;
   4 use warnings;
   5 use parent 'Catalyst::Controller';
   6
   7 use NDWeb::Include;
   8
   9 =head1 NAME
  10
  11 NDWeb::Controller::Members - Catalyst Controller
  12
  13 =head1 DESCRIPTION
  14
  15 Catalyst Controller.
  16
  17 =head1 METHODS
  18
  19 =cut
  20
  21
  22 =head2 index
  23
  24 =cut
  25
  26 sub index : Path : Args(0) {
  27         my ( $self, $c, $order ) = @_;
  28         my $dbh = $c->model;
  29
  30         $c->stash(error => $c->flash->{error});
  31
  32         $c->stash(comma => \&comma_value);
  33         $c->stash(u => $dbh->selectrow_hashref(q{SELECT planet,defense_points
  34                         ,attack_points,scan_points,humor_points
  35                         , (attack_points+defense_points+scan_points/20)::NUMERIC(5,1) as total_points
  36                         , sms,rank,hostmask FROM users WHERE uid = ?
  37                         },undef,$c->user->id)
  38         );
  39
  40         $c->stash(groups => $dbh->selectrow_array(q{SELECT array_accum(groupname)
  41                 FROM groups g NATURAL JOIN groupmembers gm
  42                 WHERE uid = $1
  43                         },undef,$c->user->id)
  44         );
  45
  46         $c->stash(p => $dbh->selectrow_hashref(q{SELECT id,x,y,z, ruler, planet,race,
  47                 size, size_gain, size_gain_day,
  48                 score,score_gain,score_gain_day,
  49                 value,value_gain,value_gain_day,
  50                 xp,xp_gain,xp_gain_day,
  51                 sizerank,sizerank_gain,sizerank_gain_day,
  52                 scorerank,scorerank_gain,scorerank_gain_day,
  53                 valuerank,valuerank_gain,valuerank_gain_day,
  54                 xprank,xprank_gain,xprank_gain_day
  55                 from current_planet_stats_full p
  56                         WHERE id = ?
  57                         },undef,$c->user->planet)
  58         );
  59
  60         my $calls = $dbh->prepare(q{
  61                 SELECT id,landing_tick,dc,curreta
  62                         ,array_accum(race::text) AS race
  63                         ,array_accum(amount) AS amount
  64                         ,array_accum(eta) AS eta
  65                         ,array_accum(shiptype) AS shiptype
  66                         ,array_accum(coords) AS attackers
  67                 FROM (SELECT c.id, c.landing_tick
  68                         ,dc.username AS dc, (c.landing_tick - tick()) AS curreta
  69                         ,p2.race, i.amount, i.eta, i.shiptype, p2.alliance
  70                         ,coords(p2.x,p2.y,p2.z)
  71                         FROM calls c
  72                                 LEFT OUTER JOIN incomings i ON i.call = c.id
  73                                 LEFT OUTER JOIN current_planet_stats p2 ON i.sender = p2.id
  74                                 LEFT OUTER JOIN users dc ON c.dc = dc.uid
  75                         WHERE c.member = $1 AND c.landing_tick >= tick()
  76                         GROUP BY c.id, c.landing_tick, dc.username
  77                                 ,p2.race,i.amount,i.eta,i.shiptype,p2.alliance,p2.x,p2.y,p2.z
  78                         ) c
  79                 GROUP BY id, landing_tick,dc,curreta
  80                 });
  81
  82         $calls->execute($c->user->id);
  83         $c->stash(calls => $calls->fetchall_arrayref({}) );
  84
  85         my $query = $dbh->prepare(q{
  86 (
  87         SELECT DISTINCT ON (mission,name) fid,mission,name,tick, NULL AS eta
  88                 ,amount, NULL AS coords, planet AS target, NULL AS back
  89         FROM fleets f
  90                 JOIN full_fleets USING (fid)
  91         WHERE uid = $1 AND planet = $2 AND tick >= tick() -  24
  92                 AND name = 'Main' AND mission = 'Full fleet'
  93         ORDER BY mission,name,tick DESC
  94 ) UNION (
  95         SELECT fid,mission,name,landing_tick AS tick, eta, amount
  96                 , coords(x,y,z), target, back
  97         FROM fleets f
  98                 JOIN launch_confirmations USING (fid)
  99         LEFT OUTER JOIN current_planet_stats t ON target = t.id
 100         WHERE uid = $1 AND f.planet = $2 AND back >= tick()
 101                 AND landing_tick - eta - 12 < tick()
 102 )
 103                 });
 104
 105         my $ships = $dbh->prepare(q{SELECT ship,amount FROM fleet_ships
 106                 WHERE fid = ? ORDER BY num
 107                 });
 108
 109         $query->execute($c->user->id,$c->user->planet);
 110         my @fleets;
 111         while (my $fleet = $query->fetchrow_hashref){
 112                 my @ships;
 113                 $ships->execute($fleet->{fid});
 114                 while (my $ship = $ships->fetchrow_hashref){
 115                         push @ships,$ship;
 116                 }
 117                 $fleet->{ships} = \@ships;
 118                 push @fleets,$fleet;
 119         }
 120         $c->stash(fleets => \@fleets);
 121
 122         my $announcements = $dbh->prepare(q{SELECT ft.ftid, u.username,ft.subject,
 123                 count(NULLIF(COALESCE(fp.time > ftv.time,TRUE),FALSE)) AS unread,count(fp.fpid) AS posts,
 124                 date_trunc('seconds',max(fp.time)::timestamp) as last_post,
 125                 min(fp.time)::date as posting_date, ft.sticky
 126                 FROM forum_threads ft JOIN forum_posts fp USING (ftid)
 127                         JOIN users u ON u.uid = ft.uid
 128                         LEFT OUTER JOIN (SELECT * FROM forum_thread_visits WHERE uid = $1) ftv ON ftv.ftid = ft.ftid
 129                 WHERE ft.fbid = 1
 130                 GROUP BY ft.ftid, ft.subject,ft.sticky,u.username
 131                 HAVING count(NULLIF(COALESCE(ft.sticky OR fp.time > ftv.time,TRUE),FALSE)) >= 1
 132                 ORDER BY sticky DESC,last_post DESC
 133                 });
 134         $announcements->execute($c->user->id);
 135         $c->stash(announcements => $announcements->fetchall_arrayref({}) );
 136 }
 137
 138 sub posthostupdate : Local {
 139         my ( $self, $c ) = @_;
 140         my $dbh = $c->model;
 141
 142         $dbh->do(q{UPDATE users SET hostmask = ? WHERE uid = ?
 143                 },undef, html_escape $c->req->param('hostname'), $c->user->id);
 144
 145         $c->res->redirect($c->uri_for(''));
 146 }
 147
 148 sub postsmsupdate : Local {
 149         my ( $self, $c ) = @_;
 150         my $dbh = $c->model;
 151
 152         $dbh->do(q{UPDATE users SET sms = ? WHERE uid = ?
 153                 },undef, html_escape $c->req->param('sms'), $c->user->id);
 154
 155         $c->res->redirect($c->uri_for(''));
 156 }
 157
 158 sub postowncoords : Local {
 159         my ( $self, $c ) = @_;
 160         my $dbh = $c->model;
 161
 162         if ($c->user->planet){
 163                 $c->flash(error => 'You already have a planet set.'
 164                         .' Contact a HC if they need to be changed');
 165         }elsif ($c->req->param('planet') =~ m/(\d+)\D+(\d+)\D+(\d+)/){
 166                 my $planet = $dbh->selectrow_array(q{SELECT planetid($1,$2,$3,TICK())
 167                         },undef,$1,$2,$3);
 168
 169                 if ($planet){
 170                         $dbh->do(q{UPDATE users SET planet = ? WHERE uid = ?
 171                                 },undef, $planet , $c->user->id);
 172                 }else{
 173                         $c->flash(error => "No planet at coords: $1:$2:$3");
 174                 }
 175         }else{
 176                 $c->flash(error => $c->req->param('planet') . " are not valid coords.");
 177         }
 178
 179         $c->res->redirect($c->uri_for(''));
 180 }
 181
 182 sub postfleetupdate : Local {
 183         my ( $self, $c ) = @_;
 184         my $dbh = $c->model;
 185
 186         my $fleet = $c->req->param('fleet');
 187         $fleet =~ s/,//g;
 188         my $amount = 0;
 189         my @ships;
 190         while ($fleet =~ m/((?:[A-Z][a-z]+ )*[A-Z][a-z]+)\s+(\d+)/g){
 191                 $amount += $2;
 192                 push @ships, [$1,$2];
 193         }
 194         if ($amount){
 195                 $dbh->begin_work;
 196                 eval{
 197                         my $insert = $dbh->prepare(q{INSERT INTO fleets
 198                                 (planet,name,mission,tick,amount)
 199                                 VALUES (?,'Main','Full fleet',tick(),?) RETURNING fid});
 200                         my ($id) = $dbh->selectrow_array($insert,undef
 201                                 ,$c->user->planet,$amount);
 202                         $insert = $dbh->prepare(q{INSERT INTO fleet_ships
 203                                 (fid,ship,amount) VALUES (?,?,?)});
 204                         for my $s (@ships){
 205                                 unshift @{$s},$id;
 206                                 $insert->execute(@{$s});
 207                         }
 208                         $insert = $dbh->prepare(q{INSERT INTO full_fleets
 209                                 (fid,uid) VALUES (?,?)});
 210                         $insert->execute($id,$c->user->id);
 211                         $dbh->commit;
 212                 };
 213                 if ($@){
 214                         if ($@ =~ m/insert or update on table "fleet_ships" violates foreign key constraint "fleet_ships_ship_fkey"\s+DETAIL:\s+Key \(ship\)=\(([^)]+)\)/){
 215                                 $c->flash( error => "'$1' is NOT a valid ship");
 216                         }else{
 217                                 $c->flash( error => $@);
 218                         }
 219                         $dbh->rollback;
 220                 }
 221         }else{
 222                 $c->flash( error => 'Fleet does not contain any ships');
 223         }
 224
 225         $c->res->redirect($c->uri_for(''));
 226 }
 227
 228 sub postfleetsupdates : Local {
 229         my ( $self, $c ) = @_;
 230         my $dbh = $c->model;
 231
 232         my $log = $dbh->prepare(q{INSERT INTO forum_posts (ftid,uid,message) VALUES(
 233                 (SELECT ftid FROM users WHERE uid = $1),$1,$2)
 234                 });
 235         $dbh->begin_work;
 236         if ($c->req->param('cmd') eq 'Recall Fleets'){
 237                 my $updatefleets = $dbh->prepare(q{UPDATE launch_confirmations
 238                         SET back = tick() + (tick() - (landing_tick - eta))
 239                         WHERE uid = ? AND fid = ? AND back > tick()+eta
 240                 });
 241
 242                 for my $param ($c->req->param()){
 243                         if ($param =~ /^change:(\d+)$/){
 244                                 $updatefleets->execute($c->user->id,$1);
 245                                 $log->execute($c->user->id,"Member recalled fleet $1");
 246                         }
 247                 }
 248         }elsif ($c->req->param('cmd') eq 'Change Fleets'){
 249                 my $updatefleets = $dbh->prepare(q{UPDATE launch_confirmations
 250                         SET back = ? WHERE uid = ? AND fid = ?});
 251
 252                 for my $param ($c->req->param()){
 253                         if ($param =~ /^change:(\d+)$/){
 254                                 my $back = $c->req->param("back:$1");
 255                                 $updatefleets->execute($back,$c->user->id,$1);
 256                                 $log->execute($c->user->id,"Member set fleet $1 to be back tick: $back");
 257                         }
 258                 }
 259         }
 260         $dbh->commit;
 261
 262         $c->res->redirect($c->uri_for(''));
 263 }
 264
 265 sub ircrequest : Local {
 266         my ( $self, $c ) = @_;
 267         my $dbh = $c->model;
 268
 269         $c->stash(reply => $c->flash->{reply});
 270         $c->stash(channels => ['def','scan','members']);
 271 }
 272
 273 sub postircrequest : Local {
 274         my ( $self, $c ) = @_;
 275         my $dbh = $c->model;
 276
 277         my $query = $dbh->prepare(q{INSERT INTO irc_requests
 278                 (uid,channel,message) VALUES($1,$2,$3)
 279                 });
 280         $query->execute($c->user->id,$c->req->param('channel'),$c->req->param('message'));
 281         system 'killall','-USR1', 'irssi';
 282
 283         $c->flash(reply => "Msg sent to: ".$c->req->param('channel'));
 284         $c->res->redirect($c->uri_for('ircrequest'));
 285 }
 286
 287 sub points : Local {
 288         my ( $self, $c, $order ) = @_;
 289         my $dbh = $c->model;
 290
 291         if ($order && $order =~ /^((?:defense|attack|total|humor|scan|raid)_points)$/){
 292                 $order = "$1 DESC";
 293         }else{
 294                 $order = 'total_points DESC';
 295         }
 296
 297         my $limit = 'LIMIT 10';
 298         $limit = '' if $c->check_user_roles(qw/members_points_nolimit/);
 299
 300         my $query = $dbh->prepare(qq{SELECT username,defense_points,attack_points
 301                 ,scan_points,humor_points
 302                 ,(attack_points+defense_points+scan_points/20)::NUMERIC(4,0) as total_points
 303                 , count(NULLIF(rc.launched,FALSE)) AS raid_points
 304                 FROM users u LEFT OUTER JOIN raid_claims rc USING (uid)
 305                 WHERE uid IN (SELECT uid FROM groupmembers WHERE gid = 2)
 306                 GROUP BY username,defense_points,attack_points,scan_points,humor_points,rank
 307                 ORDER BY $order $limit});
 308         $query->execute;
 309         my @members;
 310         while (my $member = $query->fetchrow_hashref){
 311                 push @members,$member;
 312         }
 313         $c->stash(members => \@members);
 314 }
 315
 316 sub addintel : Local {
 317         my ( $self, $c, $order ) = @_;
 318
 319         $c->stash(intel => $c->flash->{intel});
 320         $c->stash(scans => $c->flash->{scans});
 321         $c->stash(intelmessage => $c->flash->{intelmessage});
 322 }
 323
 324 sub postintel : Local {
 325         my ( $self, $c, $order ) = @_;
 326
 327         $c->forward('insertintel');
 328
 329         $c->res->redirect($c->uri_for('addintel'));
 330 }
 331
 332 sub postintelmessage : Local {
 333         my ( $self, $c, $order ) = @_;
 334
 335         unless ($c->req->param('subject')){
 336                 if ($c->req->param('message') =~ /(.*\w.*)/){
 337                         $c->req->param(subject => $1);
 338                 }
 339         }
 340
 341         $c->forward('/forum/insertThread',[12]);
 342         $c->forward('/forum/insertPost',[$c->stash->{thread}]);
 343         $c->flash(intelmessage => 1);
 344
 345         $c->forward('insertintel');
 346
 347         $c->res->redirect($c->uri_for('addintel'));
 348 }
 349
 350 sub insertintel : Private {
 351         my ( $self, $c, $order ) = @_;
 352         my $dbh = $c->model;
 353
 354         $dbh->begin_work;
 355         my $findscan = $dbh->prepare(q{SELECT scan_id FROM scans
 356                 WHERE scan_id = ? AND tick >= tick() - 168 AND groupscan = ?
 357                 });
 358         my $addscan = $dbh->prepare(q{INSERT INTO scans (scan_id,tick,uid,groupscan)
 359                 VALUES (?,tick(),?,?)
 360                 });
 361         my $addpoint = $dbh->prepare(q{UPDATE users SET scan_points = scan_points + 1
 362                 WHERE uid = ?
 363                 });
 364         my @scans;
 365         my $intel = $c->req->param('message');
 366         while ($intel =~ m{http://[\w.]+/.+?scan(_id|_grp)?=(\d+)}g){
 367                 my $groupscan = (defined $1 && $1 eq '_grp') || 0;
 368                 my %scan;
 369                 $scan{id} = $2;
 370                 $scan{group} = $groupscan;
 371                 $findscan->execute($2,$groupscan);
 372                 if ($findscan->rows == 0){
 373                         if ($addscan->execute($2,$c->user->id,$groupscan)){
 374                                 $addpoint->execute($c->user->id) unless $groupscan;
 375                                 $scan{added} = 1;
 376                         }
 377                 }else{
 378                         $scan{message} = 'already exists';
 379                 }
 380                 push @scans,\%scan;
 381         }
 382         my $tick = $c->req->param('tick');
 383         unless ($tick =~ /^(\d+)$/){
 384                 $tick = $c->stash->{game}->{tick};
 385         }
 386         my $addintel = $dbh->prepare(q{INSERT INTO intel
 387                 (name,mission,tick,target,sender,eta,amount,ingal,back,uid)
 388                 VALUES($1,$2,$3,planetid($4,$5,$6,$10),planetid($7,$8,$9,$10)
 389                         ,$11,$12,$13,$14,$15)
 390         });
 391         my @intel;
 392         while ($intel =~ m/(\d+):(\d+):(\d+)\*?\s+(\d+):(\d+):(\d+)
 393                 \*?\s+(.+)(?:Ter|Cat|Xan|Zik|Etd)?
 394                 \s+(\d+)\s+(Attack|Defend)\s+(\d+)/gx){
 395                 my $ingal = ($1 == $4 && $2 == $5) || 0;
 396                 my $lt = $tick + $10;
 397                 my $back = ($ingal ? $lt + 4 : undef);
 398                 eval {
 399                         $addintel->execute($7,$9,$lt,$1,$2,$3,$4,$5,$6,$tick,$10,$8
 400                                 ,$ingal,$back, $c->user->id);
 401                         push @intel,"Added $&";
 402                 };
 403                 if ($@){
 404                         push @intel,"Couldn't add $&: ".$dbh->errstr;
 405                 }
 406         }
 407         $dbh->commit;
 408         $c->flash(intel => \@intel);
 409         $c->flash(scans => \@scans);
 410 }
 411
 412 sub launchConfirmation : Local {
 413         my ( $self, $c ) = @_;
 414
 415         $c->stash(error => $c->flash->{error});
 416         $c->stash(missions => $c->flash->{missions});
 417 }
 418
 419 sub postconfirmation : Local {
 420         my ( $self, $c ) = @_;
 421         my $dbh = $c->model;
 422
 423         eval {
 424                 my $missions = $c->req->param('mission');
 425                 my $findplanet = $dbh->prepare("SELECT planetid(?,?,?,?)");
 426                 my $findattacktarget = $dbh->prepare(q{SELECT c.target,c.wave,c.launched
 427                         FROM  raid_claims c
 428                                 JOIN raid_targets t ON c.target = t.id
 429                                 JOIN raids r ON t.raid = r.id
 430                         WHERE c.uid = ? AND r.tick+c.wave-1 = ? AND t.planet = ?
 431                                 AND r.open AND not r.removed
 432                         });
 433                 my $finddefensetarget = $dbh->prepare(q{SELECT c.id FROM calls c
 434                                 JOIN users u ON c.member = u.uid
 435                         WHERE u.planet = $1 AND c.landing_tick = $2
 436                 });
 437                 my $informDefChannel = $dbh->prepare(q{INSERT INTO defense_missions
 438                         (fleet,call) VALUES (?,?)
 439                         });
 440                 my $addattackpoint = $dbh->prepare(q{UPDATE users SET
 441                         attack_points = attack_points + 1 WHERE uid = ?
 442                         });
 443                 my $launchedtarget = $dbh->prepare(q{UPDATE raid_claims SET launched = True
 444                         WHERE uid = ? AND target = ? AND wave = ?
 445                         });
 446                 my $addfleet = $dbh->prepare(q{INSERT INTO fleets
 447                         (name,mission,planet,tick,amount)
 448                         VALUES ($2,$3,(SELECT planet FROM users WHERE uid = $1),tick(),$4)
 449                         RETURNING fid
 450                         });
 451                 my $addconfirmation = $dbh->prepare(q{INSERT INTO launch_confirmations
 452                         (fid,uid,target,landing_tick,eta,back) VALUES ($1,$2,$3,$4,$5,$6)
 453                         });
 454                 my $addships = $dbh->prepare(q{INSERT INTO fleet_ships (fid,ship,amount)
 455                         VALUES (?,?,?)
 456                         });
 457                 my $log = $dbh->prepare(q{INSERT INTO forum_posts (ftid,uid,message) VALUES(
 458                         (SELECT ftid FROM users WHERE uid = $1),$1,$2)
 459                         });
 460                 my @missions;
 461                 $dbh->begin_work;
 462                 while ($missions && $missions =~ m/([^\n]+)\s+(\d+):(\d+):(\d+)\s+(\d+):(\d+):(\d+)
 463                         \s+\((?:(\d+)\+)?(\d+)\).*?(?:\d+hrs\s+)?\d+mins?\s+
 464                         (Attack|Defend|Return|Fake\ Attack|Fake\ Defend)
 465                         (.*?)
 466                         (?:Launching\ in\ tick\ (\d+),\ arrival\ in\ tick\ (\d+)
 467                                 |ETA:\ \d+,\ Return\ ETA:\ (\d+)
 468                                 |Return\ ETA:\ (\d+)
 469                                 )/sgx){
 470                         next if $10 eq 'Return';
 471                         my %mission;
 472                         my $name = $1;
 473                         my $tick = $c->stash->{TICK}+$9;
 474                         $tick += $8 if defined $8;
 475                         $tick = $13 if defined $13;
 476                         my $eta = $9;
 477                         $eta += $14 if defined $14;
 478                         my $mission = $10;
 479                         my $x = $5;
 480                         my $y = $6;
 481                         my $z = $7;
 482                         my $back = $tick + $eta - 1;
 483                         $mission{tick} = $tick;
 484                         $mission{mission} = $mission;
 485                         $mission{target} = "$x:$y:$z";
 486                         $mission{back} = $back;
 487
 488                         my ($planet_id) = $dbh->selectrow_array($findplanet,undef,$x,$y,$z,$c->stash->{TICK});
 489
 490                         my $findtarget = $finddefensetarget;
 491                         if ($mission eq 'Attack'){
 492                                 $findtarget = $findattacktarget;
 493                                 $findtarget->execute($c->user->id,$tick,$planet_id);
 494                         }elsif ($mission eq 'Defend'){
 495                                 $findtarget = $finddefensetarget;
 496                                 $findtarget->execute($planet_id,$tick);
 497                         }
 498
 499                         my $ships = $11;
 500                         my @ships;
 501                         my $amount = 0;
 502                         while ($ships =~ m/((?:\w+ )*\w+)\s+\w+\s+(?:(?:\w+|-)\s+){3}(?:Steal|Normal|Emp|Normal\s+Cloaked|Pod|Structure Killer)\s+(\d+)/g){
 503                                 $amount += $2;
 504                                 push @ships,{ship => $1, amount => $2};
 505                         }
 506                         $mission{ships} = \@ships;
 507
 508                         if ($amount == 0){
 509                                 warn "No ships in: $ships";
 510                                 next;
 511                         }
 512                         my $fleet = $dbh->selectrow_array($addfleet,undef,$c->user->id,$name
 513                                 ,$mission,$amount);
 514                         $addconfirmation->execute($fleet,$c->user->id,$planet_id,$tick,$eta,$back);
 515                         $mission{fleet} = $fleet;
 516                         for my $ship (@ships){
 517                                 $addships->execute($fleet,$ship->{ship},$ship->{amount});
 518                         }
 519
 520                         if ($findtarget->rows == 0){
 521                                 $mission{warning} = 'No matching target!';
 522                         }elsif ($mission eq 'Attack'){
 523                                 my $claim = $findtarget->fetchrow_hashref;
 524                                 if ($claim->{launched}){
 525                                         $mission{warning} = "Already launched on this target:$claim->{target},$claim->{wave},$claim->{launched}";
 526                                 }else{
 527                                         $addattackpoint->execute($c->user->id);
 528                                         $launchedtarget->execute($c->user->id,$claim->{target},$claim->{wave});
 529                                         $mission{warning} = "OK:$claim->{target},$claim->{wave},$claim->{launched}";
 530                                         $log->execute($c->user->id,"Gave attack point for confirmation on $mission mission to $x:$y:$z, landing tick $tick");
 531                                 }
 532                         }elsif ($mission eq 'Defend'){
 533                                 my $call = $findtarget->fetchrow_hashref;
 534                                 $informDefChannel->execute($fleet,$call->{id});
 535                         }
 536
 537                         $log->execute($c->user->id,"Pasted confirmation for $mission mission to $x:$y:$z, landing tick $tick");
 538                         push @missions,\%mission;
 539                 }
 540                 $dbh->commit;
 541                 $c->flash(missions => \@missions);
 542         };
 543         if ($@){
 544                 $dbh->rollback;
 545                 if ($@ =~ m/insert or update on table "fleet_ships" violates foreign key constraint "fleet_ships_ship_fkey"\s+DETAIL:\s+Key \(ship\)=\(([^)]+)\)/){
 546                         $c->flash( error => "'$1' is NOT a valid ship");
 547                 }else{
 548                         $c->flash( error => $@);
 549                 }
 550         }
 551
 552         $c->res->redirect($c->uri_for('launchConfirmation'));
 553 }
 554
 555 =head1 AUTHOR
 556
 557 Michael Andreen (harv@ruin.nu)
 558
 559 =head1 LICENSE
 560
 561 GPL 2.0, or later.
 562
 563 =cut
 564
 565 1;