scripts/scans.pl

   1 #!/usr/bin/perl
   2 #**************************************************************************
   3 #   Copyright (C) 2006,2007 by Michael Andreen <harvATruinDOTnu>          *
   4 #                                                                         *
   5 #   This program is free software; you can redistribute it and/or modify  *
   6 #   it under the terms of the GNU General Public License as published by  *
   7 #   the Free Software Foundation; either version 2 of the License, or     *
   8 #   (at your option) any later version.                                   *
   9 #                                                                         *
  10 #   This program is distributed in the hope that it will be useful,       *
  11 #   but WITHOUT ANY WARRANTY; without even the implied warranty of        *
  12 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the         *
  13 #   GNU General Public License for more details.                          *
  14 #                                                                         *
  15 #   You should have received a copy of the GNU General Public License     *
  16 #   along with this program; if not, write to the                         *
  17 #   Free Software Foundation, Inc.,                                       *
  18 #   51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.         *
  19 #**************************************************************************/
  20
  21
  22 use strict;
  23 use warnings;
  24 no warnings 'exiting';
  25 use CGI;
  26 use DBI;
  27 use DBD::Pg qw(:pg_types);
  28 use LWP::Simple;
  29
  30 use FindBin;
  31 use lib "$FindBin::Bin/../lib";
  32
  33 use ND::DB;
  34
  35 our $dbh = ND::DB::DB();
  36
  37 #$dbh->trace("1","/tmp/scanstest");
  38
  39 #my $test = $dbh->prepare(q{INSERT INTO scans (tick,scan_id) VALUES(1,3) RETURNING id});
  40 #print ;
  41 $dbh->do(q{SET CLIENT_ENCODING TO 'LATIN1';});
  42
  43 my $scangroups = $dbh->prepare(q{SELECT id,scan_id,tick,uid FROM scans
  44         WHERE groupscan AND NOT parsed FOR UPDATE
  45 });
  46 my $oldscan = $dbh->prepare(q{SELECT scan_id FROM scans WHERE scan_id = ? AND tick >= tick() - 168});
  47 my $addScan = $dbh->prepare(q{INSERT INTO scans (scan_id,tick,uid) VALUES (?,?,?)});
  48 my $parsedscan = $dbh->prepare(q{UPDATE scans SET tick = ?, type = ?, planet = ?, parsed = TRUE WHERE id = ?});
  49 my $addpoints = $dbh->prepare(q{UPDATE users SET scan_points = scan_points + ? WHERE uid = ? });
  50 my $delscan = $dbh->prepare(q{DELETE FROM scans WHERE id = ?});
  51
  52 $scangroups->execute or die $dbh->errstr;
  53
  54 while (my $group = $scangroups->fetchrow_hashref){
  55         $dbh->begin_work;
  56         my $file = get("http://game.planetarion.com/showscan.pl?scan_grp=$group->{scan_id}");
  57
  58         my $points = 0;
  59         while ($file =~ m/showscan.pl\?scan_id=(\d+)/g){
  60                 unless ($dbh->selectrow_array($oldscan,undef,$1)){
  61                         $addScan->execute($1,$group->{tick},$group->{uid});
  62                         ++$points;
  63                 }
  64         }
  65         $addpoints->execute($points,$group->{uid});
  66         $parsedscan->execute($group->{tick},'GROUP',undef,$group->{id});
  67         $dbh->commit;
  68 }
  69
  70 my $newscans = $dbh->prepare(q{SELECT id,scan_id,tick,uid FROM scans
  71         WHERE NOT groupscan AND NOT parsed FOR UPDATE
  72 });
  73 my $findplanet = $dbh->prepare(q{SELECT planetid(?,?,?,?)});
  74 my $findoldplanet = $dbh->prepare(q{SELECT id FROM planet_stats WHERE x = $1 AND y = $2 AND z = $3 AND tick <= $4 ORDER BY tick DESC LIMIT 1});
  75 my $findcoords = $dbh->prepare(q{SELECT * FROM planetcoords(?,?)});
  76 my $addfleet = $dbh->prepare(q{INSERT INTO fleets (name,mission,sender,target,tick,eta,back,amount,ingal,uid) VALUES(?,?,?,?,?,?,?,?,?,-1) RETURNING id});
  77 my $fleetscan = $dbh->prepare(q{INSERT INTO fleet_scans (id,scan) VALUES(?,?)});
  78 my $addships = $dbh->prepare(q{INSERT INTO fleet_ships (id,ship,amount) VALUES(?,?,?)});
  79 my $addplanetscan = $dbh->prepare(q{INSERT INTO planet_scans
  80         (id,tick,planet,metal_roids,metal,crystal_roids,crystal,eonium_roids,eonium
  81                 ,agents,guards,light,medium,heavy,hidden)
  82         VALUES(?,?,?,?,?,?,?,?,?,?,?,?,?,?,?)});
  83
  84 sub parse_planet {
  85         my ($scan,$file) = @_;
  86
  87         my @values = ($scan->{id},$scan->{tick},$scan->{planet});
  88         $file =~ s/(\d),(\d)/$1$2/g;
  89
  90         while($file =~ m/"center">(Metal|Crystal|Eonium)\D+(\d+)\D+([\d,]+)/g){
  91                 push @values,$2,$3;
  92         }
  93         if($file =~ m{Security\ Guards .+? "center">(\d+)</td>
  94                         .+? "center">(\d+)</td>}sx){
  95                 push @values,$1,$2;
  96         }
  97         if($file =~ m{<td class="center">([A-Z][a-z]+)</td><td class="center">([A-Z][a-z]+)</td><td class="center">([A-Z][a-z]+)</td>}){
  98                 push @values,$1,$2,$3;
  99         }
 100         if($file =~ m{<span class="superhighlight">([\d,]+)</span>}){
 101                 push @values,$1;
 102         }
 103         $addplanetscan->execute(@values);
 104 }
 105
 106 sub parse_incoming {
 107         my ($scan,$file) = @_;
 108
 109         while($file =~ m{class="left">Fleet:\s(.*?)</td><td\sclass="right">
 110                         Mission:\s(\w+)</td></tr>(.*?)Total\sShips:\s(\d+)}sxg){
 111                 my $id = addfleet($1,$2,$3,$scan->{planet},undef
 112                         ,$scan->{tick},undef,undef,$4);
 113                 $fleetscan->execute($id,$scan->{id}) or die $dbh->errstr;
 114         }
 115 }
 116
 117 my $adddevscan = $dbh->prepare(q{INSERT INTO development_scans
 118         (id,tick,planet,light_fac,medium_fac,heavy_fac,amps,distorters
 119                 ,metal_ref,crystal_ref,eonium_ref,reslabs,fincents,seccents
 120                 ,travel,infra,hulls,waves,extraction,covert,mining,total)
 121         VALUES(?,?,?,?,?,?,?,?,?,?,?,?,?,?,?,?,?,?,?,?,?,?)
 122         });
 123
 124
 125 my %parsers = (
 126         Planet => \&parse_planet,
 127         Incoming => \&parse_incoming,
 128 );
 129
 130
 131 $dbh->begin_work or die 'No transaction';
 132 $newscans->execute or die $dbh->errstr;
 133 $dbh->pg_savepoint('scans') or die "No savepoint";
 134
 135 my $parsedscans = 0;
 136
 137 while (my $scan = $newscans->fetchrow_hashref){
 138         $dbh->pg_release('scans') or die "Couldn't save";
 139         $dbh->pg_savepoint('scans') or die "Couldn't save";
 140         my $file = get("http://game.planetarion.com/showscan.pl?scan_id=$scan->{scan_id}");
 141         next unless defined $file;
 142         if ($file =~ /((?:\w| )*) (?:Scan|Probe) on (\d+):(\d+):(\d+) in tick (\d+)/){
 143                 eval {
 144                 my $type = $1;
 145                 my $x = $2;
 146                 my $y = $3;
 147                 my $z = $4;
 148                 my $tick = $5;
 149                 $scan->{tick} = $5;
 150
 151                 if($dbh->selectrow_array(q{SELECT * FROM scans WHERE scan_id = ? AND tick = ? AND id <> ?},undef,$scan->{scan_id},$tick,$scan->{id})){
 152                         $dbh->pg_rollback_to('scans') or die "rollback didn't work";
 153                         $delscan->execute($scan->{id});
 154                         $addpoints->execute(-1,$scan->{uid}) if $scan->{uid} > 0;
 155                         warn "Duplicate scan: $scan->{id} http://game.planetarion.com/showscan.pl?scan_id=$scan->{scan_id}\n";
 156                         next;
 157                 }
 158                 my ($planet) = $dbh->selectrow_array($findplanet,undef,$x,$y,$z,$tick);
 159                 $scan->{planet} = $planet;
 160                 unless ($planet){
 161                         $dbh->pg_rollback_to('scans') or die "rollback didn't work";
 162                         if ( $x == 0 && $y == 0 && $z == 0 ){
 163                                 $delscan->execute($scan->{id});
 164                                 $addpoints->execute(-1,$scan->{uid}) if $scan->{uid} > 0;
 165                         }
 166                         next;
 167                 }
 168                 my $scantext = "";
 169                 if ($file =~ /(Note: [^<]*)/){
 170                         #TODO: something about planet being closed?
 171                 }
 172                 if (exists $parsers{$type}){
 173                         $parsers{$type}->($scan,$file);
 174                 }elsif ($type eq 'Jumpgate'){
 175                 #print "$file\n";
 176                         while ($file =~ m{(\d+):(\d+):(\d+)\D+(Attack|Defend|Return)</td><td class="left">([^<]*)\D+(\d+)\D+(\d+)}g){
 177
 178                                 my ($sender) = $dbh->selectrow_array($findplanet,undef,$1,$2,$3,$tick) or die $dbh->errstr;
 179                                 ($sender) = $dbh->selectrow_array($findoldplanet,undef,$1,$2,$3,$tick) if ((not defined $sender) && $4 eq 'Return');
 180                                 my $id = addfleet($5,$4,undef,$sender,$planet,$tick+$6,$6
 181                                         ,undef,$7, $x == $1 && $y == $2);
 182                                 $fleetscan->execute($id,$scan->{id}) or die $dbh->errstr;
 183                         }
 184                 }elsif ($type eq 'News'){
 185                         while( $file =~ m{top">((?:\w| )+)\D+(\d+)</td><td class="left" valign="top">(.+?)</td></tr>}g){
 186                                 my $news = $1;
 187                                 my $t = $2;
 188                                 my $text = $3;
 189                                 my ($x,$y,$z) = $dbh->selectrow_array($findcoords,undef,$planet,$t);
 190                                 die "No coords for: $planet tick $t" unless defined $x;
 191                                 if($news eq 'Launch' && $text =~ m/The (.*?) fleet has been launched, heading for (\d+):(\d+):(\d+), on a mission to (Attack|Defend). Arrival tick: (\d+)/g){
 192                                         my $eta = $6 - $t;
 193                                         my $mission = $5;
 194                                         my $back = $6 + $eta;
 195                                         $mission = 'AllyDef' if $eta == 6 && $x != $2;
 196                                         my ($target) = $dbh->selectrow_array($findplanet,undef
 197                                                 ,$2,$3,$4,$t) or die $dbh->errstr;
 198                                         die "No target: $2:$3:$4" unless defined $target;
 199                                         my $id = addfleet($1,$mission,undef,$planet,$target,$6
 200                                                 ,$eta,$back,undef, ($x == $2 && $y == $3));
 201                                         $fleetscan->execute($id,$scan->{id}) or die $dbh->errstr;
 202                                 }elsif($news eq 'Incoming' && $text =~ m/We have detected an open jumpgate from (.*?), located at (\d+):(\d+):(\d+). The fleet will approach our system in tick (\d+) and appears to have roughly (\d+) ships/g){
 203                                         my $eta = $5 - $t;
 204                                         my $mission = '';
 205                                         my $back = $5 + $eta;
 206                                         $mission = 'Defend' if $eta <= 6;
 207                                         $mission = 'AllyDef' if $eta == 6 && $x != $2;
 208                                         my ($target) = $dbh->selectrow_array($findplanet,undef
 209                                                 ,$2,$3,$4,$t) or die $dbh->errstr;
 210                                         die "No target: $2:$3:$4" unless defined $target;
 211                                         my $id = addfleet($1,$mission,undef,$target,$planet,$5
 212                                                 ,$eta,$back,$6, ($x == $2 && $y == $3));
 213                                         $fleetscan->execute($id,$scan->{id}) or die $dbh->errstr;
 214                                 }
 215                         }
 216                 } elsif($type eq 'Development'){
 217                         my @values = ($scan->{id},$tick,$planet);
 218                         my $total = 0;
 219                         while($file =~ m{((?:[a-zA-Z]| )+)</t[dh]><td(?: class="right")?>(\d+)}sg){
 220                                 push @values,$2;
 221                                 $total += $2 if $#values <= 13;
 222                         }
 223                         push @values,$total;
 224                         $adddevscan->execute(@values);
 225                 } elsif($type eq 'Unit' || $type eq 'Advanced Unit'){
 226                         my $id = addfleet($type,'Full fleet',$file,$planet,undef,$tick,undef,undef,undef);
 227                         $fleetscan->execute($id,$scan->{id}) or die $dbh->errstr;
 228                 } elsif($type eq 'Landing'){
 229                 } else {
 230                         print "Something wrong with scan $scan->{id} type $type at tick $tick http://game.planetarion.com/showscan.pl?scan_id=$scan->{scan_id}\n";
 231                 }
 232                 $parsedscan->execute($tick,$type,$planet,$scan->{id}) or die $dbh->errstr;
 233                 #$dbh->rollback;
 234                 ++$parsedscans;
 235                 };
 236                 if ($@) {
 237                         warn $@;
 238                         $dbh->pg_rollback_to('scans') or die "rollback didn't work";
 239                 }
 240         }else{
 241                 warn "Nothing useful in scan: $scan->{id} http://game.planetarion.com/showscan.pl?scan_id=$scan->{scan_id}\n";
 242                 $delscan->execute($scan->{id});
 243                 $addpoints->execute(-1,$scan->{uid}) if $scan->{uid} > 0;
 244         }
 245 }
 246 #$dbh->rollback;
 247 $dbh->commit;
 248
 249 system 'killall','-USR1', 'irssi' if $parsedscans;
 250
 251 sub addfleet {
 252         my ($name,$mission,$ships,$sender,$target,$tick,$eta,$back,$amount,$ingal) = @_;
 253
 254         die "no sender" unless defined $sender;
 255
 256         $ingal = 0 unless $ingal;
 257         $back = $tick + 4 if $ingal && $eta <= 4;
 258
 259         if ($mission eq 'Return'){
 260                 ($sender,$target) = ($target,$sender);
 261                 $back = $tick + $eta if $eta;
 262         }
 263
 264         my @ships;
 265         my $total = 0;
 266         while(defined $ships && $ships =~ m{((?:[a-zA-Z]| )+)</td><td(?: class="right")?>(\d+)}sg){
 267                 $total += $2;
 268                 push @ships, [$1,$2];
 269         }
 270         $amount = $total if (!defined $amount) && defined $ships;
 271         my $id = $dbh->selectrow_array($addfleet,undef,$name,$mission,$sender
 272                 ,$target,$tick, $eta, $back, $amount,$ingal) or die $dbh->errstr;
 273         for my $s (@ships){
 274                 unshift @{$s},$id;
 275                 $addships->execute(@{$s}) or die $dbh->errstr;
 276         }
 277         return $id;
 278 };