lib/NDWeb/Controller/Calls.pm

   1 package NDWeb::Controller::Calls;
   2
   3 use strict;
   4 use warnings;
   5 use parent 'Catalyst::Controller';
   6
   7 use NDWeb::Include;
   8
   9 =head1 NAME
  10
  11 NDWeb::Controller::Calls - Catalyst Controller
  12
  13 =head1 DESCRIPTION
  14
  15 Catalyst Controller.
  16
  17 =head1 METHODS
  18
  19 =cut
  20
  21
  22 =head2 index
  23
  24 =cut
  25
  26 sub index : Path : Args(0) {
  27         my ( $self, $c) = @_;
  28
  29         $c->stash(template => 'calls/list.tt2');
  30         $c->forward('list');
  31 }
  32
  33 sub list : Local {
  34         my ( $self, $c, $type ) = @_;
  35         my $dbh = $c->model;
  36
  37         my $where = q{status = 'Open' AND landing_tick-6 > tick()};
  38         my $order = q{landing_tick DESC, defprio DESC};
  39         if (defined $type){
  40                 if ($type eq 'covered'){
  41                         $where = q{status = 'Covered'};
  42                 }elsif ($type eq 'all'){
  43                         $where = 'true';
  44                 }elsif ($type eq 'uncovered'){
  45                         $where = q{status <> 'Covered'};
  46                 }elsif ($type eq 'recent'){
  47                         $where = q{landing_tick >= tick()};
  48                         $order = q{x,y,z};
  49                 }
  50         }
  51         my $pointlimits = $dbh->prepare(q{SELECT value :: float FROM misc WHERE id = ?});
  52         $c->stash(minprio => $dbh->selectrow_array($pointlimits,undef,'DEFMINPRIO'));
  53         $c->stash(maxprio => $dbh->selectrow_array($pointlimits,undef,'DEFMAXPRIO'));
  54
  55         my $query = $dbh->prepare(qq{
  56 SELECT *, pid AS planet, coords(x,y,z)
  57 FROM full_defcalls
  58 WHERE $where
  59 ORDER BY $order
  60                 });
  61         $query->execute;
  62         $c->stash(calls => $query->fetchall_arrayref({}));
  63 }
  64
  65 sub edit : Local {
  66         my ( $self, $c, $call) = @_;
  67         my $dbh = $c->model;
  68
  69         $c->forward('findCall');
  70         $call = $c->stash->{call};
  71
  72
  73         $c->stash(cover => ($call->{covered} ? 'Uncover' : 'Cover'));
  74         if ($call->{open} && !$call->{covered}){
  75                 $c->stash(ignore => 'Ignore');
  76         }else{
  77                 $c->stash(ignore => 'Open');
  78         }
  79
  80
  81         my $outgoings = $dbh->prepare(q{
  82 (
  83         SELECT DISTINCT ON (mission,name) 1 AS type, fid,mission,name,tick, NULL AS eta
  84                 ,amount, NULL AS coords, pid AS planet, NULL AS back, NULL AS recalled
  85         FROM fleets f
  86         WHERE pid = $1 AND tick <= $2 AND (
  87                         mission = 'Full fleet'
  88                         OR fid IN (SELECT fid FROM fleet_scans)
  89                 ) AND (
  90                         mission = 'Full fleet'
  91                         OR tick >= $2 - 12
  92                 )
  93         ORDER BY mission,name,tick DESC
  94 ) UNION (
  95         SELECT 2 AS type, MAX(fid) AS fid,mission,name,landing_tick AS tick, eta, amount
  96                 , coords(x,y,z), pid AS planet, back
  97                 , (back <> landing_tick + eta - 1) AS recalled
  98         FROM launch_confirmations
  99                 JOIN (
 100                         SELECT fid,amount,name,mission FROM fleets WHERE pid = $1
 101                 ) f  USING (fid)
 102                 LEFT OUTER JOIN current_planet_stats t USING (pid)
 103         WHERE back >= $2 AND landing_tick - eta - 12 < $2
 104         GROUP BY mission,name,landing_tick,eta,amount,back,x,y,z,pid
 105 ) UNION (
 106         SELECT DISTINCT ON (tick,x,y,z,mission,name,amount)
 107                 3 AS type, NULL as fid, i.mission, i.name, i.tick,eta
 108                 , i.amount, coords(x,y,z), t.pid AS planet, back, NULL AS recalled
 109         FROM intel i
 110         LEFT OUTER JOIN current_planet_stats t ON i.target = t.pid
 111         WHERE uid = -1 AND i.sender = $1 AND i.tick > $2 - 14 AND i.tick < $2 + 14
 112         ORDER BY i.tick,x,y,z,mission,name,amount,back
 113 ) ORDER BY type, mission,name,tick DESC
 114         });
 115         my $ships = $dbh->prepare(q{SELECT ship,amount FROM fleet_ships
 116                 WHERE fid = ? ORDER BY num
 117                 });
 118         $outgoings->execute($call->{pid},$call->{landing_tick});
 119         my @fleets;
 120         while (my $fleet = $outgoings->fetchrow_hashref){
 121                 if (defined $fleet->{back} &&
 122                                 $fleet->{back} == $call->{landing_tick}){
 123                         $fleet->{fleetcatch} = 1;
 124                 }
 125                 if ($fleet->{fid}){
 126                         $ships->execute($fleet->{fid});
 127                         my @ships;
 128                         while (my $ship = $ships->fetchrow_hashref){
 129                                 push @ships,$ship;
 130                         }
 131                         push @ships, {ship => 'No', amount => 'ships'} if @ships == 0;
 132                         $fleet->{ships} = \@ships;
 133                 }
 134                 push @fleets, $fleet;
 135         }
 136
 137         my $available = $dbh->prepare(q{
 138 SELECT ship,amount from ships_home WHERE pid = $1 AND tick = $2
 139                 });
 140         $available->execute($call->{pid}, $call->{landing_tick});
 141         my $fleet = {fid => $call->{member}, mission => 'Available'
 142                 , name => 'At home', ships => $available->fetchall_arrayref({})
 143         };
 144         push @fleets, $fleet;
 145
 146         $c->stash(fleets => \@fleets);
 147
 148         my $defenders = $dbh->prepare(q{
 149 WITH lc AS (
 150         SELECT fid,uid,back,eta,landing_tick
 151         FROM launch_confirmations
 152         WHERE pid = $1 AND landing_tick = $2
 153 ), lcp AS (
 154         SELECT DISTINCT ON (fid) fid,tick,value
 155         FROM lc
 156                 JOIN users u USING (uid)
 157                 JOIN planet_stats USING (pid)
 158         WHERE tick <= landing_tick - eta
 159         ORDER BY fid,tick DESC
 160 ), lcv AS (
 161         SELECT fid,(sum(amount*(metal+crystal+eonium)) / value)::int  AS value_ratio
 162         FROM lcp
 163                 JOIN fleet_ships fs USING (fid)
 164                 JOIN ship_stats s ON s.name = fs.ship
 165         GROUP BY fid, value
 166 )
 167 SELECT DISTINCT ON (x,y,z,pid,name,amount,back) fid,mission, name, eta
 168         , amount, coords(x,y,z) AS coords, landing_tick AS tick, pid AS planet
 169         ,back, (back <> landing_tick + eta - 1) AS recalled, value_ratio
 170 FROM fleets f
 171         LEFT OUTER JOIN current_planet_stats s USING (pid)
 172         JOIN lc USING (fid)
 173         JOIN lcv USING (fid)
 174 WHERE mission IN ('Defend', 'Fake Defend')
 175 ORDER BY x,y,z
 176         });
 177
 178         $defenders->execute($call->{pid},$call->{landing_tick});
 179         my @defenders;
 180         while (my $fleet = $defenders->fetchrow_hashref){
 181                 $ships->execute($fleet->{fid});
 182                 if ($ships->rows != 0){
 183                         my @ships;
 184                         while (my $ship = $ships->fetchrow_hashref){
 185                                 push @ships,$ship;
 186                         }
 187                         $fleet->{ships} = \@ships;
 188                 }
 189                 push @defenders, $fleet;
 190         }
 191         $c->stash(defenders => \@defenders);
 192
 193         my $attackers = $dbh->prepare(q{
 194                 SELECT coords(p.x,p.y,p.z), p.planet_status, p.race,i.eta,i.amount
 195                         ,i.fleet,i.shiptype,p.relationship,p.alliance,inc,pid
 196                 FROM incomings i
 197                         JOIN current_planet_stats p USING (pid)
 198                 WHERE i.call = ?
 199                 ORDER BY p.x,p.y,p.z
 200         });
 201         $attackers->execute($call->{call});
 202         my @attackers;
 203         while(my $attacker = $attackers->fetchrow_hashref){
 204                 $outgoings->execute($attacker->{pid},$call->{landing_tick});
 205                 my @missions;
 206                 while (my $mission = $outgoings->fetchrow_hashref){
 207                         if ($mission->{fid}){
 208                                 $ships->execute($mission->{fid});
 209                                 my @ships;
 210                                 while (my $ship = $ships->fetchrow_hashref){
 211                                         push @ships,$ship;
 212                                 }
 213                                 push @ships, {ship => 'No', amount => 'ships'} if @ships == 0;
 214                                 $mission->{ships} = \@ships;
 215                         }
 216                         push @missions,$mission;
 217                 }
 218                 $attacker->{missions} = \@missions;
 219                 push @attackers,$attacker;
 220         }
 221         $c->stash(attackers => \@attackers);
 222
 223         $c->forward('/forum/findPosts',[$call->{ftid}]);
 224
 225         my $statuses = $dbh->prepare(q{
 226 SELECT status FROM call_statuses
 227                 });
 228         $statuses->execute;
 229         $c->stash(statuses => $statuses->fetchall_arrayref({}));
 230 }
 231
 232 sub defleeches : Local {
 233         my ( $self, $c, $type ) = @_;
 234         my $dbh = $c->model;
 235
 236         my $query = $dbh->prepare(q{
 237 SELECT username, defense_points, calls, fleets, recalled, defended_calls, value, sent_value
 238 FROM def_leeches
 239 ORDER BY value DESC NULLS LAST, defense_points
 240                 });
 241         $query->execute;
 242
 243         $c->stash(members => $query->fetchall_arrayref({}) );
 244 }
 245
 246 sub postcallcomment : Local {
 247         my ($self, $c, $call) = @_;
 248
 249         $c->forward('findCall');
 250         $call = $c->stash->{call};
 251
 252         $c->forward('/forum/insertPost',[$call->{ftid}]);
 253         $c->res->redirect($c->uri_for('edit',$call->{call}));
 254 }
 255
 256 sub postcallupdate : Local {
 257         my ($self, $c, $call) = @_;
 258         my $dbh = $c->model;
 259
 260         $c->forward('findCall');
 261         $call = $c->stash->{call};
 262
 263         my $log = $dbh->prepare(q{INSERT INTO forum_posts (ftid,uid,message)
 264                 VALUES($2,$1,$3)
 265                 });
 266
 267         $dbh->begin_work;
 268         if ($c->req->param('cmd') eq 'Submit'){
 269                 my $logmess = '';
 270                 if ($c->req->param('ctick')){
 271                         $dbh->do(q{UPDATE calls SET landing_tick = ? WHERE call = ?}
 272                                 ,undef,$c->req->param('tick'),$call->{call});
 273                         $logmess .= "Updated landing tick from [B] $call->{landing_tick} [/B]\n";
 274                 }
 275                 if ($c->req->param('cinfo')){
 276                         $dbh->do(q{UPDATE calls SET info = ? WHERE call = ?}
 277                                 ,undef,$c->req->param('info'),$call->{call});
 278                         $logmess .= "Updated info\n";
 279                 }
 280                 if ($c->req->param('ccalc')){
 281                         my $calc = $c->req->param('calc');
 282                         $dbh->do(q{UPDATE calls SET calc = ? WHERE call = ?}
 283                                 ,undef,$calc,$call->{call});
 284                         $logmess .= html_escape('Updated calc to: [URL]'.$calc."[/URL]\n");
 285                 }
 286                 if ($c->req->param('cstatus')){
 287                         $dbh->do(q{UPDATE calls SET status = $1, dc = $2 WHERE call = $3}
 288                                 ,undef,$c->req->param('status'),$c->user->id,$call->{call});
 289                         $logmess .= "Changed status to: ".$c->req->param('status')."\n";
 290                 }
 291                 $log->execute($c->user->id,$call->{ftid},$logmess) if $log;
 292         }elsif($c->req->param('cmd') =~ /^Take call$/){
 293                 my $extra_vars = '';
 294                 $dbh->do(q{UPDATE calls SET dc = ? WHERE call = ?},
 295                         ,undef,$c->user->id,$call->{call});
 296                 $log->execute($c->user->id,$call->{ftid}
 297                         ,'Changed status to: [B]'.$c->req->param('cmd').'[/B]');
 298         }
 299         $dbh->commit;
 300
 301         $c->res->redirect($c->uri_for('edit',$call->{call}));
 302 }
 303
 304
 305 sub postattackerupdate : Local {
 306         my ($self, $c, $call) = @_;
 307         my $dbh = $c->model;
 308
 309         $c->forward('findCall');
 310         $call = $c->stash->{call};
 311
 312         my $log = $dbh->prepare(q{INSERT INTO forum_posts (ftid,uid,message)
 313                 VALUES($2,$1,$3)
 314                 });
 315
 316         $dbh->begin_work;
 317         if($c->req->param('cmd') eq 'Remove'){
 318                 my $query = $dbh->prepare(q{DELETE FROM incomings WHERE inc = ? AND call = ?});
 319                 my $inc = $dbh->prepare(q{SELECT pid,eta,amount FROM incomings WHERE inc = $1});
 320                 for my $param ($c->req->param()){
 321                         if ($param =~ /^change:(\d+)$/){
 322                                 my ($planet,$eta,$amount) = $dbh->selectrow_array($inc,undef,$1);
 323                                 $query->execute($1,$call->{call});
 324                                 $log->execute($c->user->id,$call->{ftid}
 325                                         ,"Deleted fleet: [B] $1 [/B] ($planet:$eta:$amount)");
 326                         }
 327                 }
 328         }elsif($c->req->param('cmd') eq 'Change'){
 329                 my $query = $dbh->prepare(q{UPDATE incomings SET shiptype = ?
 330                         WHERE inc = ? AND call = ?
 331                 });
 332                 for my $param ($c->req->param()){
 333                         if ($param =~ /^change:(\d+)$/){
 334                                 my $shiptype = html_escape($c->req->param("shiptype:$1"));
 335                                 $query->execute($shiptype,$1,$call->{call});
 336                                 $log->execute($c->user->id,$call->{ftid}
 337                                         ,"set fleet: [B] $1 [/B] to: [B] $shiptype [/B]");
 338                         }
 339                 }
 340         }
 341         $dbh->commit;
 342
 343         $c->res->redirect($c->uri_for('edit',$call->{call}));
 344 }
 345
 346 sub findCall : Private {
 347         my ( $self, $c, $call) = @_;
 348         my $dbh = $c->model;
 349
 350         my $query = $dbh->prepare(q{
 351                 SELECT call, coords(p.x,p.y,p.z), c.landing_tick, c.info, status
 352                         ,dc.username AS dc, u.defense_points,c.uid
 353                         ,p.pid, u.username AS member, u.sms,c.ftid,calc
 354                 FROM calls c
 355                 JOIN users u USING (uid)
 356                 JOIN current_planet_stats p USING (pid)
 357                 LEFT OUTER JOIN users dc ON c.dc = dc.uid
 358                 WHERE call = ?
 359                 });
 360         $call = $dbh->selectrow_hashref($query,undef,$call);
 361
 362         $c->assert_user_roles(qw/calls_edit/) unless $c->user->id == $call->{uid};
 363         $c->stash(call => $call);
 364 }
 365
 366 =head1 AUTHOR
 367
 368 Michael Andreen (harv@ruin.nu)
 369
 370 =head1 LICENSE
 371
 372 GPL 2.0, or later.
 373
 374 =cut
 375
 376 1;