lib/NDWeb/Controller/Members.pm

   1 package NDWeb::Controller::Members;
   2
   3 use strict;
   4 use warnings;
   5 use parent 'Catalyst::Controller';
   6
   7 use NDWeb::Include;
   8
   9 =head1 NAME
  10
  11 NDWeb::Controller::Members - Catalyst Controller
  12
  13 =head1 DESCRIPTION
  14
  15 Catalyst Controller.
  16
  17 =head1 METHODS
  18
  19 =cut
  20
  21
  22 =head2 index
  23
  24 =cut
  25
  26 sub index : Path : Args(0) {
  27         my ( $self, $c, $order ) = @_;
  28         my $dbh = $c->model;
  29
  30         $c->stash(error => $c->flash->{error});
  31
  32         $c->stash(comma => \&comma_value);
  33         $c->stash(u => $dbh->selectrow_hashref(q{SELECT planet,defense_points
  34                         ,attack_points,scan_points,humor_points
  35                         , (attack_points+defense_points+scan_points/20) as total_points
  36                         , sms,rank,hostmask FROM users WHERE uid = ?
  37                         },undef,$c->user->id)
  38         );
  39
  40         $c->stash(groups => $dbh->selectrow_array(q{SELECT array_accum(groupname)
  41                 FROM groups g NATURAL JOIN groupmembers gm
  42                 WHERE uid = $1
  43                         },undef,$c->user->id)
  44         );
  45
  46         $c->stash(p => $dbh->selectrow_hashref(q{SELECT id,x,y,z, ruler, planet,race,
  47                 size, size_gain, size_gain_day,
  48                 score,score_gain,score_gain_day,
  49                 value,value_gain,value_gain_day,
  50                 xp,xp_gain,xp_gain_day,
  51                 sizerank,sizerank_gain,sizerank_gain_day,
  52                 scorerank,scorerank_gain,scorerank_gain_day,
  53                 valuerank,valuerank_gain,valuerank_gain_day,
  54                 xprank,xprank_gain,xprank_gain_day
  55                 from current_planet_stats_full p
  56                         WHERE id = ?
  57                         },undef,$c->user->planet)
  58         );
  59
  60         my $calls = $dbh->prepare(q{
  61                 SELECT id,landing_tick,dc,curreta
  62                         ,array_accum(race::text) AS race
  63                         ,array_accum(amount) AS amount
  64                         ,array_accum(eta) AS eta
  65                         ,array_accum(shiptype) AS shiptype
  66                         ,array_accum(coords) AS attackers
  67                 FROM (SELECT c.id, c.landing_tick
  68                         ,dc.username AS dc, (c.landing_tick - tick()) AS curreta
  69                         ,p2.race, i.amount, i.eta, i.shiptype, p2.alliance
  70                         ,coords(p2.x,p2.y,p2.z)
  71                         FROM calls c
  72                                 LEFT OUTER JOIN incomings i ON i.call = c.id
  73                                 LEFT OUTER JOIN current_planet_stats p2 ON i.sender = p2.id
  74                                 LEFT OUTER JOIN users dc ON c.dc = dc.uid
  75                         WHERE c.member = $1 AND c.landing_tick >= tick()
  76                         GROUP BY c.id, c.landing_tick, dc.username
  77                                 ,p2.race,i.amount,i.eta,i.shiptype,p2.alliance,p2.x,p2.y,p2.z
  78                         ) c
  79                 GROUP BY id, landing_tick,dc,curreta
  80                 });
  81
  82         $calls->execute($c->user->id);
  83         $c->stash(calls => $calls->fetchall_arrayref({}) );
  84
  85         my $query = $dbh->prepare(q{SELECT f.id, coords(x,y,z), target, mission
  86                 , f.amount, tick, back
  87 FROM fleets f
  88 LEFT OUTER JOIN current_planet_stats p ON f.target = p.id
  89 WHERE NOT ingal AND f.uid = ? AND f.sender = ? AND
  90         (back >= ? OR (tick >= tick() -  24 AND name = 'Main'))
  91 GROUP BY f.id, x,y,z, mission, tick,back,f.amount,f.target
  92 ORDER BY x,y,z,mission,tick
  93                 });
  94
  95         my $ships = $dbh->prepare(q{SELECT ship,amount FROM fleet_ships
  96                 WHERe id = ? ORDER BY num
  97                 });
  98
  99         $query->execute($c->user->id,$c->user->planet,$c->stash->{TICK});
 100         my @fleets;
 101         while (my $fleet = $query->fetchrow_hashref){
 102                 my @ships;
 103                 $ships->execute($fleet->{id});
 104                 while (my $ship = $ships->fetchrow_hashref){
 105                         push @ships,$ship;
 106                 }
 107                 $fleet->{ships} = \@ships;
 108                 push @fleets,$fleet;
 109         }
 110         $c->stash(fleets => \@fleets);
 111
 112         my $announcements = $dbh->prepare(q{SELECT ft.ftid, u.username,ft.subject,
 113                 count(NULLIF(COALESCE(fp.time > ftv.time,TRUE),FALSE)) AS unread,count(fp.fpid) AS posts,
 114                 date_trunc('seconds',max(fp.time)::timestamp) as last_post,
 115                 min(fp.time)::date as posting_date, ft.sticky
 116                 FROM forum_threads ft JOIN forum_posts fp USING (ftid)
 117                         JOIN users u ON u.uid = ft.uid
 118                         LEFT OUTER JOIN (SELECT * FROM forum_thread_visits WHERE uid = $1) ftv ON ftv.ftid = ft.ftid
 119                 WHERE ft.fbid = 1
 120                 GROUP BY ft.ftid, ft.subject,ft.sticky,u.username
 121                 HAVING count(NULLIF(COALESCE(ft.sticky OR fp.time > ftv.time,TRUE),FALSE)) >= 1
 122                 ORDER BY sticky DESC,last_post DESC
 123                 });
 124         $announcements->execute($c->user->id);
 125         $c->stash(announcements => $announcements->fetchall_arrayref({}) );
 126 }
 127
 128 sub posthostupdate : Local {
 129         my ( $self, $c ) = @_;
 130         my $dbh = $c->model;
 131
 132         $dbh->do(q{UPDATE users SET hostmask = ? WHERE uid = ?
 133                 },undef, html_escape $c->req->param('hostname'), $c->user->id);
 134
 135         $c->res->redirect($c->uri_for(''));
 136 }
 137
 138 sub postsmsupdate : Local {
 139         my ( $self, $c ) = @_;
 140         my $dbh = $c->model;
 141
 142         $dbh->do(q{UPDATE users SET sms = ? WHERE uid = ?
 143                 },undef, html_escape $c->req->param('sms'), $c->user->id);
 144
 145         $c->res->redirect($c->uri_for(''));
 146 }
 147
 148 sub postfleetupdate : Local {
 149         my ( $self, $c ) = @_;
 150         my $dbh = $c->model;
 151
 152         my $fleet = $c->req->param('fleet');
 153         $fleet =~ s/,//g;
 154         my $amount = 0;
 155         my @ships;
 156         while ($fleet =~ m/((?:[A-Z][a-z]+ )*[A-Z][a-z]+)\s+(\d+)/g){
 157                 $amount += $2;
 158                 push @ships, [$1,$2];
 159         }
 160         if ($amount){
 161                 $dbh->begin_work;
 162                 eval{
 163                         my $insert = $dbh->prepare(q{INSERT INTO fleets
 164                                 (uid,sender,name,mission,tick,amount)
 165                                 VALUES (?,?,'Main','Full fleet',tick(),?) RETURNING id});
 166                         my ($id) = $dbh->selectrow_array($insert,undef,$c->user->id
 167                                 ,$c->user->planet,$amount);
 168                         $insert = $dbh->prepare(q{INSERT INTO fleet_ships
 169                                 (id,ship,amount) VALUES (?,?,?)});
 170                         for my $s (@ships){
 171                                 unshift @{$s},$id;
 172                                 $insert->execute(@{$s});
 173                         }
 174                         $dbh->commit;
 175                 };
 176                 if ($@){
 177                         if ($@ =~ m/insert or update on table "fleet_ships" violates foreign key constraint "fleet_ships_ship_fkey"\s+DETAIL:\s+Key \(ship\)=\(([^)]+)\)/){
 178                                 $c->flash( error => "'$1' is NOT a valid ship");
 179                         }else{
 180                                 $c->flash( error => $@);
 181                         }
 182                         $dbh->rollback;
 183                 }
 184         }else{
 185                 $c->flash( error => 'Fleet does not contain any ships');
 186         }
 187
 188         $c->res->redirect($c->uri_for(''));
 189 }
 190
 191 sub postfleetsupdates : Local {
 192         my ( $self, $c ) = @_;
 193         my $dbh = $c->model;
 194
 195         my $log = $dbh->prepare(q{INSERT INTO forum_posts (ftid,uid,message) VALUES(
 196                 (SELECT ftid FROM users WHERE uid = $1),$1,$2)
 197                 });
 198         $dbh->begin_work;
 199         if ($c->req->param('cmd') eq 'Recall Fleets'){
 200                 my $updatefleets = $dbh->prepare(q{UPDATE fleets
 201                         SET back = tick() + (tick() - (tick - eta))
 202                         WHERE uid = ? AND id = ? AND back > tick()+eta
 203                 });
 204
 205                 for my $param ($c->req->param()){
 206                         if ($param =~ /^change:(\d+)$/){
 207                                 $updatefleets->execute($c->user->id,$1);
 208                                 $log->execute($c->user->id,"Member recalled fleet $1");
 209                         }
 210                 }
 211         }elsif ($c->req->param('cmd') eq 'Change Fleets'){
 212                 my $updatefleets = $dbh->prepare(q{UPDATE fleets
 213                         SET back = ? WHERE uid = ? AND id = ?});
 214
 215                 for my $param ($c->req->param()){
 216                         if ($param =~ /^change:(\d+)$/){
 217                                 my $back = $c->req->param("back:$1");
 218                                 $updatefleets->execute($back,$c->user->id,$1);
 219                                 $log->execute($c->user->id,"Member set fleet $1 to be back tick: $back");
 220                         }
 221                 }
 222         }
 223         $dbh->commit;
 224
 225         $c->res->redirect($c->uri_for(''));
 226 }
 227
 228 sub ircrequest : Local {
 229         my ( $self, $c ) = @_;
 230         my $dbh = $c->model;
 231
 232         $c->stash(reply => $c->flash->{reply});
 233         $c->stash(channels => ['def','scan','members']);
 234 }
 235
 236 sub postircrequest : Local {
 237         my ( $self, $c ) = @_;
 238         my $dbh = $c->model;
 239
 240         my $query = $dbh->prepare(q{INSERT INTO irc_requests
 241                 (uid,channel,message) VALUES($1,$2,$3)
 242                 });
 243         $query->execute($c->user->id,$c->req->param('channel'),$c->req->param('message'));
 244
 245         $c->flash(reply => "Msg sent to: ".$c->req->param('channel'));
 246         $c->res->redirect($c->uri_for('ircrequest'));
 247 }
 248
 249 sub points : Local {
 250         my ( $self, $c, $order ) = @_;
 251         my $dbh = $c->model;
 252
 253         if ($order =~ /^((?:defense|attack|total|humor|scan|raid)_points)$/){
 254                 $order = "$1 DESC";
 255         }else{
 256                 $order = 'total_points DESC';
 257         }
 258
 259         my $limit = 'LIMIT 10';
 260         $limit = '' if $c->check_user_roles(qw/members_points_nolimit/);
 261
 262         my $query = $dbh->prepare(qq{SELECT username,defense_points,attack_points
 263                 ,scan_points,humor_points
 264                 ,(attack_points+defense_points+scan_points/20) as total_points
 265                 , count(NULLIF(rc.launched,FALSE)) AS raid_points
 266                 FROM users u LEFT OUTER JOIN raid_claims rc USING (uid)
 267                 WHERE uid IN (SELECT uid FROM groupmembers WHERE gid = 2)
 268                 GROUP BY username,defense_points,attack_points,scan_points,humor_points,rank
 269                 ORDER BY $order $limit});
 270         $query->execute;
 271         my @members;
 272         while (my $member = $query->fetchrow_hashref){
 273                 push @members,$member;
 274         }
 275         $c->stash(members => \@members);
 276 }
 277
 278 sub addintel : Local {
 279         my ( $self, $c, $order ) = @_;
 280
 281         $c->stash(intel => $c->flash->{intel});
 282         $c->stash(scans => $c->flash->{scans});
 283         $c->stash(intelmessage => $c->flash->{intelmessage});
 284 }
 285
 286 sub postintel : Local {
 287         my ( $self, $c, $order ) = @_;
 288
 289         $c->forward('insertintel');
 290
 291         $c->res->redirect($c->uri_for('addintel'));
 292 }
 293
 294 sub postintelmessage : Local {
 295         my ( $self, $c, $order ) = @_;
 296
 297         unless ($c->req->param('subject')){
 298                 if ($c->req->param('message') =~ /(.*\w.*)/){
 299                         $c->req->param(subject => $1);
 300                 }
 301         }
 302
 303         $c->forward('/forum/insertThread',[12]);
 304         $c->forward('/forum/insertPost',[$c->stash->{thread}]);
 305         $c->flash(intelmessage => 1);
 306
 307         $c->forward('insertintel');
 308
 309         $c->res->redirect($c->uri_for('addintel'));
 310 }
 311
 312 sub insertintel : Private {
 313         my ( $self, $c, $order ) = @_;
 314         my $dbh = $c->model;
 315
 316         $dbh->begin_work;
 317         my $findscan = $dbh->prepare(q{SELECT scan_id FROM scans
 318                 WHERE scan_id = ? AND tick >= tick() - 168 AND groupscan = ?
 319                 });
 320         my $addscan = $dbh->prepare(q{INSERT INTO scans (scan_id,tick,uid,groupscan)
 321                 VALUES (?,tick(),?,?)
 322                 });
 323         my $addpoint = $dbh->prepare(q{UPDATE users SET scan_points = scan_points + 1
 324                 WHERE uid = ?
 325                 });
 326         my @scans;
 327         my $intel = $c->req->param('message');
 328         while ($intel =~ m{http://[\w.]+/.+?scan(_id|_grp)?=(\d+)}g){
 329                 my $groupscan = (defined $1 && $1 eq '_grp') || 0;
 330                 my %scan;
 331                 $scan{id} = $2;
 332                 $scan{group} = $groupscan;
 333                 $findscan->execute($2,$groupscan);
 334                 if ($findscan->rows == 0){
 335                         if ($addscan->execute($2,$c->user->id,$groupscan)){
 336                                 $addpoint->execute($c->user->id) unless $groupscan;
 337                                 $scan{added} = 1;
 338                         }
 339                 }else{
 340                         $scan{message} = 'already exists';
 341                 }
 342                 push @scans,\%scan;
 343         }
 344         my $tick = $c->req->param('tick');
 345         unless ($tick =~ /^(\d+)$/){
 346                 $tick = $c->stash->{game}->{tick};
 347         }
 348         my $addintel = $dbh->prepare(q{INSERT INTO fleets
 349                 (name,mission,tick,target,sender,eta,amount,ingal,back,uid)
 350                 VALUES($1,$2,$3,planetid($4,$5,$6,$10),planetid($7,$8,$9,$10)
 351                         ,$11,$12,$13,$14,$15)
 352         });
 353         my @intel;
 354         while ($intel =~ m/(\d+):(\d+):(\d+)\*?\s+(\d+):(\d+):(\d+)
 355                 \*?\s+(.+)(?:Ter|Cat|Xan|Zik|Etd)?
 356                 \s+(\d+)\s+(Attack|Defend)\s+(\d+)/gx){
 357                 my $ingal = ($1 == $4 && $2 == $5) || 0;
 358                 my $lt = $tick + $10;
 359                 my $back = ($ingal ? $lt + 4 : undef);
 360                 eval {
 361                         $addintel->execute($7,$9,$lt,$1,$2,$3,$4,$5,$6,$tick,$10,$8
 362                                 ,$ingal,$back, $c->user->id);
 363                         push @intel,"Added $&";
 364                 };
 365                 if ($@){
 366                         push @intel,"Couldn't add $&: ".$dbh->errstr;
 367                 }
 368         }
 369         $dbh->commit;
 370         $c->flash(intel => \@intel);
 371         $c->flash(scans => \@scans);
 372 }
 373
 374 sub launchConfirmation : Local {
 375         my ( $self, $c ) = @_;
 376
 377         $c->stash(missions => $c->flash->{missions});
 378 }
 379
 380 sub postconfirmation : Local {
 381         my ( $self, $c ) = @_;
 382         my $dbh = $c->model;
 383
 384         eval {
 385                 my $missions = $c->req->param('mission');
 386                 my $findplanet = $dbh->prepare("SELECT planetid(?,?,?,?)");
 387                 my $findattacktarget = $dbh->prepare(q{SELECT c.target,c.wave,c.launched
 388                         FROM  raid_claims c
 389                                 JOIN raid_targets t ON c.target = t.id
 390                                 JOIN raids r ON t.raid = r.id
 391                         WHERE c.uid = ? AND r.tick+c.wave-1 = ? AND t.planet = ?
 392                                 AND r.open AND not r.removed
 393                         });
 394                 my $finddefensetarget = $dbh->prepare(q{SELECT c.id FROM calls c
 395                                 JOIN users u ON c.member = u.uid
 396                         WHERE u.planet = $1 AND c.landing_tick = $2
 397                 });
 398                 my $informDefChannel = $dbh->prepare(q{INSERT INTO defense_missions
 399                         (fleet,call) VALUES (?,?)
 400                         });
 401                 my $addattackpoint = $dbh->prepare(q{UPDATE users SET
 402                         attack_points = attack_points + 1 WHERE uid = ?
 403                         });
 404                 my $launchedtarget = $dbh->prepare(q{UPDATE raid_claims SET launched = True
 405                         WHERE uid = ? AND target = ? AND wave = ?
 406                         });
 407                 my $addfleet = $dbh->prepare(q{INSERT INTO fleets
 408                         (uid,name,mission,sender,target,tick,eta,back,amount)
 409                         VALUES ($1,$2,$3,(SELECT planet FROM users WHERE uid = $1),$4,$5,$6,$7,$8)
 410                         RETURNING id
 411                         });
 412                 my $addships = $dbh->prepare(q{INSERT INTO fleet_ships (id,ship,amount)
 413                         VALUES (?,?,?)
 414                         });
 415                 my $log = $dbh->prepare(q{INSERT INTO forum_posts (ftid,uid,message) VALUES(
 416                         (SELECT ftid FROM users WHERE uid = $1),$1,$2)
 417                         });
 418                 my @missions;
 419                 $dbh->begin_work;
 420                 while ($missions =~ m/([^\n]+)\s+(\d+):(\d+):(\d+)\s+(\d+):(\d+):(\d+)
 421                         \s+\((?:(\d+)\+)?(\d+)\).*?(?:\d+hrs\s+)?\d+mins?\s+
 422                         (Attack|Defend|Return|Fake\ Attack|Fake\ Defend)
 423                         (.*?)
 424                         (?:Launching\ in\ tick\ (\d+),\ arrival\ in\ tick\ (\d+)
 425                                 |ETA:\ \d+,\ Return\ ETA:\ (\d+)
 426                                 |Return\ ETA:\ (\d+)
 427                                 )/sgx){
 428                         next if $10 eq 'Return';
 429                         my %mission;
 430                         my $name = $1;
 431                         my $tick = $c->stash->{TICK}+$9;
 432                         $tick += $8 if defined $8;
 433                         my $eta = $9;
 434                         my $mission = $10;
 435                         my $x = $5;
 436                         my $y = $6;
 437                         my $z = $7;
 438                         my $back = $tick + $eta - 1;
 439                         if ($13){
 440                                 $tick = $13;
 441                         }elsif ($14){
 442                                 $back += $14;
 443                         }
 444                         $mission{tick} = $tick;
 445                         $mission{mission} = $mission;
 446                         $mission{target} = "$x:$y:$z";
 447                         $mission{back} = $back;
 448
 449                         my ($planet_id) = $dbh->selectrow_array($findplanet,undef,$x,$y,$z,$c->stash->{TICK});
 450
 451                         my $findtarget = $finddefensetarget;
 452                         if ($mission eq 'Attack'){
 453                                 $findtarget = $findattacktarget;
 454                                 $findtarget->execute($c->user->id,$tick,$planet_id);
 455                         }elsif ($mission eq 'Defend'){
 456                                 $findtarget = $finddefensetarget;
 457                                 $findtarget->execute($planet_id,$tick);
 458                         }
 459
 460                         my $ships = $11;
 461                         my @ships;
 462                         my $amount = 0;
 463                         while ($ships =~ m/((?:\w+ )*\w+)\s+\w+\s+(?:(?:\w+|-)\s+){3}(?:Steal|Normal|Emp|Normal\s+Cloaked|Pod|Structure Killer)\s+(\d+)/g){
 464                                 $amount += $2;
 465                                 push @ships,{ship => $1, amount => $2};
 466                         }
 467                         $mission{ships} = \@ships;
 468
 469                         if ($amount == 0){
 470                                 warn "No ships in: $ships";
 471                                 next;
 472                         }
 473                         my $fleet = $dbh->selectrow_array($addfleet,undef,$c->user->id,$name,$mission
 474                                 ,$planet_id,$tick,$eta,$back,$amount);
 475                         $mission{fleet} = $fleet;
 476                         for my $ship (@ships){
 477                                 $addships->execute($fleet,$ship->{ship},$ship->{amount});
 478                         }
 479
 480                         if ($findtarget->rows == 0){
 481                                 $mission{warning} = 'No matching target!';
 482                         }elsif ($mission eq 'Attack'){
 483                                 my $claim = $findtarget->fetchrow_hashref;
 484                                 if ($claim->{launched}){
 485                                         $mission{warning} = "Already launched on this target:$claim->{target},$claim->{wave},$claim->{launched}";
 486                                 }else{
 487                                         $addattackpoint->execute($c->user->id);
 488                                         $launchedtarget->execute($c->user->id,$claim->{target},$claim->{wave});
 489                                         $mission{warning} = "OK:$claim->{target},$claim->{wave},$claim->{launched}";
 490                                         $log->execute($c->user->id,"Gave attack point for confirmation on $mission mission to $x:$y:$z, landing tick $tick");
 491                                 }
 492                         }elsif ($mission eq 'Defend'){
 493                                 my $call = $findtarget->fetchrow_hashref;
 494                                 $informDefChannel->execute($fleet,$call->{id});
 495                         }
 496
 497                         $log->execute($c->user->id,"Pasted confirmation for $mission mission to $x:$y:$z, landing tick $tick");
 498                         push @missions,\%mission;
 499                 }
 500                 $dbh->commit;
 501                 $c->flash(missions => \@missions);
 502         };
 503         if ($@){
 504                 $dbh->rollback;
 505                 die $@;
 506         }
 507
 508         $c->res->redirect($c->uri_for('launchConfirmation'));
 509 }
 510
 511 =head1 AUTHOR
 512
 513 Michael Andreen (harv@ruin.nu)
 514
 515 =head1 LICENSE
 516
 517 GPL 2.0, or later.
 518
 519 =cut
 520
 521 1;