scripts/scans.pl

   1 #!/usr/bin/perl
   2 #**************************************************************************
   3 #   Copyright (C) 2006,2007 by Michael Andreen <harvATruinDOTnu>          *
   4 #                                                                         *
   5 #   This program is free software; you can redistribute it and/or modify  *
   6 #   it under the terms of the GNU General Public License as published by  *
   7 #   the Free Software Foundation; either version 2 of the License, or     *
   8 #   (at your option) any later version.                                   *
   9 #                                                                         *
  10 #   This program is distributed in the hope that it will be useful,       *
  11 #   but WITHOUT ANY WARRANTY; without even the implied warranty of        *
  12 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the         *
  13 #   GNU General Public License for more details.                          *
  14 #                                                                         *
  15 #   You should have received a copy of the GNU General Public License     *
  16 #   along with this program; if not, write to the                         *
  17 #   Free Software Foundation, Inc.,                                       *
  18 #   51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.         *
  19 #**************************************************************************/
  20
  21
  22 use strict;
  23 use warnings;
  24 no warnings 'exiting';
  25 use local::lib;
  26 use CGI;
  27 use DBI;
  28 use DBD::Pg qw(:pg_types);
  29 use LWP::Simple;
  30
  31 use FindBin;
  32 use lib "$FindBin::Bin/../lib";
  33
  34 use ND::DB;
  35
  36 our $dbh = ND::DB::DB();
  37
  38 #$dbh->trace("1","/tmp/scanstest");
  39
  40 #my $test = $dbh->prepare(q{INSERT INTO scans (tick,scan_id) VALUES(1,3) RETURNING id});
  41 #print ;
  42 $dbh->do(q{SET CLIENT_ENCODING TO 'LATIN1';});
  43
  44 my $scangroups = $dbh->prepare(q{SELECT id,scan_id,tick,uid FROM scans
  45         WHERE groupscan AND NOT parsed FOR UPDATE
  46 });
  47 my $oldscan = $dbh->prepare(q{SELECT scan_id FROM scans WHERE scan_id = LOWER(?) AND tick >= tick() - 168});
  48 my $addScan = $dbh->prepare(q{INSERT INTO scans (scan_id,tick,uid) VALUES (LOWER(?),?,?)});
  49 my $parsedscan = $dbh->prepare(q{UPDATE scans SET tick = ?, type = ?, pid = ?, parsed = TRUE WHERE id = ?});
  50 my $addpoints = $dbh->prepare(q{UPDATE users SET scan_points = scan_points + ? WHERE uid = ? });
  51 my $delscan = $dbh->prepare(q{DELETE FROM scans WHERE id = ?});
  52
  53 $scangroups->execute or die $dbh->errstr;
  54
  55 while (my $group = $scangroups->fetchrow_hashref){
  56         $dbh->begin_work;
  57         my $file = get("http://game.planetarion.com/showscan.pl?scan_grp=$group->{scan_id}");
  58
  59         if ($file){
  60                 my $points = 0;
  61                 while ($file =~ m/showscan.pl\?scan_id=(\w+)/g){
  62                         unless ($dbh->selectrow_array($oldscan,undef,$1)){
  63                                 $addScan->execute($1,$group->{tick},$group->{uid});
  64                                 ++$points;
  65                         }
  66                 }
  67                 $addpoints->execute($points,$group->{uid});
  68                 $parsedscan->execute($group->{tick},'GROUP',undef,$group->{id});
  69         }
  70         $dbh->commit;
  71 }
  72
  73 my $newscans = $dbh->prepare(q{SELECT id,scan_id,tick,uid FROM scans
  74         WHERE NOT groupscan AND NOT parsed FOR UPDATE
  75 });
  76 my $findplanet = $dbh->prepare(q{SELECT planetid(?,?,?,?)});
  77 my $findoldplanet = $dbh->prepare(q{SELECT pid FROM planet_stats WHERE x = $1 AND y = $2 AND z = $3 AND tick <= $4 ORDER BY tick DESC LIMIT 1});
  78 my $findcoords = $dbh->prepare(q{SELECT * FROM planetcoords(?,?)});
  79 my $addfleet = $dbh->prepare(q{INSERT INTO fleets (name,mission,pid,tick,amount) VALUES(?,?,?,?,?) RETURNING fid});
  80 my $fleetscan = $dbh->prepare(q{INSERT INTO fleet_scans (fid,id) VALUES(?,?)});
  81 my $addintel = $dbh->prepare(q{INSERT INTO intel (name,mission,sender,target,tick,eta,back,amount,ingal,uid)
  82         VALUES(?,?,?,?,?,?,?,?,?,-1) RETURNING id});
  83 my $intelscan = $dbh->prepare(q{INSERT INTO intel_scans (intel,id) VALUES(?,?)});
  84 my $addships = $dbh->prepare(q{INSERT INTO fleet_ships (fid,ship,amount) VALUES(?,?,?)});
  85 my $addplanetscan = $dbh->prepare(q{INSERT INTO planet_scans
  86         (id,tick,pid,metal_roids,metal,crystal_roids,crystal,eonium_roids,eonium
  87                 ,agents,guards,light,medium,heavy,hidden)
  88         VALUES(?,?,?,?,?,?,?,?,?,?,?,?,?,?,?)});
  89
  90 sub parse_planet {
  91         my ($scan,$file) = @_;
  92
  93         my @values = ($scan->{id},$scan->{tick},$scan->{pid});
  94         $file =~ s/(\d),(\d)/$1$2/g;
  95
  96         while($file =~ m{"center">(Metal|Crystal|Eonium)</td>\D+(\d+)\D+([\d,]+)}g){
  97                 push @values,$2,$3;
  98         }
  99         if($file =~ m{Security\ Guards .+? "center">(\d+)</td>
 100                         .+? "center">(\d+)</td>}sx){
 101                 push @values,$1,$2;
 102         }
 103         if($file =~ m{<td class="center">([A-Z][a-z]+)</td><td class="center">([A-Z][a-z]+)</td><td class="center">([A-Z][a-z]+)</td>}){
 104                 push @values,$1,$2,$3;
 105         }
 106         if($file =~ m{<span class="superhighlight">([\d,]+)</span>}){
 107                 push @values,$1;
 108         }
 109         $addplanetscan->execute(@values);
 110 }
 111
 112 sub parse_incoming {
 113         my ($scan,$file) = @_;
 114
 115         while($file =~ m{class="left">Fleet:\s(.*?)</td><td\sclass="right">
 116                         Mission:\s(\w+)</td></tr>(.*?)Total\sShips:\s(\d+)}sxg){
 117                 my $id = addfleet($1,$2,$3,$scan->{pid},$scan->{tick},$4);
 118                 $fleetscan->execute($id,$scan->{id}) or die $dbh->errstr;
 119         }
 120 }
 121
 122 sub parse_unit {
 123         my ($scan,$file) = @_;
 124
 125         my $id = addfleet($scan->{type},'Full fleet',$file,$scan->{pid},$scan->{tick});
 126         $fleetscan->execute($id,$scan->{id}) or die $dbh->errstr;
 127 }
 128
 129 sub parse_jumpgate {
 130         my ($scan,$file) = @_;
 131
 132         $file =~ s/,//g;
 133         while ($file =~ m{(\d+):(\d+):(\d+)\D+(Attack|Defend|Return)</td><td class="left">([^<]*)\D+(\d+)\D+(\d+)}g){
 134                 my ($sender) = $dbh->selectrow_array($findplanet,undef,$1,$2,$3,$scan->{tick});
 135                 ($sender) = $dbh->selectrow_array($findoldplanet,undef,$1,$2,$3,$scan->{tick})
 136                         if ((not defined $sender) && $4 eq 'Return');
 137                 my $id = addintel($5,$4,$sender,$scan->{pid},$scan->{tick}+$6,$6
 138                         ,undef,$7, $scan->{x} == $1 && $scan->{y} == $2);
 139                 $intelscan->execute($id,$scan->{id});
 140         }
 141
 142 }
 143
 144 my $adddevscan = $dbh->prepare(q{INSERT INTO development_scans
 145         (id,tick,pid,light_fac,medium_fac,heavy_fac,amps,distorters
 146                 ,metal_ref,crystal_ref,eonium_ref,reslabs,fincents,seccents
 147                 ,travel,infra,hulls,waves,extraction,covert,mining,total)
 148         VALUES(?,?,?,?,?,?,?,?,?,?,?,?,?,?,?,?,?,?,?,?,?,?)
 149         });
 150
 151
 152 my %parsers = (
 153         Planet => \&parse_planet,
 154         Incoming => \&parse_incoming,
 155         Unit => \&parse_unit,
 156         'Advanced Unit' => \&parse_unit,
 157         Jumpgate => \&parse_jumpgate,
 158 );
 159
 160
 161 $dbh->begin_work or die 'No transaction';
 162 $newscans->execute or die $dbh->errstr;
 163 $dbh->pg_savepoint('scans') or die "No savepoint";
 164
 165 my $parsedscans = 0;
 166
 167 while (my $scan = $newscans->fetchrow_hashref){
 168         $dbh->pg_release('scans') or die "Couldn't save";
 169         $dbh->pg_savepoint('scans') or die "Couldn't save";
 170         my $file = get("http://game.planetarion.com/showscan.pl?scan_id=$scan->{scan_id}");
 171         next unless defined $file;
 172         if ($file =~ /((?:\w| )*) (?:Scan|Probe) on (\d+):(\d+):(\d+) in tick (\d+)/){
 173                 eval {
 174                 my $type = $1;
 175                 my $x = $2;
 176                 my $y = $3;
 177                 my $z = $4;
 178                 my $tick = $5;
 179                 $scan->{tick} = $5;
 180                 $scan->{type} = $1;
 181                 $scan->{x} = $x;
 182                 $scan->{y} = $y;
 183
 184                 if($dbh->selectrow_array(q{SELECT * FROM scans WHERE scan_id = ? AND tick = ? AND id <> ?},undef,$scan->{scan_id},$tick,$scan->{id})){
 185                         $dbh->pg_rollback_to('scans') or die "rollback didn't work";
 186                         $delscan->execute($scan->{id});
 187                         $addpoints->execute(-1,$scan->{uid}) if $scan->{uid} > 0;
 188                         warn "Duplicate scan: $scan->{id} http://game.planetarion.com/showscan.pl?scan_id=$scan->{scan_id}\n";
 189                         next;
 190                 }
 191                 my ($planet) = $dbh->selectrow_array($findplanet,undef,$x,$y,$z,$tick);
 192                 $scan->{pid} = $planet;
 193                 unless ($planet){
 194                         $dbh->pg_rollback_to('scans') or die "rollback didn't work";
 195                         if ( $x == 0 && $y == 0 && $z == 0 ){
 196                                 $delscan->execute($scan->{id});
 197                                 $addpoints->execute(-1,$scan->{uid}) if $scan->{uid} > 0;
 198                         }
 199                         next;
 200                 }
 201                 my $scantext = "";
 202                 if ($file =~ /(Note: [^<]*)/){
 203                         #TODO: something about planet being closed?
 204                 }
 205                 if (exists $parsers{$type}){
 206                         $parsers{$type}->($scan,$file);
 207                 }elsif ($type eq 'News'){
 208                         while( $file =~ m{top">((?:\w| )+)\D+(\d+)</td><td class="left" valign="top">(.+?)</td></tr>}g){
 209                                 my $news = $1;
 210                                 my $t = $2;
 211                                 my $text = $3;
 212                                 my ($x,$y,$z) = $dbh->selectrow_array($findcoords,undef,$planet,$t);
 213                                 die "No coords for: $planet tick $t" unless defined $x;
 214                                 if($news eq 'Launch' && $text =~ m{The (.*?) fleet has been launched, heading for <a class="coords" href="galaxy.pl\?x=\d+&amp;y=\d+">(\d+):(\d+):(\d+)</a>, on a mission to (Attack|Defend). Arrival tick: (\d+)}g){
 215                                         my $eta = $6 - $t;
 216                                         my $mission = $5;
 217                                         my $back = $6 + $eta;
 218                                         $mission = 'AllyDef' if $eta == 6 && $x != $2;
 219                                         my ($target) = $dbh->selectrow_array($findplanet,undef
 220                                                 ,$2,$3,$4,$t) or die $dbh->errstr;
 221                                         die "No target: $2:$3:$4" unless defined $target;
 222                                         my $id = addintel($1,$mission,$planet,$target,$6
 223                                                 ,$eta,$back,undef, ($x == $2 && $y == $3));
 224                                         $intelscan->execute($id,$scan->{id});
 225                                 }elsif($news eq 'Incoming' && $text =~ m{We have detected an open jumpgate from (.*?), located at <a class="coords" href="galaxy.pl\?x=\d+&amp;y=\d+">(\d+):(\d+):(\d+)</a>. The fleet will approach our system in tick (\d+) and appears to have (\d+) visible ships}g){
 226                                         my $eta = $5 - $t;
 227                                         my $mission = '';
 228                                         my $back = $5 + $eta;
 229                                         $mission = 'Defend' if $eta <= 6;
 230                                         $mission = 'AllyDef' if $eta == 6 && $x != $2;
 231                                         my ($target) = $dbh->selectrow_array($findplanet,undef
 232                                                 ,$2,$3,$4,$t) or die $dbh->errstr;
 233                                         die "No target: $2:$3:$4" unless defined $target;
 234                                         my $id = addintel($1,$mission,$target,$planet,$5
 235                                                 ,$eta,$back,$6, ($x == $2 && $y == $3));
 236                                         $intelscan->execute($id,$scan->{id});
 237                                 }
 238                         }
 239                 } elsif($type eq 'Development'){
 240                         my @values = ($scan->{id},$tick,$planet);
 241                         my $total = 0;
 242                         while($file =~ m{((?:[a-zA-Z]| )+)</t[dh]><td(?: class="right")?>(\d+)}sg){
 243                                 push @values,$2;
 244                                 $total += $2 if $#values <= 13;
 245                         }
 246                         push @values,$total;
 247                         $adddevscan->execute(@values);
 248                 } elsif($type eq 'Landing'){
 249                 } else {
 250                         print "Something wrong with scan $scan->{id} type $type at tick $tick http://game.planetarion.com/showscan.pl?scan_id=$scan->{scan_id}\n";
 251                 }
 252                 $parsedscan->execute($tick,$type,$planet,$scan->{id}) or die $dbh->errstr;
 253                 #$dbh->rollback;
 254                 ++$parsedscans;
 255                 };
 256                 if ($@) {
 257                         warn $@;
 258                         $dbh->pg_rollback_to('scans') or die "rollback didn't work";
 259                 }
 260         }else{
 261                 warn "Nothing useful in scan: $scan->{id} http://game.planetarion.com/showscan.pl?scan_id=$scan->{scan_id}\n";
 262                 $delscan->execute($scan->{id});
 263                 $addpoints->execute(-1,$scan->{uid}) if $scan->{uid} > 0;
 264         }
 265 }
 266 #$dbh->rollback;
 267 $dbh->commit;
 268
 269 system 'killall','-USR1', 'ndbot.pl' if $parsedscans;
 270
 271 sub addfleet {
 272         my ($name,$mission,$ships,$sender,$tick,$amount) = @_;
 273
 274         my @ships;
 275         my $total = 0;
 276         $ships =~ s/,//g;
 277         while(defined $ships && $ships =~ m{((?:[a-zA-Z]| )+)</td><td(?: class="right")?>(\d+)}sg){
 278                 $total += $2;
 279                 push @ships, [$1,$2];
 280         }
 281         $amount = $total if (!defined $amount);
 282         my $id = $dbh->selectrow_array($addfleet,undef,$name,$mission,$sender
 283                 ,$tick, $amount);
 284         for my $s (@ships){
 285                 unshift @{$s},$id;
 286                 $addships->execute(@{$s}) or die $dbh->errstr;
 287         }
 288         return $id;
 289 }
 290
 291 sub addintel {
 292         my ($name,$mission,$sender,$target,$tick,$eta,$back,$amount,$ingal) = @_;
 293
 294         die "no sender" unless defined $sender;
 295
 296         $ingal = 0 unless $ingal;
 297         $back = $tick + 4 if $ingal && $eta <= 4;
 298
 299         if ($mission eq 'Return'){
 300                 ($sender,$target) = ($target,$sender);
 301                 $back = $tick + $eta if $eta;
 302         }
 303
 304         my $id = $dbh->selectrow_array($addintel,undef,$name,$mission,$sender
 305                 ,$target,$tick, $eta, $back, $amount,$ingal);
 306         return $id;
 307 }