lib/NDWeb/Controller/Members.pm

   1 package NDWeb::Controller::Members;
   2
   3 use strict;
   4 use warnings;
   5 use parent 'Catalyst::Controller';
   6
   7 use NDWeb::Include;
   8
   9 =head1 NAME
  10
  11 NDWeb::Controller::Members - Catalyst Controller
  12
  13 =head1 DESCRIPTION
  14
  15 Catalyst Controller.
  16
  17 =head1 METHODS
  18
  19 =cut
  20
  21
  22 =head2 index
  23
  24 =cut
  25
  26 sub index : Path : Args(0) {
  27         my ( $self, $c, $order ) = @_;
  28         my $dbh = $c->model;
  29
  30         $c->stash(error => $c->flash->{error});
  31
  32         $c->stash(comma => \&comma_value);
  33         $c->stash(u => $dbh->selectrow_hashref(q{SELECT planet,defense_points
  34                         ,attack_points,scan_points,humor_points
  35                         , (attack_points+defense_points+scan_points/20) as total_points
  36                         , sms,rank,hostmask FROM users WHERE uid = ?
  37                         },undef,$c->user->id)
  38         );
  39
  40         $c->stash(groups => $dbh->selectrow_array(q{SELECT array_accum(groupname)
  41                 FROM groups g NATURAL JOIN groupmembers gm
  42                 WHERE uid = $1
  43                         },undef,$c->user->id)
  44         );
  45
  46         $c->stash(p => $dbh->selectrow_hashref(q{SELECT id,x,y,z, ruler, planet,race,
  47                 size, size_gain, size_gain_day,
  48                 score,score_gain,score_gain_day,
  49                 value,value_gain,value_gain_day,
  50                 xp,xp_gain,xp_gain_day,
  51                 sizerank,sizerank_gain,sizerank_gain_day,
  52                 scorerank,scorerank_gain,scorerank_gain_day,
  53                 valuerank,valuerank_gain,valuerank_gain_day,
  54                 xprank,xprank_gain,xprank_gain_day
  55                 from current_planet_stats_full p
  56                         WHERE id = ?
  57                         },undef,$c->user->planet)
  58         );
  59
  60         my $calls = $dbh->prepare(q{
  61                 SELECT id,landing_tick,dc,curreta
  62                         ,array_accum(race::text) AS race
  63                         ,array_accum(amount) AS amount
  64                         ,array_accum(eta) AS eta
  65                         ,array_accum(shiptype) AS shiptype
  66                         ,array_accum(coords) AS attackers
  67                 FROM (SELECT c.id, c.landing_tick
  68                         ,dc.username AS dc, (c.landing_tick - tick()) AS curreta
  69                         ,p2.race, i.amount, i.eta, i.shiptype, p2.alliance
  70                         ,coords(p2.x,p2.y,p2.z)
  71                         FROM calls c
  72                                 LEFT OUTER JOIN incomings i ON i.call = c.id
  73                                 LEFT OUTER JOIN current_planet_stats p2 ON i.sender = p2.id
  74                                 LEFT OUTER JOIN users dc ON c.dc = dc.uid
  75                         WHERE c.member = $1 AND c.landing_tick >= tick()
  76                         GROUP BY c.id, c.landing_tick, dc.username
  77                                 ,p2.race,i.amount,i.eta,i.shiptype,p2.alliance,p2.x,p2.y,p2.z
  78                         ) c
  79                 GROUP BY id, landing_tick,dc,curreta
  80                 });
  81
  82         $calls->execute($c->user->id);
  83         $c->stash(calls => $calls->fetchall_arrayref({}) );
  84
  85         my $query = $dbh->prepare(q{SELECT f.id, coords(x,y,z), target, mission
  86                 , f.amount, tick, back
  87 FROM fleets f
  88 LEFT OUTER JOIN current_planet_stats p ON f.target = p.id
  89 WHERE NOT ingal AND f.uid = ? AND f.sender = ? AND
  90         (back >= ? OR (tick >= tick() -  24 AND name = 'Main'))
  91 GROUP BY f.id, x,y,z, mission, tick,back,f.amount,f.target
  92 ORDER BY x,y,z,mission,tick
  93                 });
  94
  95         my $ships = $dbh->prepare(q{SELECT ship,amount FROM fleet_ships
  96                 WHERe id = ? ORDER BY num
  97                 });
  98
  99         $query->execute($c->user->id,$c->user->planet,$c->stash->{TICK});
 100         my @fleets;
 101         while (my $fleet = $query->fetchrow_hashref){
 102                 my @ships;
 103                 $ships->execute($fleet->{id});
 104                 while (my $ship = $ships->fetchrow_hashref){
 105                         push @ships,$ship;
 106                 }
 107                 $fleet->{ships} = \@ships;
 108                 push @fleets,$fleet;
 109         }
 110         $c->stash(fleets => \@fleets);
 111
 112         my $announcements = $dbh->prepare(q{SELECT ft.ftid, u.username,ft.subject,
 113                 count(NULLIF(COALESCE(fp.time > ftv.time,TRUE),FALSE)) AS unread,count(fp.fpid) AS posts,
 114                 date_trunc('seconds',max(fp.time)::timestamp) as last_post,
 115                 min(fp.time)::date as posting_date, ft.sticky
 116                 FROM forum_threads ft JOIN forum_posts fp USING (ftid)
 117                         JOIN users u ON u.uid = ft.uid
 118                         LEFT OUTER JOIN (SELECT * FROM forum_thread_visits WHERE uid = $1) ftv ON ftv.ftid = ft.ftid
 119                 WHERE ft.fbid = 1
 120                 GROUP BY ft.ftid, ft.subject,ft.sticky,u.username
 121                 HAVING count(NULLIF(COALESCE(ft.sticky OR fp.time > ftv.time,TRUE),FALSE)) >= 1
 122                 ORDER BY sticky DESC,last_post DESC
 123                 });
 124         $announcements->execute($c->user->id);
 125         $c->stash(announcements => $announcements->fetchall_arrayref({}) );
 126 }
 127
 128 sub posthostupdate : Local {
 129         my ( $self, $c ) = @_;
 130         my $dbh = $c->model;
 131
 132         $dbh->do(q{UPDATE users SET hostmask = ? WHERE uid = ?
 133                 },undef, html_escape $c->req->param('hostname'), $c->user->id);
 134
 135         $c->res->redirect($c->uri_for(''));
 136 }
 137
 138 sub postsmsupdate : Local {
 139         my ( $self, $c ) = @_;
 140         my $dbh = $c->model;
 141
 142         $dbh->do(q{UPDATE users SET sms = ? WHERE uid = ?
 143                 },undef, html_escape $c->req->param('sms'), $c->user->id);
 144
 145         $c->res->redirect($c->uri_for(''));
 146 }
 147
 148 sub postfleetupdate : Local {
 149         my ( $self, $c ) = @_;
 150         my $dbh = $c->model;
 151
 152         my $fleet = $c->req->param('fleet');
 153         $fleet =~ s/,//g;
 154         my $amount = 0;
 155         my @ships;
 156         while ($fleet =~ m/((?:[A-Z][a-z]+ )*[A-Z][a-z]+)\s+(\d+)/g){
 157                 $amount += $2;
 158                 push @ships, [$1,$2];
 159         }
 160         if ($amount){
 161                 $dbh->begin_work;
 162                 eval{
 163                         my $insert = $dbh->prepare(q{INSERT INTO fleets
 164                                 (uid,sender,name,mission,tick,amount)
 165                                 VALUES (?,?,'Main','Full fleet',tick(),?) RETURNING id});
 166                         my ($id) = $dbh->selectrow_array($insert,undef,$c->user->id
 167                                 ,$c->user->planet,$amount);
 168                         $insert = $dbh->prepare(q{INSERT INTO fleet_ships
 169                                 (id,ship,amount) VALUES (?,?,?)});
 170                         for my $s (@ships){
 171                                 unshift @{$s},$id;
 172                                 $insert->execute(@{$s});
 173                         }
 174                         $dbh->commit;
 175                 };
 176                 if ($@){
 177                         if ($@ =~ m/insert or update on table "fleet_ships" violates foreign key constraint "fleet_ships_ship_fkey"\s+DETAIL:\s+Key \(ship\)=\(([^)]+)\)/){
 178                                 $c->flash( error => "'$1' is NOT a valid ship");
 179                         }else{
 180                                 $c->flash( error => $@);
 181                         }
 182                         $dbh->rollback;
 183                 }
 184         }else{
 185                 $c->flash( error => 'Fleet does not contain any ships');
 186         }
 187
 188         $c->res->redirect($c->uri_for(''));
 189 }
 190
 191 sub postfleetsupdates : Local {
 192         my ( $self, $c ) = @_;
 193         my $dbh = $c->model;
 194
 195         my $log = $dbh->prepare(q{INSERT INTO forum_posts (ftid,uid,message) VALUES(
 196                 (SELECT ftid FROM users WHERE uid = $1),$1,$2)
 197                 });
 198         $dbh->begin_work;
 199         if ($c->req->param('cmd') eq 'Recall Fleets'){
 200                 my $updatefleets = $dbh->prepare(q{UPDATE fleets
 201                         SET back = tick() + (tick() - (tick - eta))
 202                         WHERE uid = ? AND id = ? AND back > tick()+eta
 203                 });
 204
 205                 for my $param ($c->req->param()){
 206                         if ($param =~ /^change:(\d+)$/){
 207                                 $updatefleets->execute($c->user->id,$1);
 208                                 $log->execute($c->user->id,"Member recalled fleet $1");
 209                         }
 210                 }
 211         }elsif ($c->req->param('cmd') eq 'Change Fleets'){
 212                 my $updatefleets = $dbh->prepare(q{UPDATE fleets
 213                         SET back = ? WHERE uid = ? AND id = ?});
 214
 215                 for my $param ($c->req->param()){
 216                         if ($param =~ /^change:(\d+)$/){
 217                                 my $back = $c->req->param("back:$1");
 218                                 $updatefleets->execute($back,$c->user->id,$1);
 219                                 $log->execute($c->user->id,"Member set fleet $1 to be back tick: $back");
 220                         }
 221                 }
 222         }
 223         $dbh->commit;
 224
 225         $c->res->redirect($c->uri_for(''));
 226 }
 227
 228
 229 sub points : Local {
 230         my ( $self, $c, $order ) = @_;
 231         my $dbh = $c->model;
 232
 233         if ($order =~ /^((?:defense|attack|total|humor|scan|raid)_points)$/){
 234                 $order = "$1 DESC";
 235         }else{
 236                 $order = 'total_points DESC';
 237         }
 238
 239         my $limit = 'LIMIT 10';
 240         $limit = '' if $c->check_user_roles(qw/members_points_nolimit/);
 241
 242         my $query = $dbh->prepare(qq{SELECT username,defense_points,attack_points
 243                 ,scan_points,humor_points
 244                 ,(attack_points+defense_points+scan_points/20) as total_points
 245                 , count(NULLIF(rc.launched,FALSE)) AS raid_points
 246                 FROM users u LEFT OUTER JOIN raid_claims rc USING (uid)
 247                 WHERE uid IN (SELECT uid FROM groupmembers WHERE gid = 2)
 248                 GROUP BY username,defense_points,attack_points,scan_points,humor_points,rank
 249                 ORDER BY $order $limit});
 250         $query->execute;
 251         my @members;
 252         while (my $member = $query->fetchrow_hashref){
 253                 push @members,$member;
 254         }
 255         $c->stash(members => \@members);
 256 }
 257
 258 sub addintel : Local {
 259         my ( $self, $c, $order ) = @_;
 260
 261         $c->stash(intel => $c->flash->{intel});
 262         $c->stash(scans => $c->flash->{scans});
 263         $c->stash(intelmessage => $c->flash->{intelmessage});
 264 }
 265
 266 sub postintel : Local {
 267         my ( $self, $c, $order ) = @_;
 268
 269         $c->forward('insertintel');
 270
 271         $c->res->redirect($c->uri_for('addintel'));
 272 }
 273
 274 sub postintelmessage : Local {
 275         my ( $self, $c, $order ) = @_;
 276
 277         unless ($c->req->param('subject')){
 278                 if ($c->req->param('message') =~ /(.*\w.*)/){
 279                         $c->req->param(subject => $1);
 280                 }
 281         }
 282
 283         $c->forward('/forum/insertThread',[12]);
 284         $c->forward('/forum/insertPost',[$c->stash->{thread}]);
 285         $c->flash(intelmessage => 1);
 286
 287         $c->forward('insertintel');
 288
 289         $c->res->redirect($c->uri_for('addintel'));
 290 }
 291
 292 sub insertintel : Private {
 293         my ( $self, $c, $order ) = @_;
 294         my $dbh = $c->model;
 295
 296         $dbh->begin_work;
 297         my $findscan = $dbh->prepare(q{SELECT scan_id FROM scans
 298                 WHERE scan_id = ? AND tick >= tick() - 168 AND groupscan = ?
 299                 });
 300         my $addscan = $dbh->prepare(q{INSERT INTO scans (scan_id,tick,uid,groupscan)
 301                 VALUES (?,tick(),?,?)
 302                 });
 303         my $addpoint = $dbh->prepare(q{UPDATE users SET scan_points = scan_points + 1
 304                 WHERE uid = ?
 305                 });
 306         my @scans;
 307         my $intel = $c->req->param('message');
 308         while ($intel =~ m{http://[\w.]+/.+?scan(_id|_grp)?=(\d+)}g){
 309                 my $groupscan = (defined $1 && $1 eq '_grp') || 0;
 310                 my %scan;
 311                 $scan{id} = $2;
 312                 $scan{group} = $groupscan;
 313                 $findscan->execute($2,$groupscan);
 314                 if ($findscan->rows == 0){
 315                         if ($addscan->execute($2,$c->user->id,$groupscan)){
 316                                 $addpoint->execute($c->user->id) unless $groupscan;
 317                                 $scan{added} = 1;
 318                         }
 319                 }else{
 320                         $scan{message} = 'already exists';
 321                 }
 322                 push @scans,\%scan;
 323         }
 324         my $tick = $c->req->param('tick');
 325         unless ($tick =~ /^(\d+)$/){
 326                 $tick = $c->stash->{game}->{tick};
 327         }
 328         my $addintel = $dbh->prepare(q{INSERT INTO fleets
 329                 (name,mission,tick,target,sender,eta,amount,ingal,back,uid)
 330                 VALUES($1,$2,$3,planetid($4,$5,$6,$10),planetid($7,$8,$9,$10)
 331                         ,$11,$12,$13,$14,$15)
 332         });
 333         my @intel;
 334         while ($intel =~ m/(\d+):(\d+):(\d+)\*?\s+(\d+):(\d+):(\d+)
 335                 \*?\s+(.+)(?:Ter|Cat|Xan|Zik|Etd)?
 336                 \s+(\d+)\s+(Attack|Defend)\s+(\d+)/gx){
 337                 my $ingal = ($1 == $4 && $2 == $5) || 0;
 338                 my $lt = $tick + $10;
 339                 my $back = ($ingal ? $lt + 4 : undef);
 340                 eval {
 341                         $addintel->execute($7,$9,$lt,$1,$2,$3,$4,$5,$6,$tick,$10,$8
 342                                 ,$ingal,$back, $c->user->id);
 343                         push @intel,"Added $&";
 344                 };
 345                 if ($@){
 346                         push @intel,"Couldn't add $&: ".$dbh->errstr;
 347                 }
 348         }
 349         $dbh->commit;
 350         $c->flash(intel => \@intel);
 351         $c->flash(scans => \@scans);
 352 }
 353
 354 sub launchConfirmation : Local {
 355         my ( $self, $c ) = @_;
 356
 357         $c->stash(missions => $c->flash->{missions});
 358 }
 359
 360 sub postconfirmation : Local {
 361         my ( $self, $c ) = @_;
 362         my $dbh = $c->model;
 363
 364         eval {
 365                 my $missions = $c->req->param('mission');
 366                 my $findplanet = $dbh->prepare("SELECT planetid(?,?,?,?)");
 367                 my $findattacktarget = $dbh->prepare(q{SELECT c.target,c.wave,c.launched
 368                         FROM  raid_claims c
 369                                 JOIN raid_targets t ON c.target = t.id
 370                                 JOIN raids r ON t.raid = r.id
 371                         WHERE c.uid = ? AND r.tick+c.wave-1 = ? AND t.planet = ?
 372                                 AND r.open AND not r.removed
 373                         });
 374                 my $finddefensetarget = $dbh->prepare(q{SELECT c.id FROM calls c
 375                                 JOIN users u ON c.member = u.uid
 376                         WHERE u.planet = $1 AND c.landing_tick = $2
 377                 });
 378                 my $informDefChannel = $dbh->prepare(q{INSERT INTO defense_missions
 379                         (fleet,call) VALUES (?,?)
 380                         });
 381                 my $addattackpoint = $dbh->prepare(q{UPDATE users SET
 382                         attack_points = attack_points + 1 WHERE uid = ?
 383                         });
 384                 my $launchedtarget = $dbh->prepare(q{UPDATE raid_claims SET launched = True
 385                         WHERE uid = ? AND target = ? AND wave = ?
 386                         });
 387                 my $addfleet = $dbh->prepare(q{INSERT INTO fleets
 388                         (uid,name,mission,sender,target,tick,eta,back,amount)
 389                         VALUES ($1,$2,$3,(SELECT planet FROM users WHERE uid = $1),$4,$5,$6,$7,$8)
 390                         RETURNING id
 391                         });
 392                 my $addships = $dbh->prepare(q{INSERT INTO fleet_ships (id,ship,amount)
 393                         VALUES (?,?,?)
 394                         });
 395                 my $log = $dbh->prepare(q{INSERT INTO forum_posts (ftid,uid,message) VALUES(
 396                         (SELECT ftid FROM users WHERE uid = $1),$1,$2)
 397                         });
 398                 my @missions;
 399                 $dbh->begin_work;
 400                 while ($missions =~ m/([^\n]+)\s+(\d+):(\d+):(\d+)\s+(\d+):(\d+):(\d+)
 401                         \s+\((?:(\d+)\+)?(\d+)\).*?(?:\d+hrs\s+)?\d+mins?\s+
 402                         (Attack|Defend|Return|Fake\ Attack|Fake\ Defend)
 403                         (.*?)
 404                         (?:Launching\ in\ tick\ (\d+),\ arrival\ in\ tick\ (\d+)
 405                                 |ETA:\ \d+,\ Return\ ETA:\ (\d+)
 406                                 |Return\ ETA:\ (\d+)
 407                                 )/sgx){
 408                         next if $10 eq 'Return';
 409                         my %mission;
 410                         my $name = $1;
 411                         my $tick = $c->stash->{TICK}+$9;
 412                         $tick += $8 if defined $8;
 413                         my $eta = $9;
 414                         my $mission = $10;
 415                         my $x = $5;
 416                         my $y = $6;
 417                         my $z = $7;
 418                         my $back = $tick + $eta - 1;
 419                         if ($13){
 420                                 $tick = $13;
 421                         }elsif ($14){
 422                                 $back += $14;
 423                         }
 424                         $mission{tick} = $tick;
 425                         $mission{mission} = $mission;
 426                         $mission{target} = "$x:$y:$z";
 427                         $mission{back} = $back;
 428
 429                         my ($planet_id) = $dbh->selectrow_array($findplanet,undef,$x,$y,$z,$c->stash->{TICK});
 430
 431                         my $findtarget = $finddefensetarget;
 432                         if ($mission eq 'Attack'){
 433                                 $findtarget = $findattacktarget;
 434                                 $findtarget->execute($c->user->id,$tick,$planet_id);
 435                         }elsif ($mission eq 'Defend'){
 436                                 $findtarget = $finddefensetarget;
 437                                 $findtarget->execute($planet_id,$tick);
 438                         }
 439
 440                         my $ships = $11;
 441                         my @ships;
 442                         my $amount = 0;
 443                         while ($ships =~ m/((?:\w+ )*\w+)\s+\w+\s+(?:(?:\w+|-)\s+){3}(?:Steal|Normal|Emp|Normal\s+Cloaked|Pod|Structure Killer)\s+(\d+)/g){
 444                                 $amount += $2;
 445                                 push @ships,{ship => $1, amount => $2};
 446                         }
 447                         $mission{ships} = \@ships;
 448
 449                         if ($amount == 0){
 450                                 warn "No ships in: $ships";
 451                                 next;
 452                         }
 453                         my $fleet = $dbh->selectrow_array($addfleet,undef,$c->user->id,$name,$mission
 454                                 ,$planet_id,$tick,$eta,$back,$amount);
 455                         $mission{fleet} = $fleet;
 456                         for my $ship (@ships){
 457                                 $addships->execute($fleet,$ship->{ship},$ship->{amount});
 458                         }
 459
 460                         if ($findtarget->rows == 0){
 461                                 $mission{warning} = 'No matching target!';
 462                         }elsif ($mission eq 'Attack'){
 463                                 my $claim = $findtarget->fetchrow_hashref;
 464                                 if ($claim->{launched}){
 465                                         $mission{warning} = "Already launched on this target:$claim->{target},$claim->{wave},$claim->{launched}";
 466                                 }else{
 467                                         $addattackpoint->execute($c->user->id);
 468                                         $launchedtarget->execute($c->user->id,$claim->{target},$claim->{wave});
 469                                         $mission{warning} = "OK:$claim->{target},$claim->{wave},$claim->{launched}";
 470                                         $log->execute($c->user->id,"Gave attack point for confirmation on $mission mission to $x:$y:$z, landing tick $tick");
 471                                 }
 472                         }elsif ($mission eq 'Defend'){
 473                                 my $call = $findtarget->fetchrow_hashref;
 474                                 $informDefChannel->execute($fleet,$call->{id});
 475                         }
 476
 477                         $log->execute($c->user->id,"Pasted confirmation for $mission mission to $x:$y:$z, landing tick $tick");
 478                         push @missions,\%mission;
 479                 }
 480                 $dbh->commit;
 481                 $c->flash(missions => \@missions);
 482         };
 483         if ($@){
 484                 $dbh->rollback;
 485                 die $@;
 486         }
 487
 488         $c->res->redirect($c->uri_for('launchConfirmation'));
 489 }
 490
 491 =head1 AUTHOR
 492
 493 Michael Andreen (harv@ruin.nu)
 494
 495 =head1 LICENSE
 496
 497 GPL 2.0, or later.
 498
 499 =cut
 500
 501 1;