scripts/scans.pl

   1 #!/usr/bin/perl
   2 #**************************************************************************
   3 #   Copyright (C) 2006,2007 by Michael Andreen <harvATruinDOTnu>          *
   4 #                                                                         *
   5 #   This program is free software; you can redistribute it and/or modify  *
   6 #   it under the terms of the GNU General Public License as published by  *
   7 #   the Free Software Foundation; either version 2 of the License, or     *
   8 #   (at your option) any later version.                                   *
   9 #                                                                         *
  10 #   This program is distributed in the hope that it will be useful,       *
  11 #   but WITHOUT ANY WARRANTY; without even the implied warranty of        *
  12 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the         *
  13 #   GNU General Public License for more details.                          *
  14 #                                                                         *
  15 #   You should have received a copy of the GNU General Public License     *
  16 #   along with this program; if not, write to the                         *
  17 #   Free Software Foundation, Inc.,                                       *
  18 #   51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.         *
  19 #**************************************************************************/
  20
  21
  22 use strict;
  23 use warnings;
  24 no warnings 'exiting';
  25 use CGI;
  26 use DBI;
  27 use DBD::Pg qw(:pg_types);
  28 use LWP::Simple;
  29 use lib qw{/var/www/ndawn/};
  30 use ND::DB;
  31
  32 our $dbh = ND::DB::DB();
  33
  34 #$dbh->trace("1","/tmp/scanstest");
  35
  36 #my $test = $dbh->prepare(q{INSERT INTO scans (tick,scan_id) VALUES(1,3) RETURNING id});
  37 #print ;
  38 $dbh->do(q{SET CLIENT_ENCODING TO 'LATIN1';});
  39
  40 my $scangroups = $dbh->prepare(q{SELECT id,scan_id,tick,uid FROM scans
  41         WHERE groupscan AND NOT parsed FOR UPDATE
  42 });
  43 my $oldscan = $dbh->prepare(q{SELECT scan_id FROM scans WHERE scan_id = ? AND tick >= tick() - 168});
  44 my $addScan = $dbh->prepare(q{INSERT INTO scans (scan_id,tick,uid) VALUES (?,?,?)});
  45 my $parsedscan = $dbh->prepare(q{UPDATE scans SET tick = ?, type = ?, planet = ?, parsed = TRUE WHERE id = ?});
  46 my $addpoints = $dbh->prepare(q{UPDATE users SET scan_points = scan_points + ? WHERE uid = ? });
  47 my $delscan = $dbh->prepare(q{DELETE FROM scans WHERE id = ?});
  48
  49 $scangroups->execute or die $dbh->errstr;
  50
  51 while (my $group = $scangroups->fetchrow_hashref){
  52         $dbh->begin_work;
  53         my $file = get("http://game.planetarion.com/showscan.pl?scan_grp=$group->{scan_id}");
  54
  55         my $points = 0;
  56         while ($file =~ m/showscan.pl\?scan_id=(\d+)/g){
  57                 unless ($dbh->selectrow_array($oldscan,undef,$1)){
  58                         $addScan->execute($1,$group->{tick},$group->{uid});
  59                         ++$points;
  60                 }
  61         }
  62         $addpoints->execute($points,$group->{uid});
  63         $parsedscan->execute($group->{tick},'GROUP',undef,$group->{id});
  64         $dbh->commit;
  65 }
  66
  67 my $newscans = $dbh->prepare(q{SELECT id,scan_id,tick,uid FROM scans
  68         WHERE NOT groupscan AND NOT parsed FOR UPDATE
  69 });
  70 my $findplanet = $dbh->prepare(q{SELECT planetid(?,?,?,?)});
  71 my $findoldplanet = $dbh->prepare(q{SELECT id FROM planet_stats WHERE x = $1 AND y = $2 AND z = $3 AND tick <= $4 ORDER BY tick DESC LIMIT 1});
  72 my $findcoords = $dbh->prepare(q{SELECT * FROM planetcoords(?,?)});
  73 my $addfleet = $dbh->prepare(q{INSERT INTO fleets (name,mission,sender,target,tick,eta,back,amount,ingal,uid) VALUES(?,?,?,?,?,?,?,?,?,-1) RETURNING id});
  74 my $fleetscan = $dbh->prepare(q{INSERT INTO fleet_scans (id,scan) VALUES(?,?)});
  75 my $addships = $dbh->prepare(q{INSERT INTO fleet_ships (id,ship,amount) VALUES(?,?,?)});
  76 my $addpdata = $dbh->prepare(q{INSERT INTO planet_data (id,tick,scan,rid,amount) VALUES(?,?,?,(SELECT id FROM planet_data_types WHERE category = ? AND name = ?), ?)});
  77
  78 $dbh->begin_work or die 'No transaction';
  79 $newscans->execute or die $dbh->errstr;
  80 $dbh->pg_savepoint('scans') or die "No savepoint";
  81 while (my $scan = $newscans->fetchrow_hashref){
  82         my $file = get("http://game.planetarion.com/showscan.pl?scan_id=$scan->{scan_id}");
  83         next unless defined $file;
  84         if ($file =~ /((?:\w| )*) (?:Scan|Probe) on (\d+):(\d+):(\d+) in tick (\d+)/){
  85                 eval {
  86                 my $type = $1;
  87                 my $x = $2;
  88                 my $y = $3;
  89                 my $z = $4;
  90                 my $tick = $5;
  91
  92                 if($dbh->selectrow_array(q{SELECT * FROM scans WHERE scan_id = ? AND tick = ? AND id <> ?},undef,$scan->{scan_id},$tick,$scan->{id})){
  93                         $dbh->pg_rollback_to('scans') or die "rollback didn't work";
  94                         $delscan->execute($scan->{id});
  95                         $addpoints->execute(-1,$scan->{uid}) if $scan->{uid} > 0;
  96                         die "Duplicate scan: $scan->{id} http://game.planetarion.com/showscan.pl?scan_id=$scan->{scan_id}\n";
  97                 }
  98                 my ($planet) = $dbh->selectrow_array($findplanet,undef,$x,$y,$z,$tick);
  99                 unless ($planet){
 100                         $dbh->pg_rollback_to('scans') or die "rollback didn't work";
 101                         next;
 102                 }
 103                 my $scantext = "";
 104                 if ($file =~ /(Note: [^<]*)/){
 105                         #TODO: something about planet being closed?
 106                 }
 107                 if ($type eq 'Planet'){
 108                         $file =~ s/(\d),(\d)/$1$2/g;
 109                         while($file =~ m/"left">(Metal|Crystal|Eonium)\D+(\d+)\D+(\d+)/g){
 110                                 $addpdata->execute($planet,$tick,$scan->{id}
 111                                         ,'roid',$1, $2) or die $dbh->errstr;
 112                                 $addpdata->execute($planet,$tick,$scan->{id}
 113                                         ,'resource',$1, $3) or die $dbh->errstr;
 114                         }
 115                 }elsif ($type eq 'Jumpgate'){
 116                         while ($file =~ m/(\d+):(\d+):(\d+)\D+"left"\>(Attack|Defend|Return)<\/td><td>([^<]*)<\/td><td>(\d+)\D+(\d+)/g){
 117
 118                                 my ($sender) = $dbh->selectrow_array($findplanet,undef,$1,$2,$3,$tick) or die $dbh->errstr;
 119                                 ($sender) = $dbh->selectrow_array($findoldplanet,undef,$1,$2,$3,$tick) if ((not defined $sender) && $4 eq 'Return');
 120                                 my $id = addfleet($5,$4,undef,$sender,$planet,$tick+$6,$6
 121                                         ,undef,$7, $x == $1 && $y == $2);
 122                                 $fleetscan->execute($id,$scan->{id}) or die $dbh->errstr;
 123                         }
 124                 }elsif ($type eq 'News'){
 125                         while( $file =~ m{top">((?:\w| )+)\D+(\d+)</td><td class="left" valign="top">(.+?)</td></tr>}g){
 126                                 my $news = $1;
 127                                 my $t = $2;
 128                                 my $text = $3;
 129                                 my ($x,$y,$z) = $dbh->selectrow_array($findcoords,undef,$planet,$t);
 130                                 die "No coords for: $planet tick $t" unless defined $x;
 131                                 if($news eq 'Launch' && $text =~ m/The (.*?) fleet has been launched, heading for (\d+):(\d+):(\d+), on a mission to (Attack|Defend). Arrival tick: (\d+)/g){
 132                                         my $eta = $6 - $t;
 133                                         my $mission = $5;
 134                                         my $back = $6 + $eta;
 135                                         $mission = 'AllyDef' if $eta == 6 && $x != $2;
 136                                         my ($target) = $dbh->selectrow_array($findplanet,undef
 137                                                 ,$2,$3,$4,$t) or die $dbh->errstr;
 138                                         die "No target: $2:$3:$4" unless defined $target;
 139                                         my $id = addfleet($1,$mission,undef,$planet,$target,$6
 140                                                 ,$eta,$back,undef, ($x == $2 && $y == $3));
 141                                         $fleetscan->execute($id,$scan->{id}) or die $dbh->errstr;
 142                                 }elsif($news eq 'Incoming' && $text =~ m/We have detected an open jumpgate from (.*?), located at (\d+):(\d+):(\d+). The fleet will approach our system in tick (\d+) and appears to have roughly (\d+) ships/g){
 143                                         my $eta = $5 - $t;
 144                                         my $mission = '';
 145                                         my $back = $5 + $eta;
 146                                         $mission = 'Defend' if $eta <= 6;
 147                                         $mission = 'AllyDef' if $eta == 6 && $x != $2;
 148                                         my ($target) = $dbh->selectrow_array($findplanet,undef
 149                                                 ,$2,$3,$4,$t) or die $dbh->errstr;
 150                                         die "No target: $2:$3:$4" unless defined $target;
 151                                         my $id = addfleet($1,$mission,undef,$target,$planet,$5
 152                                                 ,$eta,$back,$6, ($x == $2 && $y == $3));
 153                                         $fleetscan->execute($id,$scan->{id}) or die $dbh->errstr;
 154                                 }
 155                         }
 156                 } elsif($type eq 'Surface Analysis' || $type eq 'Technology Analysis'){
 157                         my $cat = ($type eq 'Surface Analysis' ? 'struc' : 'tech');
 158                         while($file =~ m{((?:[a-zA-Z]| )+)</t[dh]><td(?: class="right")?>(\d+)}sg){
 159                                 $addpdata->execute($planet,$tick,$scan->{id}
 160                                         ,$cat,$1, $2) or die $dbh->errstr;
 161                         }
 162
 163                 } elsif($type eq 'Unit' || $type eq 'Advanced Unit'){
 164                         my $id = addfleet($type,'Full fleet',$file,$planet,undef,$tick,undef,undef,undef);
 165                         $fleetscan->execute($id,$scan->{id}) or die $dbh->errstr;
 166                 } elsif($type eq 'Incoming'){
 167                         while($file =~ m{class="left">Fleet: (.*?)</td><td class="left">Mission: (\w+)</td></tr>(.*?)Total Ships: (\d+)}sg){
 168                                 my $id = addfleet($1,$2,$3,$planet,undef,$tick,undef,undef,$4);
 169                                 $fleetscan->execute($id,$scan->{id}) or die $dbh->errstr;
 170                         }
 171                 } else {
 172                         print "Something wrong with scan $scan->{id} type $type at tick $tick http://game.planetarion.com/showscan.pl?scan_id=$scan->{scan_id}";
 173                 }
 174                 $parsedscan->execute($tick,$type,$planet,$scan->{id}) or die $dbh->errstr;
 175                 $dbh->pg_release('scans') or die "Couldn't save";
 176                 $dbh->pg_savepoint('scans') or die "Couldn't save";
 177                 #$dbh->rollback;
 178                 };
 179                 if ($@) {
 180                         warn $@;
 181                         $dbh->pg_rollback_to('scans') or die "rollback didn't work";
 182                 }
 183         }else{
 184                 warn "Nothing useful in scan: $scan->{id} http://game.planetarion.com/showscan.pl?scan_id=$scan->{scan_id}\n";
 185                 $delscan->execute($scan->{id});
 186                 $addpoints->execute(-1,$scan->{uid}) if $scan->{uid} > 0;
 187         }
 188 }
 189 $dbh->commit;
 190
 191 sub addfleet {
 192         my ($name,$mission,$ships,$sender,$target,$tick,$eta,$back,$amount,$ingal) = @_;
 193
 194         die "no sender" unless defined $sender;
 195
 196         $ingal = 0 unless $ingal;
 197         $back = $tick + 4 if $ingal && $eta <= 4;
 198
 199         if ($mission eq 'Return'){
 200                 ($sender,$target) = ($target,$sender);
 201                 $back = $tick + $eta if $eta;
 202         }
 203
 204         my @ships;
 205         my $total = 0;
 206         while(defined $ships && $ships =~ m{((?:[a-zA-Z]| )+)</td><td>(\d+)}sg){
 207                 $total += $2;
 208                 push @ships, [$1,$2];
 209         }
 210         $amount = $total if (!defined $amount) && defined $ships;
 211         my $id = $dbh->selectrow_array($addfleet,undef,$name,$mission,$sender
 212                 ,$target,$tick, $eta, $back, $amount,$ingal) or die $dbh->errstr;
 213         for my $s (@ships){
 214                 unshift @{$s},$id;
 215                 $addships->execute(@{$s}) or die $dbh->errstr;
 216         }
 217         return $id;
 218 };