Commands/Channel.pm

   1 #**************************************************************************
   2 #   Copyright (C) 2008 by Michael Andreen <harvATruinDOTnu>               *
   3 #                                                                         *
   4 #   This program is free software; you can redistribute it and/or modify  *
   5 #   it under the terms of the GNU General Public License as published by  *
   6 #   the Free Software Foundation; either version 2 of the License, or     *
   7 #   (at your option) any later version.                                   *
   8 #                                                                         *
   9 #   This program is distributed in the hope that it will be useful,       *
  10 #   but WITHOUT ANY WARRANTY; without even the implied warranty of        *
  11 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the         *
  12 #   GNU General Public License for more details.                          *
  13 #                                                                         *
  14 #   You should have received a copy of the GNU General Public License     *
  15 #   along with this program; if not, write to the                         *
  16 #   Free Software Foundation, Inc.,                                       *
  17 #   51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.         *
  18 #**************************************************************************/
  19
  20 package NDIRC::Commands::Channel;
  21
  22 use strict;
  23 use warnings;
  24 use feature ':5.10';
  25
  26 use Moose;
  27 use MooseX::MethodAttributes;
  28
  29 sub op
  30         : Alias(qw/deop voice devoice/)
  31         : Help(syntax: .op [nicks] | Gives op to the specified nicks, or yourself if no command is given)
  32         : Type(channel)
  33 {
  34         my ($self,$c,$msg) = @_;
  35
  36         my ($access) = $self->name =~ /(op|voice)/;
  37
  38         my $where = "";
  39         if ($msg =~ /^\s*$/){
  40                 $msg = $c->nick;
  41                 $where = "OR f.name = 'auto_$access'";
  42         }
  43
  44         my $mode = qq{
  45 SELECT DISTINCT c.name FROM users u
  46         JOIN groupmembers g ON g.uid = u.uid
  47         JOIN channel_group_flags gf ON g.gid = gf.group
  48         JOIN channels c ON gf.channel = c.id
  49         JOIN channel_flags f ON f.id = gf.flag
  50 WHERE u.hostmask ILIKE ? AND c.name = ? AND (f.name = '$access' $where);
  51                 };
  52         if ($c->check_user_roles(qw/irc_masterop/)){
  53                 $mode = 1;
  54         }else{
  55                 ($mode) = $c->model->selectrow_array($mode,undef,$c->host,$c->channel);
  56         }
  57         if ($mode){
  58                 $c->server->command($self->name . " " . $c->channel . " $msg");
  59         }else{
  60                 $c->reply("No access to " . $self->name . " in this channel");
  61         }
  62 }
  63
  64 sub invite
  65         :Help(Syntax: invite [channel] | If no channel is specified it invites you to all channel you have auto invite access on)
  66         : Type(pm)
  67 {
  68         my ($self,$c,$msg) = @_;
  69
  70         my ($channel) = $msg =~ /^\s*(\S+)?\s*$/ or die 'ARGS';
  71
  72         my @channels;
  73         if ($channel && $c->check_user_roles('irc_masterinvite')){
  74                 push @channels,$channel;
  75         }else{
  76                 my @access = ('auto_invite');
  77                 push @access, 'invite' if $channel;
  78                 my $channels = $c->model->prepare(q{
  79 SELECT DISTINCT c.name FROM users u
  80         JOIN groupmembers g ON g.uid = u.uid
  81         JOIN channel_group_flags gf ON g.gid = gf.group
  82         JOIN channels c ON gf.channel = c.id
  83         JOIN channel_flags f ON f.id = gf.flag
  84 WHERE u.hostmask ILIKE $1 AND COALESCE(c.name = $2,TRUE)
  85         AND (f.name = ANY($3) )
  86                 });
  87                 $channels->execute($c->host,$channel,\@access);
  88                 while (my ($channel) = $channels->fetchrow()){
  89                         push @channels,$channel;
  90                 }
  91         }
  92         for (@channels){
  93                 $c->server->command("invite ". $c->nick ." $_");
  94         }
  95 }
  96
  97 sub hostname
  98         : Help(Shows your hostname, as seen by the bots.)
  99 {
 100         my ($self,$c,$msg) = @_;
 101
 102         $c->reply('Your hostname is: '.$c->host);
 103 }
 104
 105 ###########################################################
 106 # Written by Guy Malachi http://guymal.com
 107 # 18 August, 2002
 108 ###########################################################
 109 sub generate_random_string
 110 {
 111         my $length_of_randomstring=shift;# the length of
 112                          # the random string to generate
 113
 114         my @chars=('a'..'z','A'..'Z','0'..'9','_');
 115         my $random_string;
 116         foreach (1..$length_of_randomstring)
 117         {
 118                 # rand @chars will generate a random
 119                 # number between 0 and scalar @chars
 120                 $random_string .= $chars[rand @chars];
 121         }
 122         return $random_string;
 123 }
 124
 125 sub getpass
 126         : Help(Gives new users a random password.)
 127         : Type(pm)
 128 {
 129         my ($self,$c,$msg) = @_;
 130         my $dbh = $c->model;
 131
 132         my $password = generate_random_string 10;
 133         my $update = $dbh->do(q{
 134 UPDATE users SET password = MD5( ? )
 135 WHERE hostmask ILIKE ? AND password =''
 136                 },undef,$password,$c->host);
 137         if ($update > 0){
 138                 $c->reply("Password set to: $password (you can change it on webbie)");
 139         }else{
 140                 $c->reply("Couldn't set password. Either it has already been set or you don't have an account");
 141         }
 142 }
 143
 144 1;