lib/NDWeb/Controller/Members.pm

   1 package NDWeb::Controller::Members;
   2
   3 use strict;
   4 use warnings;
   5 use parent 'Catalyst::Controller';
   6
   7 use NDWeb::Include;
   8
   9 =head1 NAME
  10
  11 NDWeb::Controller::Members - Catalyst Controller
  12
  13 =head1 DESCRIPTION
  14
  15 Catalyst Controller.
  16
  17 =head1 METHODS
  18
  19 =cut
  20
  21
  22 =head2 index
  23
  24 =cut
  25
  26 sub index : Path : Args(0) {
  27         my ( $self, $c, $order ) = @_;
  28         my $dbh = $c->model;
  29
  30         $c->stash(error => $c->flash->{error});
  31
  32         $c->stash(comma => \&comma_value);
  33         $c->stash(u => $dbh->selectrow_hashref(q{SELECT planet,defense_points
  34                         ,attack_points,scan_points,humor_points
  35                         , (attack_points+defense_points+scan_points/20)::NUMERIC(5,1) as total_points
  36                         , sms,rank,hostmask FROM users WHERE uid = ?
  37                         },undef,$c->user->id)
  38         );
  39
  40         $c->stash(groups => $dbh->selectrow_array(q{SELECT array_accum(groupname)
  41                 FROM groups g NATURAL JOIN groupmembers gm
  42                 WHERE uid = $1
  43                         },undef,$c->user->id)
  44         );
  45
  46         $c->stash(p => $dbh->selectrow_hashref(q{SELECT id,x,y,z, ruler, planet,race,
  47                 size, size_gain, size_gain_day,
  48                 score,score_gain,score_gain_day,
  49                 value,value_gain,value_gain_day,
  50                 xp,xp_gain,xp_gain_day,
  51                 sizerank,sizerank_gain,sizerank_gain_day,
  52                 scorerank,scorerank_gain,scorerank_gain_day,
  53                 valuerank,valuerank_gain,valuerank_gain_day,
  54                 xprank,xprank_gain,xprank_gain_day
  55                 from current_planet_stats_full p
  56                         WHERE id = ?
  57                         },undef,$c->user->planet)
  58         );
  59
  60         my $calls = $dbh->prepare(q{
  61                 SELECT id,landing_tick,dc,curreta
  62                         ,array_accum(race::text) AS race
  63                         ,array_accum(amount) AS amount
  64                         ,array_accum(eta) AS eta
  65                         ,array_accum(shiptype) AS shiptype
  66                         ,array_accum(coords) AS attackers
  67                 FROM (SELECT c.id, c.landing_tick
  68                         ,dc.username AS dc, (c.landing_tick - tick()) AS curreta
  69                         ,p2.race, i.amount, i.eta, i.shiptype, p2.alliance
  70                         ,coords(p2.x,p2.y,p2.z)
  71                         FROM calls c
  72                                 LEFT OUTER JOIN incomings i ON i.call = c.id
  73                                 LEFT OUTER JOIN current_planet_stats p2 ON i.sender = p2.id
  74                                 LEFT OUTER JOIN users dc ON c.dc = dc.uid
  75                         WHERE c.member = $1 AND c.landing_tick >= tick()
  76                         GROUP BY c.id, c.landing_tick, dc.username
  77                                 ,p2.race,i.amount,i.eta,i.shiptype,p2.alliance,p2.x,p2.y,p2.z
  78                         ) c
  79                 GROUP BY id, landing_tick,dc,curreta
  80                 });
  81
  82         $calls->execute($c->user->id);
  83         $c->stash(calls => $calls->fetchall_arrayref({}) );
  84
  85         my $query = $dbh->prepare(q{SELECT f.id, coords(x,y,z), target, mission
  86                 , f.amount, tick, back
  87 FROM fleets f
  88 LEFT OUTER JOIN current_planet_stats p ON f.target = p.id
  89 WHERE NOT ingal AND f.uid = ? AND f.sender = ? AND
  90         (back >= ? OR (tick >= tick() -  24 AND name = 'Main'))
  91 GROUP BY f.id, x,y,z, mission, tick,back,f.amount,f.target
  92 ORDER BY x,y,z,mission,tick
  93                 });
  94
  95         my $ships = $dbh->prepare(q{SELECT ship,amount FROM fleet_ships
  96                 WHERe id = ? ORDER BY num
  97                 });
  98
  99         $query->execute($c->user->id,$c->user->planet,$c->stash->{TICK});
 100         my @fleets;
 101         while (my $fleet = $query->fetchrow_hashref){
 102                 my @ships;
 103                 $ships->execute($fleet->{id});
 104                 while (my $ship = $ships->fetchrow_hashref){
 105                         push @ships,$ship;
 106                 }
 107                 $fleet->{ships} = \@ships;
 108                 push @fleets,$fleet;
 109         }
 110         $c->stash(fleets => \@fleets);
 111
 112         my $announcements = $dbh->prepare(q{SELECT ft.ftid, u.username,ft.subject,
 113                 count(NULLIF(COALESCE(fp.time > ftv.time,TRUE),FALSE)) AS unread,count(fp.fpid) AS posts,
 114                 date_trunc('seconds',max(fp.time)::timestamp) as last_post,
 115                 min(fp.time)::date as posting_date, ft.sticky
 116                 FROM forum_threads ft JOIN forum_posts fp USING (ftid)
 117                         JOIN users u ON u.uid = ft.uid
 118                         LEFT OUTER JOIN (SELECT * FROM forum_thread_visits WHERE uid = $1) ftv ON ftv.ftid = ft.ftid
 119                 WHERE ft.fbid = 1
 120                 GROUP BY ft.ftid, ft.subject,ft.sticky,u.username
 121                 HAVING count(NULLIF(COALESCE(ft.sticky OR fp.time > ftv.time,TRUE),FALSE)) >= 1
 122                 ORDER BY sticky DESC,last_post DESC
 123                 });
 124         $announcements->execute($c->user->id);
 125         $c->stash(announcements => $announcements->fetchall_arrayref({}) );
 126 }
 127
 128 sub posthostupdate : Local {
 129         my ( $self, $c ) = @_;
 130         my $dbh = $c->model;
 131
 132         $dbh->do(q{UPDATE users SET hostmask = ? WHERE uid = ?
 133                 },undef, html_escape $c->req->param('hostname'), $c->user->id);
 134
 135         $c->res->redirect($c->uri_for(''));
 136 }
 137
 138 sub postsmsupdate : Local {
 139         my ( $self, $c ) = @_;
 140         my $dbh = $c->model;
 141
 142         $dbh->do(q{UPDATE users SET sms = ? WHERE uid = ?
 143                 },undef, html_escape $c->req->param('sms'), $c->user->id);
 144
 145         $c->res->redirect($c->uri_for(''));
 146 }
 147
 148 sub postowncoords : Local {
 149         my ( $self, $c ) = @_;
 150         my $dbh = $c->model;
 151
 152         if ($c->user->planet){
 153                 $c->flash(error => 'You already have a planet set.'
 154                         .' Contact a HC if they need to be changed');
 155         }elsif ($c->req->param('planet') =~ m/(\d+)\D+(\d+)\D+(\d+)/){
 156                 my $planet = $dbh->selectrow_array(q{SELECT planetid($1,$2,$3,TICK())
 157                         },undef,$1,$2,$3);
 158
 159                 if ($planet){
 160                         $dbh->do(q{UPDATE users SET planet = ? WHERE uid = ?
 161                                 },undef, $planet , $c->user->id);
 162                 }else{
 163                         $c->flash(error => "No planet at coords: $1:$2:$3");
 164                 }
 165         }else{
 166                 $c->flash(error => $c->req->param('planet') . " are not valid coords.");
 167         }
 168
 169         $c->res->redirect($c->uri_for(''));
 170 }
 171
 172 sub postfleetupdate : Local {
 173         my ( $self, $c ) = @_;
 174         my $dbh = $c->model;
 175
 176         my $fleet = $c->req->param('fleet');
 177         $fleet =~ s/,//g;
 178         my $amount = 0;
 179         my @ships;
 180         while ($fleet =~ m/((?:[A-Z][a-z]+ )*[A-Z][a-z]+)\s+(\d+)/g){
 181                 $amount += $2;
 182                 push @ships, [$1,$2];
 183         }
 184         if ($amount){
 185                 $dbh->begin_work;
 186                 eval{
 187                         my $insert = $dbh->prepare(q{INSERT INTO fleets
 188                                 (uid,sender,name,mission,tick,amount)
 189                                 VALUES (?,?,'Main','Full fleet',tick(),?) RETURNING id});
 190                         my ($id) = $dbh->selectrow_array($insert,undef,$c->user->id
 191                                 ,$c->user->planet,$amount);
 192                         $insert = $dbh->prepare(q{INSERT INTO fleet_ships
 193                                 (id,ship,amount) VALUES (?,?,?)});
 194                         for my $s (@ships){
 195                                 unshift @{$s},$id;
 196                                 $insert->execute(@{$s});
 197                         }
 198                         $dbh->commit;
 199                 };
 200                 if ($@){
 201                         if ($@ =~ m/insert or update on table "fleet_ships" violates foreign key constraint "fleet_ships_ship_fkey"\s+DETAIL:\s+Key \(ship\)=\(([^)]+)\)/){
 202                                 $c->flash( error => "'$1' is NOT a valid ship");
 203                         }else{
 204                                 $c->flash( error => $@);
 205                         }
 206                         $dbh->rollback;
 207                 }
 208         }else{
 209                 $c->flash( error => 'Fleet does not contain any ships');
 210         }
 211
 212         $c->res->redirect($c->uri_for(''));
 213 }
 214
 215 sub postfleetsupdates : Local {
 216         my ( $self, $c ) = @_;
 217         my $dbh = $c->model;
 218
 219         my $log = $dbh->prepare(q{INSERT INTO forum_posts (ftid,uid,message) VALUES(
 220                 (SELECT ftid FROM users WHERE uid = $1),$1,$2)
 221                 });
 222         $dbh->begin_work;
 223         if ($c->req->param('cmd') eq 'Recall Fleets'){
 224                 my $updatefleets = $dbh->prepare(q{UPDATE fleets
 225                         SET back = tick() + (tick() - (tick - eta))
 226                         WHERE uid = ? AND id = ? AND back > tick()+eta
 227                 });
 228
 229                 for my $param ($c->req->param()){
 230                         if ($param =~ /^change:(\d+)$/){
 231                                 $updatefleets->execute($c->user->id,$1);
 232                                 $log->execute($c->user->id,"Member recalled fleet $1");
 233                         }
 234                 }
 235         }elsif ($c->req->param('cmd') eq 'Change Fleets'){
 236                 my $updatefleets = $dbh->prepare(q{UPDATE fleets
 237                         SET back = ? WHERE uid = ? AND id = ?});
 238
 239                 for my $param ($c->req->param()){
 240                         if ($param =~ /^change:(\d+)$/){
 241                                 my $back = $c->req->param("back:$1");
 242                                 $updatefleets->execute($back,$c->user->id,$1);
 243                                 $log->execute($c->user->id,"Member set fleet $1 to be back tick: $back");
 244                         }
 245                 }
 246         }
 247         $dbh->commit;
 248
 249         $c->res->redirect($c->uri_for(''));
 250 }
 251
 252 sub ircrequest : Local {
 253         my ( $self, $c ) = @_;
 254         my $dbh = $c->model;
 255
 256         $c->stash(reply => $c->flash->{reply});
 257         $c->stash(channels => ['def','scan','members']);
 258 }
 259
 260 sub postircrequest : Local {
 261         my ( $self, $c ) = @_;
 262         my $dbh = $c->model;
 263
 264         my $query = $dbh->prepare(q{INSERT INTO irc_requests
 265                 (uid,channel,message) VALUES($1,$2,$3)
 266                 });
 267         $query->execute($c->user->id,$c->req->param('channel'),$c->req->param('message'));
 268         system 'killall','-USR1', 'irssi';
 269
 270         $c->flash(reply => "Msg sent to: ".$c->req->param('channel'));
 271         $c->res->redirect($c->uri_for('ircrequest'));
 272 }
 273
 274 sub points : Local {
 275         my ( $self, $c, $order ) = @_;
 276         my $dbh = $c->model;
 277
 278         if ($order && $order =~ /^((?:defense|attack|total|humor|scan|raid)_points)$/){
 279                 $order = "$1 DESC";
 280         }else{
 281                 $order = 'total_points DESC';
 282         }
 283
 284         my $limit = 'LIMIT 10';
 285         $limit = '' if $c->check_user_roles(qw/members_points_nolimit/);
 286
 287         my $query = $dbh->prepare(qq{SELECT username,defense_points,attack_points
 288                 ,scan_points,humor_points
 289                 ,(attack_points+defense_points+scan_points/20)::NUMERIC(4,0) as total_points
 290                 , count(NULLIF(rc.launched,FALSE)) AS raid_points
 291                 FROM users u LEFT OUTER JOIN raid_claims rc USING (uid)
 292                 WHERE uid IN (SELECT uid FROM groupmembers WHERE gid = 2)
 293                 GROUP BY username,defense_points,attack_points,scan_points,humor_points,rank
 294                 ORDER BY $order $limit});
 295         $query->execute;
 296         my @members;
 297         while (my $member = $query->fetchrow_hashref){
 298                 push @members,$member;
 299         }
 300         $c->stash(members => \@members);
 301 }
 302
 303 sub addintel : Local {
 304         my ( $self, $c, $order ) = @_;
 305
 306         $c->stash(intel => $c->flash->{intel});
 307         $c->stash(scans => $c->flash->{scans});
 308         $c->stash(intelmessage => $c->flash->{intelmessage});
 309 }
 310
 311 sub postintel : Local {
 312         my ( $self, $c, $order ) = @_;
 313
 314         $c->forward('insertintel');
 315
 316         $c->res->redirect($c->uri_for('addintel'));
 317 }
 318
 319 sub postintelmessage : Local {
 320         my ( $self, $c, $order ) = @_;
 321
 322         unless ($c->req->param('subject')){
 323                 if ($c->req->param('message') =~ /(.*\w.*)/){
 324                         $c->req->param(subject => $1);
 325                 }
 326         }
 327
 328         $c->forward('/forum/insertThread',[12]);
 329         $c->forward('/forum/insertPost',[$c->stash->{thread}]);
 330         $c->flash(intelmessage => 1);
 331
 332         $c->forward('insertintel');
 333
 334         $c->res->redirect($c->uri_for('addintel'));
 335 }
 336
 337 sub insertintel : Private {
 338         my ( $self, $c, $order ) = @_;
 339         my $dbh = $c->model;
 340
 341         $dbh->begin_work;
 342         my $findscan = $dbh->prepare(q{SELECT scan_id FROM scans
 343                 WHERE scan_id = ? AND tick >= tick() - 168 AND groupscan = ?
 344                 });
 345         my $addscan = $dbh->prepare(q{INSERT INTO scans (scan_id,tick,uid,groupscan)
 346                 VALUES (?,tick(),?,?)
 347                 });
 348         my $addpoint = $dbh->prepare(q{UPDATE users SET scan_points = scan_points + 1
 349                 WHERE uid = ?
 350                 });
 351         my @scans;
 352         my $intel = $c->req->param('message');
 353         while ($intel =~ m{http://[\w.]+/.+?scan(_id|_grp)?=(\d+)}g){
 354                 my $groupscan = (defined $1 && $1 eq '_grp') || 0;
 355                 my %scan;
 356                 $scan{id} = $2;
 357                 $scan{group} = $groupscan;
 358                 $findscan->execute($2,$groupscan);
 359                 if ($findscan->rows == 0){
 360                         if ($addscan->execute($2,$c->user->id,$groupscan)){
 361                                 $addpoint->execute($c->user->id) unless $groupscan;
 362                                 $scan{added} = 1;
 363                         }
 364                 }else{
 365                         $scan{message} = 'already exists';
 366                 }
 367                 push @scans,\%scan;
 368         }
 369         my $tick = $c->req->param('tick');
 370         unless ($tick =~ /^(\d+)$/){
 371                 $tick = $c->stash->{game}->{tick};
 372         }
 373         my $addintel = $dbh->prepare(q{INSERT INTO fleets
 374                 (name,mission,tick,target,sender,eta,amount,ingal,back,uid)
 375                 VALUES($1,$2,$3,planetid($4,$5,$6,$10),planetid($7,$8,$9,$10)
 376                         ,$11,$12,$13,$14,$15)
 377         });
 378         my @intel;
 379         while ($intel =~ m/(\d+):(\d+):(\d+)\*?\s+(\d+):(\d+):(\d+)
 380                 \*?\s+(.+)(?:Ter|Cat|Xan|Zik|Etd)?
 381                 \s+(\d+)\s+(Attack|Defend)\s+(\d+)/gx){
 382                 my $ingal = ($1 == $4 && $2 == $5) || 0;
 383                 my $lt = $tick + $10;
 384                 my $back = ($ingal ? $lt + 4 : undef);
 385                 eval {
 386                         $addintel->execute($7,$9,$lt,$1,$2,$3,$4,$5,$6,$tick,$10,$8
 387                                 ,$ingal,$back, $c->user->id);
 388                         push @intel,"Added $&";
 389                 };
 390                 if ($@){
 391                         push @intel,"Couldn't add $&: ".$dbh->errstr;
 392                 }
 393         }
 394         $dbh->commit;
 395         $c->flash(intel => \@intel);
 396         $c->flash(scans => \@scans);
 397 }
 398
 399 sub launchConfirmation : Local {
 400         my ( $self, $c ) = @_;
 401
 402         $c->stash(missions => $c->flash->{missions});
 403 }
 404
 405 sub postconfirmation : Local {
 406         my ( $self, $c ) = @_;
 407         my $dbh = $c->model;
 408
 409         eval {
 410                 my $missions = $c->req->param('mission');
 411                 my $findplanet = $dbh->prepare("SELECT planetid(?,?,?,?)");
 412                 my $findattacktarget = $dbh->prepare(q{SELECT c.target,c.wave,c.launched
 413                         FROM  raid_claims c
 414                                 JOIN raid_targets t ON c.target = t.id
 415                                 JOIN raids r ON t.raid = r.id
 416                         WHERE c.uid = ? AND r.tick+c.wave-1 = ? AND t.planet = ?
 417                                 AND r.open AND not r.removed
 418                         });
 419                 my $finddefensetarget = $dbh->prepare(q{SELECT c.id FROM calls c
 420                                 JOIN users u ON c.member = u.uid
 421                         WHERE u.planet = $1 AND c.landing_tick = $2
 422                 });
 423                 my $informDefChannel = $dbh->prepare(q{INSERT INTO defense_missions
 424                         (fleet,call) VALUES (?,?)
 425                         });
 426                 my $addattackpoint = $dbh->prepare(q{UPDATE users SET
 427                         attack_points = attack_points + 1 WHERE uid = ?
 428                         });
 429                 my $launchedtarget = $dbh->prepare(q{UPDATE raid_claims SET launched = True
 430                         WHERE uid = ? AND target = ? AND wave = ?
 431                         });
 432                 my $addfleet = $dbh->prepare(q{INSERT INTO fleets
 433                         (uid,name,mission,sender,target,tick,eta,back,amount)
 434                         VALUES ($1,$2,$3,(SELECT planet FROM users WHERE uid = $1),$4,$5,$6,$7,$8)
 435                         RETURNING id
 436                         });
 437                 my $addships = $dbh->prepare(q{INSERT INTO fleet_ships (id,ship,amount)
 438                         VALUES (?,?,?)
 439                         });
 440                 my $log = $dbh->prepare(q{INSERT INTO forum_posts (ftid,uid,message) VALUES(
 441                         (SELECT ftid FROM users WHERE uid = $1),$1,$2)
 442                         });
 443                 my @missions;
 444                 $dbh->begin_work;
 445                 while ($missions && $missions =~ m/([^\n]+)\s+(\d+):(\d+):(\d+)\s+(\d+):(\d+):(\d+)
 446                         \s+\((?:(\d+)\+)?(\d+)\).*?(?:\d+hrs\s+)?\d+mins?\s+
 447                         (Attack|Defend|Return|Fake\ Attack|Fake\ Defend)
 448                         (.*?)
 449                         (?:Launching\ in\ tick\ (\d+),\ arrival\ in\ tick\ (\d+)
 450                                 |ETA:\ \d+,\ Return\ ETA:\ (\d+)
 451                                 |Return\ ETA:\ (\d+)
 452                                 )/sgx){
 453                         next if $10 eq 'Return';
 454                         my %mission;
 455                         my $name = $1;
 456                         my $tick = $c->stash->{TICK}+$9;
 457                         $tick += $8 if defined $8;
 458                         my $eta = $9;
 459                         my $mission = $10;
 460                         my $x = $5;
 461                         my $y = $6;
 462                         my $z = $7;
 463                         my $back = $tick + $eta - 1;
 464                         if ($13){
 465                                 $tick = $13;
 466                         }elsif ($14){
 467                                 $back += $14;
 468                         }
 469                         $mission{tick} = $tick;
 470                         $mission{mission} = $mission;
 471                         $mission{target} = "$x:$y:$z";
 472                         $mission{back} = $back;
 473
 474                         my ($planet_id) = $dbh->selectrow_array($findplanet,undef,$x,$y,$z,$c->stash->{TICK});
 475
 476                         my $findtarget = $finddefensetarget;
 477                         if ($mission eq 'Attack'){
 478                                 $findtarget = $findattacktarget;
 479                                 $findtarget->execute($c->user->id,$tick,$planet_id);
 480                         }elsif ($mission eq 'Defend'){
 481                                 $findtarget = $finddefensetarget;
 482                                 $findtarget->execute($planet_id,$tick);
 483                         }
 484
 485                         my $ships = $11;
 486                         my @ships;
 487                         my $amount = 0;
 488                         while ($ships =~ m/((?:\w+ )*\w+)\s+\w+\s+(?:(?:\w+|-)\s+){3}(?:Steal|Normal|Emp|Normal\s+Cloaked|Pod|Structure Killer)\s+(\d+)/g){
 489                                 $amount += $2;
 490                                 push @ships,{ship => $1, amount => $2};
 491                         }
 492                         $mission{ships} = \@ships;
 493
 494                         if ($amount == 0){
 495                                 warn "No ships in: $ships";
 496                                 next;
 497                         }
 498                         my $fleet = $dbh->selectrow_array($addfleet,undef,$c->user->id,$name,$mission
 499                                 ,$planet_id,$tick,$eta,$back,$amount);
 500                         $mission{fleet} = $fleet;
 501                         for my $ship (@ships){
 502                                 $addships->execute($fleet,$ship->{ship},$ship->{amount});
 503                         }
 504
 505                         if ($findtarget->rows == 0){
 506                                 $mission{warning} = 'No matching target!';
 507                         }elsif ($mission eq 'Attack'){
 508                                 my $claim = $findtarget->fetchrow_hashref;
 509                                 if ($claim->{launched}){
 510                                         $mission{warning} = "Already launched on this target:$claim->{target},$claim->{wave},$claim->{launched}";
 511                                 }else{
 512                                         $addattackpoint->execute($c->user->id);
 513                                         $launchedtarget->execute($c->user->id,$claim->{target},$claim->{wave});
 514                                         $mission{warning} = "OK:$claim->{target},$claim->{wave},$claim->{launched}";
 515                                         $log->execute($c->user->id,"Gave attack point for confirmation on $mission mission to $x:$y:$z, landing tick $tick");
 516                                 }
 517                         }elsif ($mission eq 'Defend'){
 518                                 my $call = $findtarget->fetchrow_hashref;
 519                                 $informDefChannel->execute($fleet,$call->{id});
 520                         }
 521
 522                         $log->execute($c->user->id,"Pasted confirmation for $mission mission to $x:$y:$z, landing tick $tick");
 523                         push @missions,\%mission;
 524                 }
 525                 $dbh->commit;
 526                 $c->flash(missions => \@missions);
 527         };
 528         if ($@){
 529                 $dbh->rollback;
 530                 die $@;
 531         }
 532
 533         $c->res->redirect($c->uri_for('launchConfirmation'));
 534 }
 535
 536 =head1 AUTHOR
 537
 538 Michael Andreen (harv@ruin.nu)
 539
 540 =head1 LICENSE
 541
 542 GPL 2.0, or later.
 543
 544 =cut
 545
 546 1;