lib/NDWeb/Controller/Alliances.pm

   1 package NDWeb::Controller::Alliances;
   2
   3 use strict;
   4 use warnings;
   5 use parent 'Catalyst::Controller';
   6
   7 =head1 NAME
   8
   9 NDWeb::Controller::Alliances - Catalyst Controller
  10
  11 =head1 DESCRIPTION
  12
  13 Catalyst Controller.
  14
  15 =head1 METHODS
  16
  17 =cut
  18
  19
  20 =head2 index
  21
  22 =cut
  23
  24 sub index :Path :Args(0) {
  25         my ( $self, $c ) = @_;
  26         $c->stash(template => 'alliances/list.tt2');
  27         $c->forward('list');
  28 }
  29
  30 sub list : Local {
  31         my ( $self, $c, $order ) = @_;
  32         my $dbh = $c->model;
  33
  34         if (defined $order && $order =~ /^(score|kscore|size|ksize|members|kmem|kxp
  35                         |kxp|scavg|kscavg|siavg|ksiavg|kxpavg|kvalue|kvalavg)$/x){
  36                 $order = "$1 DESC";
  37         } else {
  38                 $order = "score DESC";
  39         }
  40         my $query = $dbh->prepare(q{
  41                 SELECT aid AS id,alliance AS name,COALESCE(s.score,SUM(p.score)) AS score
  42                         ,COALESCE(s.size,SUM(p.size)) AS size,s.members,count(p.score) AS kmem
  43                         ,COALESCE(SUM(p.score),-1) AS kscore
  44                         ,COALESCE(SUM(p.size),-1) AS ksize
  45                         ,COALESCE(SUM(p.xp),-1) AS kxp
  46                         ,COALESCE(SUM(p.value),-1) AS kvalue
  47                         ,COALESCE(s.score/LEAST(s.members,60),-1) AS scavg
  48                         ,COALESCE(AVG(p.score)::int,-1) AS kscavg
  49                         ,COALESCE(s.size/s.members,-1) AS siavg
  50                         ,COALESCE(AVG(p.size)::int,-1) AS ksiavg
  51                         ,COALESCE(AVG(p.xp)::int,-1) AS kxpavg
  52                         ,COALESCE(AVG(p.value)::int,-1) AS kvalavg
  53                 FROM alliances a
  54                         LEFT OUTER JOIN (SELECT * FROM alliance_stats
  55                                 WHERE tick = (SELECT max(tick) FROM alliance_stats)) s USING (aid)
  56                         LEFT OUTER JOIN current_planet_stats p USING (alliance,aid)
  57                 GROUP BY aid,alliance,s.score,s.size,s.members
  58                 HAVING s.score IS NOT NULL OR count(p.score) > 0
  59                 ORDER BY
  60                 } . $order);
  61         $query->execute;
  62         $c->stash(alliances => $query->fetchall_arrayref({}) );
  63 }
  64
  65 sub edit : Local {
  66         my ( $self, $c, $id, $order ) = @_;
  67         my $dbh = $c->model;
  68
  69         my $query = $dbh->prepare(q{SELECT aid AS id,alliance AS name, relationship FROM alliances WHERE aid = ?});
  70         my $a = $dbh->selectrow_hashref($query,undef,$id);
  71         $c->stash(a => $a);
  72
  73
  74         if ($order && $order =~ /^((score|size|value|xp|hit_us|race)(rank)?)$/){
  75                 $order = $1;
  76         }else {
  77                 $order = 'x,y,z';
  78         }
  79         $c->stash(order => $order);
  80
  81         $order .= ' DESC' if $order eq 'hit_us';
  82
  83         my $members = $dbh->prepare(q{
  84                 SELECT pid AS id, coords(x,y,z), nick, ruler, planet, race, size, score, value, xp
  85                         ,planet_status,hit_us, sizerank, scorerank, valuerank, xprank
  86                 FROM current_planet_stats p
  87                 WHERE p.alliance = ?
  88                 ORDER BY
  89                 } . $order);
  90         $members->execute($a->{name});
  91         $c->stash(members => $members->fetchall_arrayref({}) );
  92
  93         my $ticks = $c->req->param('ticks') || 48;
  94         $c->stash(showticks => $ticks);
  95
  96         $query = $dbh->prepare(q{
  97 SELECT salliance, scoords, sender, talliance, tcoords, target
  98         ,mission, tick AS landingtick, eta, amount, ingal, username
  99 FROM full_intel
 100 WHERE NOT ingal AND (salliance = $1 OR talliance = $1)
 101         AND (mission = 'Defend' OR mission = 'AllyDef')
 102         AND COALESCE( talliance <> salliance, TRUE)
 103         AND tick > (tick() - $2)
 104 ORDER BY tick DESC, mission
 105                 });
 106         $query->execute($a->{name}, $ticks);
 107         $c->stash(intel => $query->fetchall_arrayref({}) );
 108 }
 109
 110 sub postallianceupdate : Local {
 111         my ( $self, $c, $id, $order ) = @_;
 112         my $dbh = $c->model;
 113
 114         my $query = $dbh->prepare(q{SELECT aid,alliance, relationship FROM alliances WHERE aid = ?});
 115         my $a = $dbh->selectrow_hashref($query,undef,$id);
 116
 117         $dbh->begin_work;
 118         my $log = $dbh->prepare(q{INSERT INTO forum_posts (ftid,uid,message) VALUES(
 119                 (SELECT ftid FROM users WHERE uid = $1),$1,$2)
 120                 });
 121         if ($c->req->param('crelationship')){
 122                 my $value = $c->req->param('relationship');
 123                 $dbh->do(q{UPDATE alliances SET relationship = ? WHERE aid =?}
 124                         ,undef,$value,$id);
 125                 $log->execute($c->user->id
 126                         ,"HC set alliance: $a->{alliance} ($id) relationship: $value");
 127         }
 128         my $coords = $c->req->param('coords');
 129         my $findplanet = $dbh->prepare(q{SELECT pid FROM current_planet_stats
 130                 WHERE x = ? AND y = ? AND z = ?});
 131         my $addplanet = $dbh->prepare(q{
 132                 UPDATE planets SET alliance = $2, nick = coalesce($3,nick)
 133                 WHERE pid = $1;
 134                 });
 135         my $text = '';
 136         while ($coords =~ m/(\d+):(\d+):(\d+)(?:\s+nick=(\S+))?/g){
 137                 my ($planet) = $dbh->selectrow_array($findplanet,undef,$1,$2,$3);
 138                 $addplanet->execute($planet,$a->{alliance},$4);
 139                 my $nick = '';
 140                 $nick = "(nick $4)" if defined $4;
 141                 $text .= "($planet) $1:$2:$3 $nick\n";
 142         }
 143         if ($text){
 144                 $log->execute($c->user->id
 145                         ,"HC added the following planets to alliance $a->{alliance} ($id):\n $text");
 146         }
 147         $dbh->commit;
 148
 149         $c->res->redirect($c->uri_for('edit',$id));
 150 }
 151
 152 sub postremoveallplanets : Local {
 153         my ( $self, $c, $id, $order ) = @_;
 154         my $dbh = $c->model;
 155
 156         my $query = $dbh->prepare(q{SELECT aid,alliance, relationship FROM alliances WHERE aid = ?});
 157         my $a = $dbh->selectrow_hashref($query,undef,$id);
 158
 159         $dbh->begin_work;
 160         my $log = $dbh->prepare(q{INSERT INTO forum_posts (ftid,uid,message) VALUES(
 161                 (SELECT ftid FROM users WHERE uid = $1),$1,$2)
 162                 });
 163         my ($coords) = $dbh->selectrow_array(q{SELECT array_to_string(array_agg(coords(x,y,z)),' ')
 164                         FROM current_planet_stats where alliance = $1
 165                 },undef,$a->{alliance});
 166         my $removeplanets = $dbh->prepare(q{
 167                 UPDATE planets SET alliance = NULL
 168                 WHERE alliance = $1;
 169         });
 170         $removeplanets->execute($a->{alliance});
 171         $log->execute($c->user->id
 172                 ,"HC cleaned alliance $a->{alliance} (id) :\n\n$coords");
 173         $dbh->commit;
 174
 175         $c->res->redirect($c->uri_for('edit',$id));
 176 }
 177
 178 sub hostile : Local {
 179     my ( $self, $c, $order ) = @_;
 180         my $dbh = $c->model;
 181
 182         my $begintick = 0;
 183         my $endtick = $c->stash->{TICK};
 184         if ($c->req->param('ticks')){
 185                 $begintick = $endtick - $c->req->param('ticks');
 186         }elsif(defined $c->req->param('begintick') && defined $c->req->param('endtick')){
 187                 $begintick = $c->req->param('begintick');
 188                 $endtick = $c->req->param('endtick');
 189         }
 190
 191         my $query = $dbh->prepare(q{
 192 SELECT aid, alliance, hostile_count, targeted, targeted_raids
 193 FROM hostile_alliances($1,$2)
 194 ORDER BY hostile_count DESC
 195                 });
 196         $query->execute($begintick,$endtick);
 197         $c->stash(alliances => $query->fetchall_arrayref({}) );
 198         $c->stash(ticks => $endtick - $begintick);
 199         $c->stash(begin_tick => $begintick);
 200         $c->stash(end_tick => $endtick);
 201 }
 202
 203 sub resources : Local {
 204     my ( $self, $c, $order ) = @_;
 205         my $dbh = $c->model;
 206
 207         if (defined $order && $order =~ /^(size|score|resources|hidden|resplanet|hidplanet|nscore|nscore2|nscore3)$/){
 208                 $order = "$1 DESC";
 209         }else{
 210                 $order = "resplanet DESC";
 211         }
 212
 213         my $query = $dbh->prepare(q{
 214 SELECT aid AS id,alliance AS name,relationship,members,score,size
 215         ,resources,hidden,planets
 216         ,(resources/planets)::bigint AS resplanet
 217         ,(hidden/planets)::bigint AS hidplanet
 218         , nscore, nscore2, nscore3
 219 FROM alliance_resources
 220 ORDER BY } . $order
 221         );
 222         $query->execute;
 223         $c->stash(alliances => $query->fetchall_arrayref({}));
 224 }
 225
 226
 227 =head1 AUTHOR
 228
 229 Michael Andreen (harv@ruin.nu)
 230
 231 =head1 LICENSE
 232
 233 GPL 2.0, or later.
 234
 235 =cut
 236
 237 1;